Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: ORKCHK4

ORKCHK4.m

Go to the documentation of this file. 
  1. ORKCHK4 ; slc/CLA - Support routine called by ORKCHK to do SELECT mode order checks ;3/6/97  9:35
  1.  ;;3.0;ORDER ENTRY/RESULTS REPORTING;**6,32,74,87,94,123,162,190,249**;Dec 17, 1997
  1.  Q
  1.  ;
  1. EN(ORKS,ORKDFN,ORKA,ORENT,ORKTMODE) ;perform order checking for orderable item selection
  1.  Q:$$GET^XPAR("DIV^SYS^PKG","ORK SYSTEM ENABLE/DISABLE",1,"I")="D"
  1.  ;
  1.  N OI,ORKDG,HL7,ODT,ORNUM,HL7NPTR,HL7NTXT,HL7NCOD,HL7LPTR,HL7LTXT,HL7LCOD
  1.  N ORKMSG,ORKT,ORKTXT
  1.  ;
  1.  S OI=$P(ORKA,"|"),ORKDG=$P(ORKA,"|",2)
  1.  S HL7=$P(ORKA,"|",3),ODT=$P(ORKA,"|",4),ORNUM=$P(ORKA,"|",5)
  1.  S HL7NPTR=$P(HL7,U),HL7NTXT=$P(HL7,U,2),HL7NCOD=$P(HL7,U,3)
  1.  S HL7LPTR=$P(HL7,U,4),HL7LTXT=$P(HL7,U,5),HL7LCOD=$P(HL7,U,6)
  1.  ;
  1.  I $E(ORKDG,1,2)="PS" D PHARM
  1.  I $E(ORKDG,1,2)'="PS" D MLM^ORKCHK2(.ORKS,ORKDFN,ORKA,ORENT,"SELECT")
  1.  Q
  1.  ;
  1. PHARM ;process pharmacy order checks:
  1.  N ORPSPKG,ORPSA,ORKDD
  1.  N ORCRITN,ORCRITF,ORCRITD,ORSIGN,ORSIGF,ORSIGD,ORDUPN,ORDUPF,ORDUPD,ORDUPCN,ORDUPCF,ORDUPCD
  1.  ;
  1.  D PARAMS("CRITICAL DRUG INTERACTION",.ORCRITN,.ORCRITF,.ORCRITD)
  1.  D PARAMS("SIGNIFICANT DRUG INTERACTION",.ORSIGN,.ORSIGF,.ORSIGD)
  1.  D PARAMS("DUPLICATE DRUG ORDER",.ORDUPN,.ORDUPF,.ORDUPD)
  1.  D PARAMS("DUPLICATE DRUG CLASS ORDER",.ORDUPCN,.ORDUPCF,.ORDUPCD)
  1.  ;
  1.  ;dispense drug selected:
  1.  I $L($G(HL7LPTR)),($G(HL7LCOD)="99PSD") D
  1.  .D RXOCS
  1.  .D MLM^ORKCHK2(.ORKS,ORKDFN,ORKA,ORENT,"SELECT")
  1.  ;
  1.  ;dispense drug NOT selected, split OI into dispense drugs:
  1.  I '$L($G(HL7LPTR)) D
  1.  .S ORPSPKG=$E(ORKDG,3)
  1.  .I ORPSPKG="H" S ORPSPKG="X"  ;change to "X" if "H"erbal/non-VA med
  1.  .I "IOX"[ORPSPKG D OI2DD(.ORPSA,OI,ORPSPKG)
  1.  .S ORKDD=0 F  S ORKDD=$O(ORPSA(ORKDD)) Q:'ORKDD  D
  1.  ..S HL7LTXT=ORPSA(ORKDD)
  1.  ..S HL7NPTR=$P(ORKDD,";",2)
  1.  ..S HL7LPTR=+ORKDD
  1.  ..S HL7LCOD="99PSD",HL7NCOD="99NDF"
  1.  ..S $P(HL7,U)=HL7NPTR,$P(HL7,U,3)=HL7NCOD
  1.  ..S $P(HL7,U,4)=HL7LPTR,$P(HL7,U,5)=HL7LTXT,$P(HL7,U,6)=HL7LCOD
  1.  ..S $P(ORKA,"|",3)=HL7  ;set these for MLM OCX call
  1.  ..D RXOCS
  1.  ..D MLM^ORKCHK2(.ORKS,ORKDFN,ORKA,ORENT,"SELECT")
  1.  Q
  1.  ;
  1. RXOCS ;drug-drug interaction, duplicate drug order, duplicate drug class
  1.  Q:ORCRITF_ORSIGF_ORDUPF_ORDUPCF'["E"  ;quit if none are "E"nabled
  1.  N ORKRX,ORPSNUM
  1.  D CHECK^ORKPS(.ORKRX,ORKDFN,HL7LPTR,OI,ORKDG)
  1.  N CHK,XX S CHK=0,XX=""
  1.  F  S CHK=$O(ORKRX(CHK)) Q:'CHK  D
  1.  .S XX=ORKRX(CHK)
  1.  .;
  1.  .;critical drug interaction:
  1.  .I $P(XX,U)="DI",$P(XX,U,5)="CRITICAL" D  ;,(ORKTMODE'="ALL") D
  1.  ..Q:ORCRITF="D"
  1.  ..S ORPSNUM=$P(XX,U,8)  ;get the associated order number
  1.  ..I $L(ORPSNUM),$G(^OR(100,+ORPSNUM,0)) S ORKT=$$FULLTEXT^ORQOR1(+ORPSNUM),ORKTXT=$P(ORKT,U)_" ["_$P(ORKT,U,2)_"]"
  1.  ..E  S ORKTXT=$P(XX,U,3)
  1.  ..S ORKMSG=$P(XX,U,5)_" drug-drug interaction: "_$P(XX,U,6)_" & "_$P(XX,U,7)
  1.  ..S ORKS("ORK",ORCRITD_","_$G(ORNUM)_","_ORPSNUM_","_$E(ORKMSG,1,225))=ORNUM_U_ORCRITN_U_ORCRITD_U_ORKMSG_" ("_ORKTXT_")"_U_$G(ORPSNUM)
  1.  .;
  1.  .;significant drug interaction:
  1.  .I $P(XX,U)="DI",$P(XX,U,5)="SIGNIFICANT" D  ;,(ORKTMODE'="ALL") D
  1.  ..Q:ORSIGF="D"
  1.  ..S ORPSNUM=$P(XX,U,8)  ;get the associated order number
  1.  ..I $L(ORPSNUM),$G(^OR(100,+ORPSNUM,0)) S ORKT=$$FULLTEXT^ORQOR1(+ORPSNUM),ORKTXT=$P(ORKT,U)_" ["_$P(ORKT,U,2)_"]"
  1.  ..E  S ORKTXT=$P(XX,U,3)
  1.  ..S ORKMSG=$P(XX,U,5)_" drug-drug interaction: "_$P(XX,U,6)_" & "_$P(XX,U,7)
  1.  ..S ORKS("ORK",ORSIGD_","_$G(ORNUM)_","_ORPSNUM_","_$E(ORKMSG,1,225))=ORNUM_U_ORSIGN_U_ORSIGD_U_ORKMSG_" ("_ORKTXT_")"_U_$G(ORPSNUM)
  1.  .;
  1.  .;duplicate drug:
  1.  .I $P(XX,U)="DD" D  ;,(ORKTMODE'="ALL") D
  1.  ..Q:ORDUPF="D"
  1.  ..S ORPSNUM=$P(XX,U,4)  ;get the associated order number
  1.  ..I $L(ORPSNUM),$G(^OR(100,+ORPSNUM,0)) S ORKT=$$FULLTEXT^ORQOR1(+ORPSNUM),ORKTXT=$P(ORKT,U)_" ["_$P(ORKT,U,2)_"]"
  1.  ..E  S ORKTXT=$P(XX,U,3)
  1.  ..S ORKMSG="Duplicate drug order: "_ORKTXT
  1.  ..S ORKS("ORK",ORDUPD_","_$G(ORNUM)_","_ORPSNUM_",Duplicate drug order: "_$P(XX,U,3))=ORNUM_U_ORDUPN_U_ORDUPD_U_ORKMSG_U_$G(ORPSNUM)
  1.  .;
  1.  .;duplicate class:
  1.  .I $P(XX,U)="DC" D  ;,(ORKTMODE'="ALL") D
  1.  ..Q:ORDUPCF="D"
  1.  ..S ORPSNUM=$P(XX,U,6)  ;get the associated order number
  1.  ..I $L(ORPSNUM),$G(^OR(100,+ORPSNUM,0)) S ORKT=$$FULLTEXT^ORQOR1(+ORPSNUM),ORKTXT=$P(ORKT,U)_" ["_$P(ORKT,U,2)_"]"
  1.  ..E  S ORKTXT=$P(XX,U,5)
  1.  ..S ORKMSG="Duplicate drug class order: "_$P(XX,U,3)
  1.  ..S ORKS("ORK",ORDUPCD_","_$G(ORNUM)_","_ORPSNUM_","_$E(ORKMSG,1,225))=ORNUM_U_ORDUPCN_U_ORDUPCD_U_ORKMSG_" ("_ORKTXT_")"_U_$G(ORPSNUM)
  1.  Q
  1.  ;
  1. OI2DD(ORPSA,OROI,ORPSPKG)       ;rtn dispense drugs for a PS OI
  1.  N PSOI
  1.  Q:'$D(^ORD(101.43,OROI,0))
  1.  S PSOI=$P($P(^ORD(101.43,OROI,0),U,2),";")
  1.  Q:+$G(PSOI)<1
  1.  D DRG^PSSUTIL1(.ORPSA,PSOI,ORPSPKG)
  1.  Q
  1.  ;
  1. PARAMS(ORKNAME,ORKNUM,ORKFLAG,ORKDNGR) ; get parameter values for an order chk
  1.  S ORKNUM=0,ORKNUM=$O(^ORD(100.8,"B",ORKNAME,ORKNUM))
  1.  S ORKFLAG=$$GET^XPAR(ORENT,"ORK PROCESSING FLAG",ORKNUM,"I")
  1.  S ORKDNGR=$$GET^XPAR("DIV^SYS^PKG","ORK CLINICAL DANGER LEVEL",ORKNUM,"I")
  1.  Q