Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: ORWDBA14

ORWDBA14.m

Go to the documentation of this file. 
  1. ORWDBA14 ; SLC/GDU - Billing Awareness - Phase I [10/18/04 10:26]
  1.  ;;3.0;ORDER ENTRY/RESULTS REPORTING;**195**;Dec 17, 1997
  1.  ;
  1.  ;Enable Billing Data Capture By Provider Parameter
  1.  ;ORWDBA14 - Get a report of assigned parameters
  1.  ;
  1.  ;Report to print out the providers with the Billing Data Capture By
  1.  ;Provider parameter set.
  1.  ;Billing Data Capture By Provider will be referred to as BDCBP.
  1.  ;Billing Data Capture will be referred to as BDC
  1.  ;The user has the option to search by:
  1.  ; 1. For all providers with the BDCBP parameter
  1.  ; 2. For all providers with the BDCBP parameter and BDC enabled
  1.  ; 3. For all providers with the BDCBP parameter and BDC disabled
  1.  ;
  1.  ;Programs called:
  1.  ; ^%ZIS         DBIA 10086
  1.  ; ^%ZISC        DBIA 10089
  1.  ; ^%ZTLOAD      DBIA 10063
  1.  ; ^DIR          DBIA 10026
  1.  ; RPT^ORWDBA16  Generates and prints the report
  1.  ; ENVAL^XPAR    DBIA 2263
  1.  ;
  1.  ;Variables Used:
  1.  ; %ZIS     KERNEL device selection variable
  1.  ; DIR      Input array variable for ^DIR
  1.  ; DTOUT    Timeout indicator variable, output from ^DIR
  1.  ; DUOUT    Up Arrow '^' indicator variable, output from ^DIR
  1.  ; ORERR    Error message output array variable from ENVAL^XPAR
  1.  ; IO       Input / Output array variable, System settings
  1.  ; IOF      Page feed variable, System settings
  1.  ; ION      Device name, System settings
  1.  ; POP      Cancel device select, program run output from ^%ZIS
  1.  ; SEARCH   User select of type of report to run
  1.  ; Y        Processed user selection, output from ^DIR
  1.  ; ZTDESC   Description of queued job, input for ^%ZTLOAD
  1.  ; ZTIO     Device selected for the queued job, input for ^%ZTLOAD
  1.  ; ZTRTN    Routine selected for the queued job, input for ^%ZTLOAD
  1.  ; ZTSAVE   Input parameters for the queued job, input for ^%ZTLOAD
  1.  ; ZTSK     Internal Entry Number of the queued job, output from ^%ZTLOAD
  1.  ;
  1.  ;Globals Used:
  1.  ; ^TMP("ORCK"
  1.  ; Temp global to hold value of LIST, output from ENVAL^XPAR. If
  1.  ; ^TMP("ORCK",$J,"A") has a count of 0 the user is alerted that there
  1.  ; are no parameter assigned to providers. This is acknowledged by the
  1.  ; user and the program quits.
  1.  ;
  1. MAIN ;Main starting point for this program
  1.  ;User selects the type of report to run. Then selects the device the
  1.  ;reports output will go.
  1.  N %ZIS,DIR,DTOUT,DUOUT,ORERR,POP,SEARCH,Y,ZTDESC,ZTIO,ZTRTN,ZTSAVE,ZTSK
  1.  ;Check for assigned parameters.
  1.  D ENVAL^XPAR("^TMP(""ORCK"",$J,""A"")","OR BILLING AWARENESS BY USER",1,.ORERR,1)
  1.  ;If none found alert user, exit program
  1.  I ^TMP("ORCK",$J,"A")=0 D  G EXIT
  1.  . D SCRHDR
  1.  . S DIR(0)="E"
  1.  . S DIR("A",1)=$P($T(NPA1),";",3)
  1.  . S DIR("A",2)=$P($T(NPA2),";",3)
  1.  . S DIR("A",3)=$P($T(NPA3),";",3)
  1.  . S DIR("A")=$P($T(NPA4),";",3)
  1.  . W !! D ^DIR K DIR
  1.  K ^TMP("ORCK",$J)
  1.  S SEARCH=""
  1.  S DIR(0)="SO^"_$P($T(L0A),";",3)_";"
  1.  S DIR(0)=DIR(0)_$P($T(L0E),";",3)_";"
  1.  S DIR(0)=DIR(0)_$P($T(L0D),";",3)
  1.  S DIR("?",1)=$P($T(LHA),";",3)
  1.  S DIR("?",2)=$P($T(LHE),";",3)
  1.  S DIR("?")=$P($T(LHD),";",3)
  1.  S DIR("A")=$P($T(LA),";",3)
  1.  D SCRHDR,^DIR K DIR S SEARCH=Y
  1.  I SEARCH="Q"!(SEARCH="")!($D(DTOUT))!($D(DUOUT)) G EXIT
  1.  S %ZIS="Q" D ^%ZIS I POP G EXIT
  1.  I $D(IO("Q")) D  K IO("Q") G EXIT
  1.  . S ZTIO=ION
  1.  . S ZTDESC="BA Enabled By User Report"
  1.  . S ZTRTN="RPT^ORWDBA16"
  1.  . S ZTSAVE("SEARCH")=""
  1.  . D ^%ZTLOAD I $D(ZTSK) W !?32,"REQUEST QUEUED"
  1.  U IO D RPT^ORWDBA16
  1.  D ^%ZISC
  1. AGAIN ;Ask if the user would like to repeat the parameter report process
  1.  ;If yes, the program starts over.
  1.  ;If no, the program quits and the user is returned to the previous menu.
  1.  S DIR(0)="Y"
  1.  S DIR("A")=$P($T(ALA),";",3)
  1.  S DIR("B")="N"
  1.  S DIR("?",1)=$P($T(ALHY),";",3)
  1.  S DIR("?")=$P($T(ALHN),";",3)
  1.  W !! D ^DIR K DIR
  1.  I Y=1 G MAIN
  1. EXIT ;Exit point for this program
  1.  K ^TMP("ORCK",$J)
  1.  D ^%ZISC
  1.  Q
  1. SCRHDR ;Screen Header Display
  1.  W:$D(IOF) @IOF
  1.  W !,"Enable Clinical Indicator Data Capture By Provider Parameter Management"
  1.  W !,"Assigned Parameter Report"
  1.  Q
  1.  ;Text to build the DIR variable for ^DIR in LIST
  1. L0A ;;A:All providers with CIDC parameter
  1. L0E ;;E:Only providers with CIDC enabled
  1. L0D ;;D:Only providers with CIDC disabled
  1. LA ;;Enter the search criteria
  1. LHA ;;Enter A to list all providers with Clinical Indicator Data Capture parameter.
  1. LHE ;;Enter E to list only providers with Clinical Indicator Data Capture enabled.
  1. LHD ;;Enter D to list only providers with Clinical Indicator Data Capture disabled.
  1.  ;Text to build the DIR variable for ^DIR in NPA
  1. NPA1 ;;No providers currently have the parameter assigned to them.
  1. NPA2 ;;You will need to select the 'Manage parameter by provider' option and
  1. NPA3 ;;assign this parameter to the providers.
  1. NPA4 ;;Press the return key or '^' to continue.
  1.  ;Text to build the DIR variable for ^DIR in AGAIN
  1. ALA ;;Run another report
  1. ALHY ;;Enter Y for Yes to run another report.
  1. ALHN ;;Enter N for No to not run another report.