Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: ORWDBA81

ORWDBA81.m

Go to the documentation of this file. 
  1. ORWDBA81 ; SLC/GDU - Billing Awareness - Phase I [10/18/04 10:42]
  1.  ;;3.0;ORDER ENTRY/RESULTS REPORTING;**195**;Dec 17, 1997
  1.  ;
  1.  ;Enable Clinical Indicator Data Capture By Provider Parameter Module
  1.  ;ORWDBA81 - Mass assign the parameter to all providers without the 
  1.  ;           parameter and set it to 1 to enable the CIDC functionality.
  1.  ;
  1.  ;Local Variables
  1.  ;DIR          Input array variable for ^DIR
  1.  ;DTOUT        Timeout indicator, output variable of ^DIR
  1.  ;DUOUT        Up arrow indicator, output variable of ^DIR
  1.  ;ENT          Entity the parameter is assigned to, input variable for
  1.  ;             ADD^XPAR
  1.  ;ORERR        Error Message, output variable of ADD^XPAR
  1.  ;INST         Instance indicator, input variable for ADD^XPAR
  1.  ;IOF          Clear Screen and move cursor to top of screen, standard
  1.  ;             Kernal IO variable
  1.  ;PAR          The Name or IEN of a parameter in the PARAMETER DEFINITION
  1.  ;             FILE, input variable for ADD^XPAR 
  1.  ;VAL          Value of the parameter being added, input variable for
  1.  ;             ADD^XPAR
  1.  ;X            Standard FileMan work varaible
  1.  ;Y            Processed output of user selection, output variable for
  1.  ;             ^DIR
  1.  ;
  1.  ;Global Variables
  1.  ;^TMP("ORPUL" Temp global for providers who do not have the
  1.  ;             Enable/Disable CIDC By Provider parameter assigned to them
  1.  ;^XTV(8989.51 PARAMETER DEFINITION FILE, file # 8989.51
  1.  ;
  1.  ;External References
  1.  ;^DIR         FileMan general purpose response reader
  1.  ;ADD^XPAR     PARAMETER TOOLS, API to add a new parameter value
  1.  ;
  1. MAIN ;Starting point of this program
  1.  N DIR,DTOUT,DUOUT,ENT,ORERR,INST,PAR,VAL,X,Y
  1.  ;Prepare and display user options for this program
  1.  S DIR(0)=$P($T(SXOPT),";",3)_";"
  1.  S DIR(0)=DIR(0)_$P($T(OY),";",3)_";"_$P($T(ON),";",3)
  1.  S DIR("A",1)=^TMP("ORPUL",$J,"A")_" "_$P($T(A1),";",3)
  1.  S DIR("A",2)=$P($T(A2),";",3)
  1.  S DIR("A",3)=$P($T(A3),";",3)
  1.  S DIR("A")=$P($T(A4),";",3)
  1.  S DIR("?",1)=$P($T(HY),";",3)
  1.  S DIR("?")=$P($T(HN),";",3)
  1.  D SCRHDR,^DIR K DIR
  1.  ;Process user selection.
  1.  I Y="NO"!($D(DTOUT))!($D(DUOUT)) Q  ;If NO, timeout, or up arrow quit
  1.  ;Process the mass parameter assignment and functionality enabling
  1.  S (ENT,X)="",(INST,VAL)=1
  1.  S PAR=$QS($Q(^XTV(8989.51,"B","OR BILLING AWARENESS BY USER")),4)
  1.  D SCRHDR
  1.  W !!,$P($T(EP),";",3),!
  1.  S X="" F  S X=$O(^TMP("ORPUL",$J,"A",X)) Q:X=""  D
  1.  . W "."
  1.  . S ENT=^TMP("ORPUL",$J,"A",X)
  1.  . D ADD^XPAR(ENT,PAR,INST,VAL,.ORERR)
  1.  ;Alert user the mass parameter assignment and functionality enabling is
  1.  ;done.
  1.  S DIR(0)="E",DIR("A")=$P($T(EC),";",3)
  1.  D ^DIR K DIR Q
  1. SCRHDR ;Screen Header
  1.  W:$D(IOF) @IOF
  1.  W !,$P($T(SH1),";",3),!,$P($T(SH2),";",3)
  1.  Q
  1. SXOPT ;;SX^
  1. SH1 ;;Enable Clinical Indicator Data Capture By Provider Parameter Management
  1. SH2 ;;Assign/Enable Parameter For All Providers Option
  1. OY ;;YES:Enter YES to begin process of assign/enable
  1. ON ;;NO:Enter NO to cancel process of assign/enable and quit
  1. A1 ;;providers do not have this parameter assigned to them.
  1. A2 ;;You have selected to assign the parameter and enable Clinical Indictor
  1. A3 ;;Data Capture for all of these providers. This may take some time.
  1. A4 ;;Are you sure you want to do this? (YES/NO - must be all caps)
  1. HY ;;Enter YES to begin the assign/enable process.
  1. HN ;;Enter NO to cancel the assign/enable process and quit.
  1. EP ;;Now assigning CIDC parameter and enabling the functionality.
  1. EC ;;CIDC parameter assignment and functionality enabling complete.