Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: ORWDFH

ORWDFH.m

Go to the documentation of this file. 
  1. ORWDFH ; SLC/KCM/JLI - Diet Order calls for Windows Dialogs ;12/12/00  14:44
  1.  ;;3.0;ORDER ENTRY/RESULTS REPORTING;**10,92,141,187,215,243**;Dec 17, 1997;Build 242
  1. TXT(LST,DFN)    ; Return text of current & future diets for a patient
  1.  S LST(1)="Current Diet:  "_$$DIET^ORCDFH(DFN)
  1.  N FUTLST D FUT(.FUTLST,DFN) I $D(FUTLST)>1 D
  1.  . S LST(2)="Future Diet Orders:",ILST=2
  1.  . S I=0 F  S I=$O(FUTLST(I)) Q:'I  D
  1.  . . S X=$$FMTE^XLFDT(I,2)_"  "_$P(FUTLST(I),U,2)
  1.  . . S LST(ILST)=$S(ILST=2:"Future Diet Orders:  "_X,1:"   "_X)
  1.  . . S ILST=ILST+1
  1.  Q
  1. FUT(LST,DFN)    ; Return a list of future diet orders
  1.  N DGRP,NXTDT,ORIFN,ORVP,ORTX
  1.  S ORVP=DFN_";DPT(",DGRP=$O(^ORD(100.98,"B","DO",0)),NXTDT=$$NOW^XLFDT
  1.  F  S NXTDT=$O(^OR(100,"AW",ORVP,DGRP,NXTDT)) Q:NXTDT'>0  D
  1.  . S ORIFN=+$O(^OR(100,"AW",ORVP,DGRP,NXTDT,0))
  1.  . I $P($G(^OR(100,ORIFN,3)),U,3)'=8 Q  ; only scheduled diets
  1.  . D TEXT^ORQ12(.ORTX,ORIFN) S LST(NXTDT)=NXTDT_U_$G(ORTX(1))
  1.  Q
  1. PARAM(ORLST,ORVP,ORLOC)  ; Return dietetics parameters for a patient at a location
  1.  ; ORLOC: hospital location ptr to ^SC #44
  1.  ; ORLST(1)=EB1^EB2^EB3^LB1^LB2^LB3^EN1^EN2^...LE2^LE3
  1.  ; ORLST(2)=BAB^BAE^NAB^NAE^EAB^EAE^BegB^BegN^BegE^Bagged
  1.  ; ORLST(3)=type of service^RegIEN^NPOIEN^EarlyIEN^LateIEN^TFIFN
  1.  ; ORLST(4)=max days in future for outpatient recurring meals
  1.  ; ORLST(5)=default outpatient diet
  1.  Q:'+ORVP
  1.  N X,IEN,CURTM
  1.  S ORVP=+ORVP_";DPT(",ORLOC=+ORLOC
  1.  S CURTM=$$NOW^XLFDT
  1.  I +$G(^SC(ORLOC,42)) S ORLOC=$G(^SC(ORLOC,42))_";DIC(42"
  1.  E  S ORLOC=ORLOC_";SC("
  1.  D EN1^FHWOR8(ORLOC,.ORLST)
  1.  ;
  1.  I '$L($G(ORLST(3))) S ORLST(3)="T"
  1.  S $P(ORLST(3),U,2)=$O(^ORD(101.43,"S.DIET","REGULAR",0))
  1.  S $P(ORLST(3),U,3)=$O(^ORD(101.43,"S.DIET","NPO",0))
  1.  S $P(ORLST(3),U,4)=$O(^ORD(101.43,"S.E/L T","EARLY TRAY",0))
  1.  S $P(ORLST(3),U,5)=$O(^ORD(101.43,"S.E/L T","LATE TRAY",0))
  1.  N TF S TF=$$CURRENT^ORCDFH("TF") I $L(TF,";")=1 S TF=TF_";1"
  1.  I TF,'$$FUTURE^ORCDFH("EFFECTIVE DATE/TIME") S $P(ORLST(3),U,6)=TF
  1.  I $$VERSION^XPDUTL("FH")>5 D
  1.  . S ORLST(4)=$$MAXDAYS^FHOMAPI(ORLOC)
  1.  . D DIETLST^FHOMAPI Q:'$G(FHDIET(1))
  1.  . S IEN=$O(^ORD(101.43,"ID",$P(FHDIET(1),U,1)_";99FHD",0)) Q:+IEN=0
  1.  . S X=^ORD(101.43,"S.DIET",$P(FHDIET(1),U,2),IEN)
  1.  . I +$P(X,U,3),$P(X,U,3)<CURTM Q
  1.  . I $P($G(^ORD(101.43,IEN,"FH")),U)'="D",($P($G(^(0)),U)'="NPO") Q
  1.  . S ORLST(5)=+$G(IEN)
  1.  Q
  1. ATTR(REC,OI)    ; Return OI^Text^Type^Precedence^AskExpire for a diet
  1.  I $G(^ORD(101.43,OI,.1)),^(.1)'>$$NOW^XLFDT S REC="0^"_$P($G(^ORD(101.43,OI,0)),U)_" has been inactivated and may not be ordered anymore." Q
  1.  S REC=OI_U_$P($G(^ORD(101.43,OI,0)),U)_U_$G(^("FH"))
  1.  Q
  1. DIETS(Y,FROM,DIR)       ; Return a subset of active diets, including NPO
  1.  ; Y(n)=IEN^.01 Name^.01 Name  -or-  IEN^Synonym <.01 Name>^.01 Name
  1.  N I,IEN,CNT,X,CURTM
  1.  S I=0,CNT=44,CURTM=$$NOW^XLFDT
  1.  F  Q:I'<CNT  S FROM=$O(^ORD(101.43,"S.DIET",FROM),DIR) Q:FROM=""  D
  1.  . S IEN=0 F  S IEN=$O(^ORD(101.43,"S.DIET",FROM,IEN)) Q:'IEN  D
  1.  . . S X=^ORD(101.43,"S.DIET",FROM,IEN)
  1.  . . I +$P(X,U,3),$P(X,U,3)<CURTM Q
  1.  . . I $P($G(^ORD(101.43,IEN,"FH")),U)'="D",($P($G(^(0)),U)'="NPO") Q
  1.  . . S I=I+1
  1.  . . I 'X S Y(I)=IEN_U_$P(X,U,2)_U_$P(X,U,2)
  1.  . . E  S Y(I)=IEN_U_$P(X,U,2)_$C(9)_"<"_$P(X,U,4)_">"_U_$P(X,U,4)
  1.  Q
  1. OPDIETS(ORY,FROM,DIR)   ;Return a list of up to 5 outpatient diets from file 119.9
  1.  N X,I,J,IEN,CURTM,SYNCNT,SYNTOT,FHDIET
  1.  D DIETLST^FHOMAPI
  1.  S CURTM=$$NOW^XLFDT,I=0,SYNTOT=1
  1.  F  S I=$O(FHDIET(I)) Q:'I  D
  1.  . S IEN=$O(^ORD(101.43,"ID",$P(FHDIET(I),U,1)_";99FHD",0)) Q:+IEN=0
  1.  . S X=^ORD(101.43,"S.DIET",$P(FHDIET(I),U,2),IEN)
  1.  . I +$P(X,U,3),$P(X,U,3)<CURTM Q
  1.  . I $P($G(^ORD(101.43,IEN,"FH")),U)'="D",($P($G(^(0)),U)'="NPO") Q
  1.  . S X=$P(^ORD(101.43,IEN,0),U,1)
  1.  . S SYNCNT=$P($G(^ORD(101.43,IEN,2,0)),U,4),J=0
  1.  . S ORY(X)=IEN_U_X_U_X
  1.  . I +SYNCNT  D  Q
  1.  . . S SYNTOT=SYNTOT+SYNCNT
  1.  . . F  S J=$O(^ORD(101.43,IEN,2,J)) Q:'J  D
  1.  . . . S ORY(^ORD(101.43,IEN,2,J,0))=IEN_U_^ORD(101.43,IEN,2,J,0)_$C(9)_"<"_X_">"_U_X
  1.  Q
  1. TFPROD(Y)     ; Return a list of active tubefeeding products
  1.  N I,IEN,NAM,X,CURTM
  1.  S I=0,NAM="",CURTM=$$NOW^XLFDT
  1.  F  S NAM=$O(^ORD(101.43,"S.TF",NAM)) Q:NAM=""  D
  1.  . S IEN=0 F  S IEN=$O(^ORD(101.43,"S.TF",NAM,IEN)) Q:'IEN  D
  1.  . . S X=^ORD(101.43,"S.TF",NAM,IEN)
  1.  . . I +$P(X,U,3),$P(X,U,3)<CURTM Q
  1.  . . S I=I+1
  1.  . . I 'X S Y(I)=IEN_U_$P(X,U,2)_U_$P(X,U,2)
  1.  . . E  S Y(I)=IEN_U_$P(X,U,2)_$C(9)_"<"_$P(X,U,4)_">"_U_$P(X,U,4)
  1.  Q
  1. QTY2CC(VAL,PRD,STR,QTY)     ; Return cc's given a product, strength, & quantity
  1.  N X,VQTY,DUR
  1.  S VQTY=$$VALIDQTY^ORCDFHTF(QTY) I '$L(VQTY)!('PRD)!('STR) S VAL="" Q
  1.  S PRD=+$P($G(^ORD(101.43,PRD,0)),U,2)
  1.  S DUR=$P(VQTY," X ",2) I $L(DUR) S DUR=$S(DUR["H":"H",1:"X")_+DUR
  1.  S X=+VQTY_"&"_$E($P(VQTY," ",2))_U_$P($P(VQTY,"/",2)," ")_U_DUR
  1.  S VAL=$$QUAN^FHWOR5R(PRD_"-"_STR,X)_U_VQTY
  1.  Q
  1. FINDTYP(VAL,DGRP)       ; Return type of dietetics order based on display group
  1.  S VAL=$P($G(^ORD(100.98,DGRP,0)),U,3)
  1.  S:VAL="D AO" VAL="A" S VAL=$E(VAL)
  1.  Q
  1. ISOIEN(VAL)     ; Return IEN for the Isolation/Precaution orderable item
  1.  S VAL=$O(^ORD(101.43,"S.PREC","ISOLATION PROCEDURES",0))
  1.  Q
  1. CURISO(VAL,ORVP) ; Return a patient's current isolation
  1.  S ORVP=ORVP_";DPT(" S VAL=$P($$IP^ORMBLD,U,2)
  1.  I '$L(VAL) S VAL="<none>"
  1.  Q
  1. ISOLIST(LST)    ; Return list of active isolations/precautions
  1.  N I,X,IEN
  1.  S I=0,X="" F  S X=$O(^FH(119.4,"B",X)) Q:X=""  S IEN=$O(^(X,0)) D
  1.  . I '$D(^FH(119.4,IEN,"I")) S I=I+1,LST(I)=IEN_U_X
  1.  Q
  1. MILTM(X)        ; return military time for am/pm time
  1.  N TM
  1.  S TM=$P(X,":",1)_+$P(X,":",2)
  1.  I X["P",TM<1200 S TM=TM+1200
  1.  I X["A",TM>1200 S TM=TM-1200
  1.  Q TM
  1.  ;
  1. ASKLATE(REC,DFN,ORIFN)        ; Return info for ordering late tray for diet order
  1.  ; REC=0  or  1^meal^bagged^time^time^time
  1.  S REC=0 Q:'$G(ORIFN)  Q:$E($$VALUE^ORX8(ORIFN,"ORDERABLE",1,"E"),1,3)="NPO"
  1.  N X,Y,%DT,STRT,DATE,ORPARAM,I,MEAL,MEALTIME
  1.  S X=$O(^OR(100,ORIFN,4.5,"ID","START",0)),X=$G(^OR(100,ORIFN,4.5,+X,1))
  1.  Q:X=""  S %DT="TX" D ^%DT Q:Y'>0  Q:$P(Y,".")>DT  ;invalid or future
  1.  S DATE=$P(Y,"."),STRT=+$E($P(Y,".",2)_"0000",1,4),MEAL=0
  1.  D EN^FHWOR8(DFN,.ORPARAM) Q:'$D(ORPARAM(2))
  1.  F I=1,3,5 I $P(ORPARAM(2),U,I)<STRT,STRT<$P(ORPARAM(2),U,I+1) S MEAL=I Q
  1.  S MEAL=$S(MEAL=1:4,MEAL=3:10,MEAL=5:16,1:0) Q:'MEAL
  1.  S MEALTIME=$P(ORPARAM(1),U,MEAL,MEAL+2)
  1.  S MEAL=$S(MEAL=4:"B",MEAL=10:"N",MEAL=16:"E",1:"")
  1.  F I=1:1:3 S X=$$MILTM($P(MEAL,U,I)) I X<STRT S $P(MEAL,U,I)=""
  1.  S REC="1"_U_MEAL_U_$P(ORPARAM(2),U,10)_U_MEALTIME
  1.  I $P(REC,U,2,4)="^^" S REC=0
  1.  Q
  1. ADDLATE(REC,ORVP,ORNP,ORL,MEAL,TIME,BAG)      ; Add late tray order
  1.  N ORIFN,ORNEW,ORDUZ,ORSTS,OREVENT,ORCAT,ORDA,ORTS,ORCHECK,ORLOG
  1.  N ORDIALOG,ORDG,ORTYPE,DA,FIRST,TRAY
  1.  S ORVP=ORVP_";DPT(",ORL(2)=ORL_";SC(",ORL=ORL(2)
  1.  S ORTYPE="D",FIRST=1,ORDUZ=DUZ,ORLOG=+$E($$NOW^XLFDT,1,12)
  1.  S TRAY=+$O(^ORD(101.43,"S.E/L T","LATE TRAY",0))
  1.  S ORDIALOG=$O(^ORD(101.41,"AB","FHW2",0))
  1.  D GETDLG^ORCD(ORDIALOG)
  1.  S ORDIALOG($$PTR^ORCD("OR GTX MEAL"),1)=MEAL
  1.  S ORDIALOG($$PTR^ORCD("OR GTX ORDERABLE ITEM"),1)=TRAY
  1.  S ORDIALOG($$PTR^ORCD("OR GTX START DATE"),1)=DT
  1.  S ORDIALOG($$PTR^ORCD("OR GTX STOP DATE"),1)=DT
  1.  S ORDIALOG($$PTR^ORCD("OR GTX MEAL TIME"),1)=TIME
  1.  S ORDIALOG($$PTR^ORCD("OR GTX YES/NO"),1)=BAG
  1.  D EN^ORCSAVE
  1.  S REC="" I ORIFN D GETBYIFN^ORWORR(.REC,ORIFN)
  1.  Q
  1. CURMEALS(ORY,ORDFN,ORMEAL)     ;Return current list of recurring meals for AO and TF orders
  1.  N I,Y,X S I=0
  1.  S ORMEAL=$G(ORMEAL,"")
  1.  D EN2^FHWOR8(ORDFN,ORMEAL,.ORY)
  1.  F  S I=$O(ORY(I)) Q:'I  D
  1.  . S X=$P(ORY(I),U,2)
  1.  . S Y=$P(ORY(I),U,1) D DD^%DT S $P(ORY(I),U,2)=Y
  1.  . S $P(ORY(I),U,3)=$S(X="B":"Breakfast",X="N":"Noon",X="E":"Evening",1:"")
  1.  Q
  1. NFSLOC(ORLOC) ;Get NUTRITION LOCATION name for HOSPITAL LOCATION
  1.  Q $$NFSLOC^FHOMAPI(ORLOC)
  1. OPLOCOK(ORY,ORLOC) ; OK to order OP Meals from this location
  1.  I 'ORLOC S ORY=0 Q
  1.  S ORY=$S($L($$NFSLOC^FHOMAPI(ORLOC))>0:1,1:0)
  1.  Q