Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: ORWDXM1

ORWDXM1.m

Go to the documentation of this file. 
  1. ORWDXM1 ; SLC/KCM - Order Dialogs, Menus;04-Jun-2010 14:12;PLS
  1.  ;;3.0;ORDER ENTRY/RESULTS REPORTING;**10,85,131,132,141,178,185,187,1002,1004,215,243,1010**;Dec 17, 1997;Build 47
  1.  ;Modified - IHS/MSC/PLS - 5/14/2010 - Line BLDQRSP+25
  1.  ;                         6/04/2010   Line BLDQRSP+136
  1. BLDQRSP(LST,ORIT,FLDS,ISIMO,ENCLOC) ; Build responses for an order
  1.  ; LST=QuickLevel^ResponseID(ORIT;$H)^Dialog^Type^FormID^DGrp
  1.  ; LST(n)=verify text or reject text
  1.  ; ORIT= ptr to 101.41 for quick order, 100 for copy
  1.  ;       1   2    3    4   5   6    7    8        11-20
  1.  ; FLDS=DFN^LOC^ORNP^INPT^SEX^AGE^EVENT^SC%^^^Key Variables...
  1.  ; ORIT=+ORIT: ptr to 101.41, $E(ORIT)=C: copy $E(ORIT)=X: change
  1.  ; !! SHOULD CHECK for PRE-CPRS ORDERS (treat as text?)
  1.  K ^TMP("ORWDXMQ",$J)
  1.  N ORWMODE ; 0:Dialog,Quick 1:copy order 2:change order
  1.  N TEMPCAT ; patient category from DPT file
  1.  N ISXFER ; Transfer order?
  1.  N ORIMO ;If IMO(inpatient medication on outpatient)
  1.  N TEMPORIT
  1.  N ADMLOC,PATLOC,ORDLOC,LEVEL,DELAY,SCHLOC,SCHTYP
  1.  S PATLOC=$P(FLDS,U,2)
  1.  S ORDLOC=$S(ORIT["C":+$P($G(^OR(100,+$P(ORIT,"C",2),0)),U,10),1:0)
  1.  S ORIMO=$G(ISIMO)
  1.  S ORWMODE=0,ISXFER=""
  1.  S:$E(ORIT)="C" ORWMODE=1 S:$E(ORIT)="T" ORWMODE=1,ISXFER=";T" ;treat xfer as copy for now
  1.  S:$E(ORIT)="X" ORWMODE=2
  1.  S:$E(ORIT)="P" ORWMODE=3  ; IHS/CIA/DKM - Added to support med processing function
  1.  S TEMPORIT=ORIT
  1.  I ORWMODE S ORIT=$E(ORIT,2,999)
  1.  S LST(0)=""
  1.  ; IHS/CIA/DKM - Modified next 2 lines
  1.  ;D CHKDSBL^ORWDXM3(.LST,ORIT,ORWMODE) Q:+LST(0)=8  ;disable
  1.  ;D CHKVACT^ORWDXM3(.LST,ORIT,ORWMODE,$P(FLDS,U,3)) Q:+LST(0)=8  ;action
  1.  D:ORWMODE'=3 CHKDSBL^ORWDXM3(.LST,ORIT,ORWMODE) Q:+LST(0)=8  ;disable
  1.  D:ORWMODE'=3 CHKVACT^ORWDXM3(.LST,ORIT,ORWMODE,$P(FLDS,U,3)) Q:+LST(0)=8  ;action
  1.  I ORWMODE=1 D CHKCOPY^ORWDXM3(.LST,ORIT,FLDS) Q:+LST(0)=8  ;no copy
  1.  I ORWMODE=2 D BLD4CHG^ORWDXM3(.LST,ORIT,FLDS) Q  ;change
  1.  I 'ORWMODE,($P(^ORD(101.41,+ORIT,0),U,4)="D"),'($O(^DIC(9.4,"C","OR",0))[$P(^ORD(101.41,+ORIT,0),U,7)) S LST(0)="0^0^"_$$DLGINFO^ORWDXM3(ORIT,ORWMODE_ISXFER) Q
  1.  ;radilogy vars
  1.  N ORIMTYPE
  1.  ;blood bank vars
  1.  N ORCOMP,ORTAS
  1.  ;lab vars
  1.  N LRFZX,LRFSAMP,LRFSPEC,LRFDATE,LRFURG,LRFSCH
  1.  N ORTIME,ORCOLLCT,ORMAX,ORTEST,ORIMTIME,ORSMAX,ORSTMS,ORSCH
  1.  ;pharmacy vars
  1.  N PSJNOPC,ORMORE,ORINPT,ORXNP,ORSCHED,ORQTY,ORNOUNS,ORXNP,OREFILLS
  1.  N ORCOMPLX,ORQTY,ORCOPAY,ORDRUG,ORWPSPIK,ORWPSWRG,ORSD,ORDSUP,ORWP94
  1.  ;dietetics vars
  1.  N ORPARAM,ORNPO,ORTIME,ORMEAL,ORTRAY,ORDATE
  1.  ;consults vars
  1.  N GMRCNOPD,GMRCNOAT,GMRCREAF
  1.  ; setup general env
  1.  N ORTYPE,ORVP,ORL,ORNP,ORSEX,ORAGE,ORWARD,OREVENT,ORDIV,ORSC,KEYVAR
  1.  N ORDG,ORDIALOG,ORCAT,FIRST,ORQUIT,X,ORTRAIL,ORLEAD,RSPREF,AUTOACK
  1.  N OREVNTYP
  1.  S ORWP94=$O(^ORD(101.41,"AB","PS MEDS",0))>0
  1.  S ORVP=$P(FLDS,U,1)_";DPT(",ORNP=+$P(FLDS,U,3),ORSC=$P(FLDS,U,8)
  1.  S ORL=$P(FLDS,U,2)_";SC(",ORL(2)=ORL
  1.  S ORSEX=$P(FLDS,U,5),ORAGE=$P(FLDS,U,6),ORTYPE="Q",FIRST=1
  1.  I $P(FLDS,U,4),$G(^SC(+ORL,42)) S ORWARD=+^SC(+ORL,42)
  1.  I $L($P(FLDS,U,7))  D
  1.  . S OREVENT=$P(FLDS,U,7)
  1.  . S OREVNTYP=$P(OREVENT,";",2)
  1.  . S OREVENT("TS")=$P(OREVENT,";",3)
  1.  . S OREVENT("EFFECTIVE")=$P(OREVENT,";",4)
  1.  . S OREVENT=+$P(OREVENT,";",1)
  1.  I 'ORWMODE D
  1.  . D SETKEYV^ORWDXM3($P(FLDS,U,11,20)) ; from menu path
  1.  . S KEYVAR=$$KEYVAR^ORWDXM3(ORIT) ; from entry action
  1.  . D SETKEYV^ORWDXM3(KEYVAR)
  1.  K ^TMP("ORWORD",$J)
  1.  ; init return record based on auto-accept
  1.  I ORWMODE S LST(0)="2^"_ORIT ;verify on copy
  1.  E  S LST(0)=+$P($G(^ORD(101.41,ORIT,5)),U,8)_U_ORIT
  1.  S TEMPCAT=$S($L($P($G(^DPT(+ORVP,.1)),U)):"I",1:"O")
  1.  I TEMPCAT="I",+$P(FLDS,U,4)=1,$E(TEMPORIT)="C",$P($G(^ORD(100.98,$P($G(^OR(100,+ORIT,0)),U,11),0)),U)="OUTPATIENT MEDICATIONS" S TEMPCAT="O"
  1.  I $L($G(OREVNTYP)) D
  1.  . S ORCAT=$S(OREVNTYP="A":"I",OREVNTYP="T":"I",OREVNTYP="O":TEMPCAT,OREVNTYP="M":TEMPCAT,OREVNTYP="C":TEMPCAT,1:"O") I $G(OREVENT) D
  1.  .. N X S X=$$EVT^OREVNTX(OREVENT),X=$P($G(^ORD(100.5,+X,0)),U,7)
  1.  .. I OREVNTYP="T",X,X<4 S ORCAT="O" ;To pass=outpt
  1.  .. I OREVNTYP="D",X=41 S ORCAT="I" ;From ASIH=inpt
  1.  E  S ORCAT=TEMPCAT
  1.  D SETUP^ORWDXM4 Q:+LST(0)=8
  1.  S X="OR GTX START DATE"_$S($G(ORWP94):"/TIME",1:"")
  1.  I ORWMODE,(ORDG=+$O(^ORD(100.98,"B","O RX",0))) D  ;remove old values
  1.  . K ORDIALOG($$PTR^ORCD(X),1)
  1.  . I ORWMODE=2,$$DRAFT^ORWDX2(ORIT) Q  ;keep comments
  1.  . K:ISXFER'["T" ORDIALOG($$PTR^ORCD("OR GTX WORD PROCESSING 1"),1)
  1.  D SETUPS^ORWDXM4 ;moved to save space, expects X
  1.  Q:+LST(0)=8
  1.  I $G(ORQUIT) S LST(0)="0^0^"_$$DLGINFO^ORWDXM3(ORIT,ORWMODE_ISXFER)_"^"_$G(KEYVAR) Q
  1.  N SEQ,DA,XCODE,MUSTASK,PROMPT,INST,KEY,IVFID
  1.  S IVFID=$O(^ORD(101.41,"B","PSJI OR PAT FLUID OE",0))
  1.  S AUTOACK=$S($D(ORWPSWRG):0,1:1)
  1.  S SEQ=0 F  S SEQ=$O(^ORD(101.41,+ORDIALOG,10,"B",SEQ)) Q:'SEQ  D
  1.  . S DA=0 F  S DA=$O(^ORD(101.41,+ORDIALOG,10,"B",SEQ,DA)) Q:'DA  D
  1.  . . ; skip if this is a child prompt
  1.  . . I $P(^ORD(101.41,+ORDIALOG,10,DA,0),U,11) Q
  1.  . . ; set default for prompt, see if needs to be interactive
  1.  . . S PROMPT=$P(^ORD(101.41,+ORDIALOG,10,DA,0),U,2)
  1.  . . D SETITEM(DA,PROMPT,1,.MUSTASK)
  1.  . . I MUSTASK S AUTOACK=0 Q
  1.  . . ; iterate through the child items if parent and edit only
  1.  . . Q:'$D(^ORD(101.41,+ORDIALOG,10,"DAD",PROMPT))
  1.  . . N CSEQ,CDA,CPROMPT,INST,ORQUIT
  1.  . . S CSEQ=0 F  S CSEQ=$O(^ORD(101.41,+ORDIALOG,10,"DAD",PROMPT,CSEQ)) Q:'CSEQ  D  Q:$G(ORQUIT)
  1.  . . . S CDA=$O(^ORD(101.41,+ORDIALOG,10,"DAD",PROMPT,CSEQ,0))
  1.  . . . S CPROMPT=$P(^ORD(101.41,+ORDIALOG,10,CDA,0),U,2)
  1.  . . . ; if req & no instances then need interaction
  1.  . . . I $P(^ORD(101.41,+ORDIALOG,10,CDA,0),U,6),ORDIALOG'=IVFID,'$O(ORDIALOG(CPROMPT,0)) S AUTOACK=0
  1.  . . . S INST=0 F  S INST=$O(ORDIALOG(CPROMPT,INST)) Q:'INST  D
  1.  . . . . N ORASK D VBASK^ORWDXM4(INST) ; set ORASK for VBECS
  1.  . . . . ; set default for each child prompt, if necessary
  1.  . . . . D SETITEM(CDA,CPROMPT,INST,.MUSTASK)
  1.  . . . . ; if no val & child prmpt required then need interaction
  1.  . . . . I MUSTASK,$P(^ORD(101.41,+ORDIALOG,10,CDA,0),U,6) S AUTOACK=0
  1.  N IVDLG
  1.  S IVDLG=$O(^ORD(101.41,"AB","PSJI OR PAT FLUID OE",0))
  1.  I $$ISMED(ORIT),(ORDIALOG'=IVDLG),(ORCAT="I") D
  1.  . F P="PATIENT INSTRUCTIONS","START DATE/TIME","DAYS SUPPLY","QUANTITY","REFILLS","ROUTING","SERVICE CONNECTED" K ORDIALOG($$PTR(P),1)
  1.  S KEY=$S(ORWMODE:"C",1:"")_ORIT_"-"_$P($H,",",2),SEQ=0
  1.  I $$ISINPMED(ORIT) D
  1.  .S LEVEL=$P(LST(0),U),DELAY=$S($P($G(OREVENT),";")>0:1,1:0)
  1.  .I LEVEL=2!(ISIMO) D ADMTIME^ORWDXM2(ORDLOC,PATLOC,ENCLOC,DELAY,ISIMO)
  1.  I ($$ISMED(ORIT)),'($$VALQO^ORWDXM3(ORIT)) S AUTOACK=0
  1.  S PROMPT=0 F  S PROMPT=$O(ORDIALOG(PROMPT)) Q:'PROMPT  D
  1.  . I '$D(^ORD(101.41,ORDIALOG,10,"D",PROMPT)) K ORDIALOG(PROMPT) Q
  1.  . S INST=0 F  S INST=$O(ORDIALOG(PROMPT,INST)) Q:'INST  D
  1.  . . S SEQ=SEQ+1,^TMP("ORWDXMQ",$J,KEY,SEQ,0)=U_PROMPT_U_INST
  1.  . . ; save word processing value
  1.  . . I $E(ORDIALOG(PROMPT,0))="W",$L(ORDIALOG(PROMPT,INST)) D
  1.  . . .  M ^TMP("ORWDXMQ",$J,KEY,SEQ,2)=@ORDIALOG(PROMPT,INST)
  1.  . . ; save other value types
  1.  . . E  S ^TMP("ORWDXMQ",$J,KEY,SEQ,1)=ORDIALOG(PROMPT,INST)
  1.  I AUTOACK D
  1.  . I ORWMODE S AUTOACK=2
  1.  . I 'ORWMODE,($P(^ORD(101.41,ORIT,0),U,8)!'LST(0)) S AUTOACK=2
  1.  ;I ($$ISMED(ORIT)),'($$VALQO^ORWDXM3(ORIT)) S AUTOACK=0
  1.  I ORIMO,ORWMODE S AUTOACK=2
  1.  ; added to accept Herbal/OTC/NonVA Med quick orders
  1.  I ORWMODE'=3,$L($G(^ORD(101.41,+ORIT,0))),($P(^ORD(100.98,$P(^ORD(101.41,+ORIT,0),U,5),0),U,3)="NV RX"),($P($G(^ORD(101.41,+ORIT,5)),U,8)) S AUTOACK=1
  1.  ;I $G(^OR(100,+ORIT,0)),$P($G(^ORD(101.41,+$P(^OR(100,+ORIT,0),U,5),0)),U,8),$D(ORDIALOG("B","HERBAL/OTC/NON VA MEDICATION")) S AUTOACK=1
  1.  I AUTOACK=2,$$ISMED(ORIT),(ORDIALOG=IVDLG),$$VERORD^ORWDXM3=0 S AUTOACK=0
  1.  I AUTOACK=2 D VERTXT^ORWDXM2
  1.  S LST(0)=AUTOACK_U_KEY_U_$$DLGINFO^ORWDXM3(ORIT,ORWMODE_ISXFER)_"^"_$G(KEYVAR)
  1.  I $P(LST(0),U,4)="D" S $P(LST(0),U,4)="Q"
  1.  I ORWMODE=1 S $P(LST(0),U,4)="C"
  1.  K ^TMP("ORWORD",$J)
  1.  K ^TMP("PSJINS",$J),^TMP("PSJMR",$J),^TMP("PSJNOUN",$J)
  1.  Q
  1. SETITEM(DA,PROMPT,INST,MUSTASK) ; set default value & return if must prompt
  1.  N EDITONLY,Y,VALIV,XCODE
  1.  S MUSTASK=0,EDITONLY=0,VALIV=0
  1.  I $D(^TMP("ORWDHTM",$J,ORDIALOG,PROMPT)) D
  1.  . I $E(ORDIALOG(PROMPT,0))="W" D
  1.  . . S ^TMP("ORWORD",$J,PROMPT,INST,1,0)=^TMP("ORWDHTM",$J,ORDIALOG,PROMPT)
  1.  . . S ORDIALOG(PROMPT,INST)="^TMP(""ORWORD"","_$J_","_PROMPT_","_INST_")"
  1.  . E  S ORDIALOG(PROMPT,INST)=^TMP("ORWDHTM",$J,ORDIALOG,PROMPT)
  1.  I $D(^TMP("ORWDHTM",$J,ORIT,PROMPT)) D
  1.  . S ORDIALOG(PROMPT,INST)=^TMP("ORWDHTM",$J,ORIT,PROMPT)
  1.  . ; NEED TO CLEAN UP ^TMP("ORWDHTM") after process order set!!!
  1.  ;
  1.  ; skip if a value already exists for this prompt and not WP
  1.  Q:$D(ORDIALOG(PROMPT,INST))&($E(ORDIALOG(PROMPT,0))'="W")
  1.  ; execute default action if no value in QO, checking EDITONLY afterwards
  1.  I '$D(ORDIALOG(PROMPT,INST)) D
  1.  . ;
  1.  . ;Intermittent IV orders do not require a solution or an infusion rate
  1.  . I PROMPT=$$PTR("INFUSION RATE"),$$GETIVTYP^ORWDXM3="I" S VALIV=1 Q
  1.  . I PROMPT=$$PTR("ORDERABLE ITEM"),$$GETIVTYP^ORWDXM3="I" S VALIV=1 Q
  1.  . I $E(ORDIALOG(PROMPT,0))="W",$D(^ORD(101.41,+ORDIALOG,10,DA,8))>9 D
  1.  . . M ^TMP("ORWORD",$J,PROMPT,INST)=^ORD(101.41,+ORDIALOG,10,DA,8)
  1.  . . S ORDIALOG(PROMPT,INST)="^TMP(""ORWORD"","_$J_","_PROMPT_","_INST_")"
  1.  . E  D
  1.  . . S XCODE=$$SUBCODE($G(^ORD(101.41,+ORDIALOG,10,DA,7)))
  1.  . . I $L(XCODE) X XCODE S:$D(Y) ORDIALOG(PROMPT,INST)=Y
  1.  Q:VALIV=1
  1.  Q:$G(EDITONLY)
  1.  I 'ORWMODE,$P($G(^ORD(101.41,+ORDIALOG,10,DA,0)),U,8) Q
  1.  I ORWMODE,($P($G(^ORD(101.41,+ORDIALOG,10,DA,0)),U,9)'["W"),'$P($G(^ORD(101.41,+ORDIALOG,10,DA,0)),U,6)!$D(ORDIALOG(PROMPT,INST)) Q
  1.  I 'ORWMODE,LST(0),$D(ORDIALOG(PROMPT,INST)),($E(ORDIALOG(PROMPT,0))="W") Q
  1.  I 'ORWMODE,LST(0),'$P($G(^ORD(101.41,+ORDIALOG,10,DA,0)),U,6) Q
  1.  S XCODE=$$SUBCODE($G(^ORD(101.41,+ORDIALOG,10,DA,3)))
  1.  I $L(XCODE) X XCODE Q:'$T
  1.  S MUSTASK=1
  1.  Q
  1. SUBCODE(X) ; substitute code
  1.  I X["$$REQDCOMM^ORCDLR" Q "I $$LRRQCM^ORWDXM2"
  1.  I X["$$ASKSAMP^ORCDLR" Q "I $$LRASMP^ORWDXM2"
  1.  I X["$$SCHEDULD^ORCDRA1" Q "I $$SCHEDULD^ORWDXM2"
  1.  I X["(^PSX(550,""C"")" Q "S Y=$E($$DEFPICK^ORWDPS32) K:'$L(Y) Y"
  1.  I X["I $$ASKURG^ORCDVBEC" Q "I 1"
  1.  I X["K:$G(ORASK)" Q "I $G(ORASK)"
  1.  Q X
  1. PTR(NAME) ; -- Returns pointer to OR GTX NAME
  1.  Q +$O(^ORD(101.41,"AB",$E("OR GTX "_NAME,1,63),0))
  1.  ;
  1. ISINPMED(IFN) ;
  1.  N PKG,RESULT,Y
  1.  I 'ORWMODE S PKG=$P($G(^ORD(101.41,IFN,0)),U,7)
  1.  E  S PKG=$P($G(^OR(100,+IFN,0)),U,14)
  1.  S Y=$$GET1^DIQ(9.4,+PKG_",",1)
  1.  S RESULT=$S($E(Y,1,3)="PSJ":1,1:0)
  1.  Q RESULT
  1.  ;
  1. ISMED(IFN) ; return 1 if pharmacy order dlg used
  1.  N PKG
  1.  I 'ORWMODE S PKG=$P($G(^ORD(101.41,IFN,0)),U,7)
  1.  E  S PKG=$P($G(^OR(100,+IFN,0)),U,14)
  1.  Q $$NMSP^ORCD(PKG)="PS"
  1. SITEVAL() ;return 1 if site does want the reason for study to carry through from past orders of this ordering session
  1.  I $$GET^XPAR("ALL","OR RA RFS CARRY ON")=0 Q 0
  1.  Q 1
  1. SVRPC(RET,X) ;RPC FOR SITEVAL
  1.  S RET=$$SITEVAL
  1.  Q