Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: ORWPCE1

ORWPCE1.m

Go to the documentation of this file. 
  1. ORWPCE1 ;SLC/KCM - PCE Calls from CPRS GUI; 10/26/04 ;4/9/08  07:44
  1.  ;;3.0;ORDER ENTRY/RESULTS REPORTING;**10,85,116,132,148,187,190,215,243**;Dec 17, 1997;Build 242
  1.  ;
  1.  ; DBIA 1365   DSELECT^GMPLENFM   ^TMP("IB",$J)
  1.  ;
  1. GETVSIT(VSTR,DFN) ; lookup a visit
  1.  N PKG,SRC,ORPXAPI,OK,ORVISIT
  1.  S PKG=$O(^DIC(9.4,"B","ORDER ENTRY/RESULTS REPORTING",0))
  1.  S SRC="TEXT INTEGRATION UTILITIES"
  1.  S ORPXAPI("ENCOUNTER",1,"ENC D/T")=$P(VSTR,";",2)
  1.  S ORPXAPI("ENCOUNTER",1,"PATIENT")=DFN
  1.  S ORPXAPI("ENCOUNTER",1,"HOS LOC")=+VSTR
  1.  S ORPXAPI("ENCOUNTER",1,"SERVICE CATEGORY")=$P(VSTR,";",3)
  1.  S ORPXAPI("ENCOUNTER",1,"ENCOUNTER TYPE")="P"
  1.  S OK=$$DATA2PCE^PXAPI("ORPXAPI",PKG,SRC,.ORVISIT)
  1.  Q ORVISIT
  1. DQDEL ; background call to DATA2PCE and DELVFILE
  1.  N VISIT,VAL
  1.  I $D(ZTQUEUED) S ZTREQ="@"
  1.  S VISIT=$$GETVSIT(VSTR,DFN)
  1.  S VAL=$$DELVFILE^PXAPI("ALL",VISIT,"","TEXT INTEGRATION UTILITIES")
  1.  S ZTSTAT=0  ; clear sync flag
  1.  Q
  1. DQSAVE ; Background Call to DATA2PCE
  1.  N PKG,SRC,TYP,CODE,IEN,OK,I,X,ORPXAPI,ORPXDEL
  1.  N CAT,NARR,ROOT,ROOT2,ORAVST
  1.  N PRV,CPT,ICD,IMM,SK,PED,HF,XAM,TRT,MOD,MODCNT,MODIDX,MODS
  1.  N COM,COMMENT,COMMENTS
  1.  N DFN,PROBLEMS,PXAPREDT,ORCPTDEL
  1.  I $D(ZTQUEUED) S ZTREQ="@"
  1.  S PKG=$O(^DIC(9.4,"B","ORDER ENTRY/RESULTS REPORTING",0))
  1.  S SRC="TEXT INTEGRATION UTILITIES"
  1.  S (PRV,CPT,ICD,IMM,SK,PED,HF,XAM,TRT)=0
  1.  S I="" F  S I=$O(PCELIST(I)) Q:'I  S X=PCELIST(I) D
  1.  . S X=PCELIST(I),TYP=$P(X,U),CODE=$P(X,U,2),CAT=$P(X,U,3),NARR=$P(X,U,4)
  1.  . I $E(TYP,1,3)="PRV" D  Q
  1.  . . Q:'$L(CODE)
  1.  . . S PRV=PRV+1
  1.  . . S ROOT="ORPXAPI(""PROVIDER"","_PRV_")"
  1.  . . S ROOT2="ORPXDEL(""PROVIDER"","_PRV_")"
  1.  . . I $E(TYP,4)'="-" D
  1.  . . . S @ROOT@("NAME")=CODE
  1.  . . . S @ROOT@("PRIMARY")=$P(X,U,6)
  1.  . . S @ROOT2@("NAME")=CODE
  1.  . . S @ROOT2@("DELETE")=1
  1.  . . S PXAPREDT=1 ;Allow edit of primary flag
  1.  . I TYP="VST" D  Q
  1.  . . S ROOT="ORPXAPI(""ENCOUNTER"",1)"
  1.  . . I CODE="DT" S @ROOT@("ENC D/T")=$P(X,U,3) Q
  1.  . . I CODE="PT" S @ROOT@("PATIENT")=$P(X,U,3),DFN=$P(X,U,3) Q
  1.  . . I CODE="HL" S @ROOT@("HOS LOC")=$P(X,U,3) Q
  1.  . . I CODE="PR" S @ROOT@("PARENT")=$P(X,U,3) Q
  1.  . . ;prevents checkout!
  1.  . . I CODE="VC" S @ROOT@("SERVICE CATEGORY")=$P(X,U,3) Q
  1.  . . I CODE="SC" S @ROOT@("SC")=$P(X,U,3) Q
  1.  . . I CODE="AO" S @ROOT@("AO")=$P(X,U,3) Q
  1.  . . I CODE="IR" S @ROOT@("IR")=$P(X,U,3) Q
  1.  . . I CODE="EC" S @ROOT@("EC")=$P(X,U,3) Q
  1.  . . I CODE="MST" S @ROOT@("MST")=$P(X,U,3) Q
  1.  . . I CODE="HNC" S @ROOT@("HNC")=$P(X,U,3) Q
  1.  . . I CODE="CV" S @ROOT@("CV")=$P(X,U,3) Q
  1.  . . I CODE="SHD" S @ROOT@("SHAD")=$P(X,U,3) Q
  1.  . . I CODE="OL" D  Q
  1.  . . . I +$P(X,U,3) S @ROOT@("INSTITUTION")=$P(X,U,3)
  1.  . . . E  I $P(X,U,4)'="",$P(X,U,4)'="0" D
  1.  . . . . I $$PATCH^XPDUTL("PX*1.0*96") S @ROOT@("OUTSIDE LOCATION")=$P(X,U,4)
  1.  . . . . E  S @ROOT@("COMMENT")="OUTSIDE LOCATION:  "_$P(X,U,4)
  1.  . I $E(TYP,1,3)="CPT" D  Q
  1.  . . Q:'$L(CODE)
  1.  . . S CPT=CPT+1,ROOT="ORPXAPI(""PROCEDURE"","_CPT_")"
  1.  . . S IEN=+$O(^ICPT("B",CODE,0))
  1.  . . S @ROOT@("PROCEDURE")=IEN
  1.  . . I +$P(X,U,9) D
  1.  . . . S MODS=$P(X,U,9),MODCNT=+MODS
  1.  . . . F MODIDX=1:1:MODCNT D
  1.  . . . . S MOD=$P($P(MODS,";",MODIDX+1),"/")
  1.  . . . . S @ROOT@("MODIFIERS",MOD)=""
  1.  . . S:$L(CAT) @ROOT@("CATEGORY")=CAT
  1.  . . S:$L(NARR) @ROOT@("NARRATIVE")=NARR
  1.  . . S:$L($P(X,U,5)) @ROOT@("QTY")=$P(X,U,5)
  1.  . . S:$P(X,U,6)>0 @ROOT@("ENC PROVIDER")=$P(X,U,6)
  1.  . . S:$L($P(X,U,10))>0 COMMENT($P(X,U,10))="PROCEDURE^"_CPT
  1.  . . I $E(TYP,4)="-" S @ROOT@("DELETE")=1,@ROOT@("QTY")=0,ORCPTDEL=CPT
  1.  . I $E(TYP,1,3)="POV" D  Q
  1.  . . Q:'$L(CODE)
  1.  . . S ICD=ICD+1,ROOT="ORPXAPI(""DX/PL"","_ICD_")"
  1.  . . S IEN=+$O(^ICD9("AB",CODE_" ",0))
  1.  . . S @ROOT@("DIAGNOSIS")=IEN
  1.  . . S @ROOT@("PRIMARY")=$P(X,U,5)
  1.  . . S:$L(CAT) @ROOT@("CATEGORY")=CAT
  1.  . . S:$L(NARR) @ROOT@("NARRATIVE")=NARR
  1.  . . S:$P(X,U,6)>0 @ROOT@("ENC PROVIDER")=$P(X,U,6)
  1.  . . I $L($P(X,U,7)),$P(X,U,7)=1 S @ROOT@("PL ADD")=$P(X,U,7),PROBLEMS(ICD)=NARR_U_CODE
  1.  . . S:$L($P(X,U,10))>0 COMMENT($P(X,U,10))="DX/PL^"_ICD
  1.  . . I $E(TYP,4)="-" S @ROOT@("DELETE")=1
  1.  . I $E(TYP,1,3)="IMM" D  Q
  1.  . . Q:'$L(CODE)
  1.  . . S IMM=IMM+1,ROOT="ORPXAPI(""IMMUNIZATION"","_IMM_")"
  1.  . . S @ROOT@("IMMUN")=CODE
  1.  . . S:$L($P(X,U,5)) @ROOT@("SERIES")=$P(X,U,5)
  1.  . . S:$L($P(X,U,5)) @ROOT@("REACTION")=$P(X,U,7)
  1.  . . S:$L($P(X,U,8)) @ROOT@("CONTRAINDICATED")=$P(X,U,8)
  1.  . . S:$L($P(X,U,9)) @ROOT@("REFUSED")=$P(X,U,9)
  1.  . . S:$P(X,U,6)>0 @ROOT@("ENC PROVIDER")=$P(X,U,6)
  1.  . . S:$L($P(X,U,10))>0 COMMENT($P(X,U,10))="IMMUNIZATION^"_IMM
  1.  . . I $E(TYP,4)="-" S @ROOT@("DELETE")=1
  1.  . I $E(TYP,1,2)="SK" D  Q
  1.  . . Q:'$L(CODE)
  1.  . . S SK=SK+1,ROOT="ORPXAPI(""SKIN TEST"","_SK_")"
  1.  . . S @ROOT@("TEST")=CODE
  1.  . . S:$L($P(X,U,5)) @ROOT@("RESULT")=$P(X,U,5)
  1.  . . S:$L($P(X,U,7)) @ROOT@("READING")=$P(X,U,7)
  1.  . . S:$L($P(X,U,8)) @ROOT@("D/T READ")=$P(X,U,8)
  1.  . . S:$L($P(X,U,9)) @ROOT@("EVENT D/T")=$P(X,U,9)
  1.  . . S:$P(X,U,6)>0 @ROOT@("ENC PROVIDER")=$P(X,U,6)
  1.  . . S:$L($P(X,U,10))>0 COMMENT($P(X,U,10))="SKIN TEST^"_SK
  1.  . . I $E(TYP,3)="-" S @ROOT@("DELETE")=1
  1.  . I $E(TYP,1,3)="PED" D  Q
  1.  . . Q:'$L(CODE)
  1.  . . S PED=PED+1,ROOT="ORPXAPI(""PATIENT ED"","_PED_")"
  1.  . . S @ROOT@("TOPIC")=CODE
  1.  . . S:$L($P(X,U,5)) @ROOT@("UNDERSTANDING")=$P(X,U,5)
  1.  . . S:$P(X,U,6)>0 @ROOT@("ENC PROVIDER")=$P(X,U,6)
  1.  . . S:$L($P(X,U,10))>0 COMMENT($P(X,U,10))="PATIENT ED^"_PED
  1.  . . I $E(TYP,4)="-" S @ROOT@("DELETE")=1
  1.  . I $E(TYP,1,2)="HF" D  Q
  1.  . . Q:'$L(CODE)
  1.  . . S HF=HF+1,ROOT="ORPXAPI(""HEALTH FACTOR"","_HF_")"
  1.  . . S @ROOT@("HEALTH FACTOR")=CODE
  1.  . . S:$L($P(X,U,5)) @ROOT@("LEVEL/SEVERITY")=$P(X,U,5)
  1.  . . S:$P(X,U,6)'>0 $P(X,U,6)=$G(ORPXAPI("PROVIDER",1,"NAME"))
  1.  . . S:$P(X,U,6)>0 @ROOT@("ENC PROVIDER")=$P(X,U,6)
  1.  . . S:$L($P(X,U,11)) @ROOT@("EVENT D/T")=$P($P(X,U,11),";",1)
  1.  . . S:$L($P(X,U,11)) SRC=$P($P(X,U,11),";",2)
  1.  . . S:$L($P(X,U,10))>0 COMMENT($P(X,U,10))="HEALTH FACTOR^"_HF
  1.  . . I $E(TYP,3)="-" S @ROOT@("DELETE")=1
  1.  . I $E(TYP,1,3)="XAM" D  Q
  1.  . . Q:'$L(CODE)
  1.  . . S XAM=XAM+1,ROOT="ORPXAPI(""EXAM"","_XAM_")"
  1.  . . S @ROOT@("EXAM")=CODE
  1.  . . S:$L($P(X,U,5)) @ROOT@("RESULT")=$P(X,U,5)
  1.  . . S:$P(X,U,6)>0 @ROOT@("ENC PROVIDER")=$P(X,U,6)
  1.  . . S:$L($P(X,U,10))>0 COMMENT($P(X,U,10))="EXAM^"_XAM
  1.  . . I $E(TYP,4)="-" S @ROOT@("DELETE")=1
  1.  . I $E(TYP,1,3)="TRT" D  Q
  1.  . . Q:'$L(CODE)
  1.  . . S TRT=TRT+1,ROOT="ORPXAPI(""TREATMENT"","_TRT_")"
  1.  . . S @ROOT@("IMMUN")=CODE
  1.  . . S:$L(CAT) @ROOT@("CATEGORY")=CAT
  1.  . . S:$L(NARR) @ROOT@("NARRATIVE")=NARR
  1.  . . S:$L($P(X,U,5)) @ROOT@("QTY")=$P(X,U,5)
  1.  . . S:$P(X,U,6)>0 @ROOT@("ENC PROVIDER")=$P(X,U,6)
  1.  . . S:$L($P(X,U,10))>0 COMMENT($P(X,U,10))="TREATMENT^"_TRT
  1.  . . I $E(TYP,4)="-" S @ROOT@("DELETE")=1,@ROOT@("QTY")=0
  1.  . I $E(TYP,1,3)="COM" D  Q
  1.  . . Q:'$L(CODE)
  1.  . . Q:'$L(CAT)
  1.  . . S COMMENTS(CODE)=$P(X,U,3,999)
  1.  ;Store the comments
  1.  S COM=""
  1.  F  S COM=$O(COMMENT(COM)) Q:COM=""  S:$D(COMMENTS(COM)) ORPXAPI($P(COMMENT(COM),"^",1),$P(COMMENT(COM),"^",2),"COMMENT")=COMMENTS(COM)
  1.  ;
  1.  ;Remove any problems to add that the patient already has as active problems
  1.  I $D(PROBLEMS),$D(DFN) D
  1.  . N ORWPROB,ORPROBIX
  1.  . K ^TMP("IB",$J,"INTERFACES","GMP SELECT PATIENT ACTIVE PROBLEMS")
  1.  . D DSELECT^GMPLENFM  ;DBIA 1365
  1.  . S ORPROBIX=0
  1.  . F  S ORPROBIX=$O(^TMP("IB",$J,"INTERFACES","GMP SELECT PATIENT ACTIVE PROBLEMS",ORPROBIX)) Q:'ORPROBIX  D  ;DBIA 1365
  1.  .. S ORWPROB=$P(^TMP("IB",$J,"INTERFACES","GMP SELECT PATIENT ACTIVE PROBLEMS",ORPROBIX),"^",2,3)
  1.  .. S ORWPROB($S($E(ORWPROB,1)="$":$E(ORWPROB,2,255),1:ORWPROB))=""
  1.  . K ^TMP("IB",$J,"INTERFACES","GMP SELECT PATIENT ACTIVE PROBLEMS")
  1.  . Q:'$D(ORWPROB)
  1.  . S ORPROBIX=""
  1.  . F  S ORPROBIX=$O(PROBLEMS(ORPROBIX)) Q:'ORPROBIX  D
  1.  .. S:$D(ORWPROB(PROBLEMS(ORPROBIX))) ORPXAPI("DX/PL",ORPROBIX,"PL ADD")=0
  1.  ;
  1.  I $$MDS(.ORPXAPI,$G(ORLOC)) S ORPXAPI("ENCOUNTER",1,"CHECKOUT D/T")=$$NOW^XLFDT
  1.  S ORPXAPI("ENCOUNTER",1,"ENCOUNTER TYPE")="P"
  1. DATA2PCE ;
  1.  I $G(PXAPREDT)!($G(ORCPTDEL)) D
  1.  . M ORPXDEL("ENCOUNTER")=ORPXAPI("ENCOUNTER")
  1.  . I $G(ORCPTDEL) M ORPXDEL("PROCEDURE",ORCPTDEL)=ORPXAPI("PROCEDURE",ORCPTDEL)
  1.  . S OK=$$DATA2PCE^PXAPI("ORPXDEL",PKG,SRC,.ORAVST)
  1.  S OK=$$DATA2PCE^PXAPI("ORPXAPI",PKG,SRC,.ORAVST)
  1.  I OK>0,+NOTEIEN,+ORAVST D  ; NOTEIEN only set on inpatient encounters
  1.  .N OROK,ORX
  1.  .S ORX(1207)=ORAVST
  1.  .D FILE^TIUSRVP(.OROK,NOTEIEN,.ORX,1)
  1.  S ZTSTAT=0  ; clear sync flag
  1.  Q
  1.  ;
  1. MDS(X,ORLOC) ; return TRUE if checkout is needed
  1.  I $$CHKOUT^ORWPCE2(ORLOC) Q 1
  1.  N I,ORAUTO,OROK
  1.  S (OROK,I)=0
  1.  F  S I=$O(X("DX/PL",I)) Q:'I  D  Q:OROK
  1.  . I $G(X("DX/PL",I,"DIAGNOSIS")) S OROK=1
  1.  I 'OROK D
  1.  .S I=0 F  S I=$O(X("PROCEDURE",I)) Q:'I  D  Q:OROK
  1.  .. I $G(X("PROCEDURE",I,"PROCEDURE")) S OROK=1
  1.  I $D(X("PROVIDER",1,"NAME")) S OROK=1
  1.  Q OROK
  1. NONCOUNT(ORY,ORLOC) ;  Is the location a non-count clinic? (DBIA #964)
  1.  Q:'ORLOC
  1.  S ORY=$S($P($G(^SC(ORLOC,0)),U,17)="Y":1,1:0)
  1.  Q