Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: ORWPS

ORWPS.m

Go to the documentation of this file. 
  1. ORWPS ; SLC/KCM/JLI/REV/CLA - Meds Tab; 02/11/2008
  1.  ;;3.0;ORDER ENTRY/RESULTS REPORTING;**10,85,116,132,141,173,203,190,195,265,275,243**;Dec 17, 1997;Build 242
  1.  ;;Per VHA Directive 2004-038, this routine should not be modified.
  1. COVER(LST,DFN) ; retrieve meds for cover sheet
  1.  K ^TMP("PS",$J)
  1.  D OCL^PSOORRL(DFN,"","")
  1.  N ILST,ITMP,X S ILST=0
  1.  S ITMP="" F  S ITMP=$O(^TMP("PS",$J,ITMP)) Q:'ITMP  D
  1.  . S X=^TMP("PS",$J,ITMP,0)
  1.  . I '$L($P(X,U,2)) S X="??"  ; show something if drug empty
  1.  . I $D(^TMP("PS",$J,ITMP,"CLINIC",0)) S LST($$NXT)=$P(X,U,1,2)_U_$P(X,U,8,9)_U_"C"
  1.  . E  S LST($$NXT)=$P(X,U,1,2)_U_$P(X,U,8,9)
  1.  K ^TMP("PS",$J)
  1.  Q
  1. DT(X) ; -- Returns FM date for X
  1.  N Y,%DT S %DT="T",Y="" D:X'="" ^%DT
  1.  Q Y
  1.  ;
  1. ACTIVE(LST,DFN,USER,VIEW,UPDATE) ; retrieve active inpatient & outpatient meds
  1.  K ^TMP("PS",$J)
  1.  K ^TMP("ORACT",$J)
  1.  N BEG,END,ERROR,CTX,STVIEW
  1.  S (BEG,END,CTX)=""
  1.  S VIEW=+$G(VIEW)
  1.  S UPDATE=+$G(UPDATE)
  1.  I VIEW=0,UPDATE=0 S VIEW=1
  1.  S CTX=$$GET^XPAR("ALL","ORCH CONTEXT MEDS")
  1.  I CTX=";" D DEL^XPAR("USR.`"_DUZ,"ORCH CONTEXT MEDS")
  1.  S CTX=$$GET^XPAR("ALL","ORCH CONTEXT MEDS")
  1.  S BEG=$$DT($P(CTX,";")),END=$$DT($P(CTX,";",2))
  1.  I +$G(USER)=0 S USER=DUZ
  1.  I UPDATE=1 D
  1.  .S STVIEW=$$GET^XPAR($G(USER)_";VA(200,","OR MEDS TAB SORT",1,"I")
  1.  .I VIEW>0,+STVIEW'=VIEW D PUT^XPAR(DUZ_";VA(200,","OR MEDS TAB SORT",,VIEW,.ERROR) S STVIEW=VIEW
  1.  .I VIEW=0,+STVIEW=0 D PUT^XPAR(DUZ_";VA(200,","OR MEDS TAB SORT",,"1",.ERROR) S STVIEW=1,VIEW=1
  1.  .I VIEW=0,+STVIEW'=VIEW S VIEW=+STVIEW
  1.  .S LST(0)=STVIEW
  1.  D OCL^PSOORRL(DFN,BEG,END,VIEW)
  1.  N ITMP,FIELDS,INSTRUCT,COMMENTS,REASON,NVSDT,TYPE,ILST,J S ILST=0
  1.  S ITMP="" F  S ITMP=$O(^TMP("PS",$J,ITMP)) Q:'ITMP  D
  1.  . K INSTRUCT,COMMENTS,REASON
  1.  . K ^TMP("ORACT",$J,"COMMENTS")
  1.  . S COMMENTS="^TMP(""ORACT"",$J,""COMMENTS"")"
  1.  . S (INSTRUCT,@COMMENTS)="",FIELDS=^TMP("PS",$J,ITMP,0)
  1.  . I +$P(FIELDS,"^",8),$D(^OR(100,+$P(FIELDS,"^",8),8,"C","XX")) D
  1.  . . S $P(^TMP("PS",$J,ITMP,0),"^",2)="*"_$P(^TMP("PS",$J,ITMP,0),"^",2) ;dan testing
  1.  . S TYPE=$S($P($P(FIELDS,U),";",2)="O":"OP",1:"UD")
  1.  . I $D(^TMP("PS",$J,ITMP,"CLINIC",0)) S TYPE="CP"
  1.  . N LOC,LOCEX S (LOC,LOCEX)=""
  1.  . I TYPE="CP" S LOC=$G(^TMP("PS",$J,ITMP,"CLINIC",0))
  1.  . S:LOC LOCEX=$P($G(^SC(+LOC,0)),U)_":"_+LOC ;IMO NEW
  1.  . I TYPE="OP",$P(FIELDS,";")["N" S TYPE="NV"          ;non-VA med
  1.  . I $O(^TMP("PS",$J,ITMP,"A",0))>0 S TYPE="IV"
  1.  . I $O(^TMP("PS",$J,ITMP,"B",0))>0 S TYPE="IV"
  1.  . I (TYPE="UD")!(TYPE="CP") D UDINST(.INSTRUCT,ITMP)
  1.  . I TYPE="OP" D OPINST(.INSTRUCT,ITMP)
  1.  . I TYPE="IV" D IVINST(.INSTRUCT,ITMP)
  1.  . I TYPE="NV" D NVINST(.INSTRUCT,ITMP),NVREASON(.REASON,.NVSDT,ITMP)
  1.  . I (TYPE="UD")!(TYPE="IV")!(TYPE="NV")!(TYPE="CP") D SETMULT(COMMENTS,ITMP,"SIO")
  1.  . M COMMENTS=@COMMENTS
  1.  . I $D(COMMENTS(1)) S COMMENTS(1)="\"_COMMENTS(1)
  1.  . S:TYPE="NV" $P(FIELDS,U,4)=$G(NVSDT)
  1.  . I LOC S LST($$NXT)="~CP:"_LOCEX_U_FIELDS
  1.  . E  S LST($$NXT)="~"_TYPE_U_FIELDS
  1.  . S J=0 F  S J=$O(INSTRUCT(J)) Q:'J  S LST($$NXT)=INSTRUCT(J)
  1.  . S J=0 F  S J=$O(COMMENTS(J)) Q:'J  S LST($$NXT)="t"_COMMENTS(J)
  1.  . S J=0 F  S J=$O(REASON(J)) Q:'J  S LST($$NXT)="t"_REASON(J)
  1.  K ^TMP("PS",$J)
  1.  K ^TMP("ORACT",$J)
  1.  Q
  1. NXT() ; increment ILST
  1.  S ILST=ILST+1
  1.  Q ILST
  1.  ;
  1. UDINST(Y,INDEX) ; assembles instructions for a unit dose order
  1.  N I,X,RST
  1.  S X=^TMP("PS",$J,INDEX,0)
  1.  S RST="^TMP(""ORACT"",$J,""INSTRUCT"")"
  1.  S @RST@(1)=" "_$P(X,U,2),@RST=1
  1.  S X=$S($L($P(X,U,6)):$P(X,U,6),1:$P(X,U,7))
  1.  I $L(X) S @RST=2,@RST@(2)=X
  1.  E  S @RST=1 D SETMULT(.RST,INDEX,"SIG")
  1.  S @RST@(2)="\Give: "_$G(@RST@(2)),@RST=$G(@RST,2)
  1.  D SETMULT(RST,INDEX,"MDR"),SETMULT(RST,INDEX,"SCH")
  1.  F I=3:1:@RST S @RST@(I)=" "_@RST@(I)
  1.  M Y=@RST K @RST
  1.  Q
  1. OPINST(Y,INDEX) ; assembles instructions for an outpatient prescription
  1.  N I,X,RST
  1.  S X=^TMP("PS",$J,INDEX,0)
  1.  S RST="^TMP(""ORACT"",$J,""INSTRUCT"")"
  1.  S @RST@(1)=" "_$P(X,U,2),@RST=1
  1.  I $L($P(X,U,12)) S @RST@(1)=@RST@(1)_"  Qty: "_$P(X,U,12)
  1.  I $L($P(X,U,11)) S @RST@(1)=@RST@(1)_" for "_$P(X,U,11)_" days"
  1.  D SETMULT(RST,INDEX,"SIG")
  1.  I @RST=1 D
  1.  . D SETMULT(RST,INDEX,"SIO")
  1.  . D SETMULT(RST,INDEX,"MDR")
  1.  . D SETMULT(RST,INDEX,"SCH")
  1.  S @RST@(2)="\ Sig: "_$G(@RST@(2))
  1.  F I=3:1:@RST S @RST@(I)=" "_@RST@(I)
  1.  M Y=@RST K @RST
  1.  Q
  1. IVINST(Y,INDEX) ; assembles instructions for an IV order
  1.  N SOLN1,I,RST,IVDUR,CNT
  1.  S IVDUR=""
  1.  S RST="^TMP(""ORACT"",$J,""INSTRUCT"")"
  1.  S @RST=0 D SETMULT(RST,INDEX,"A") S SOLN1=@RST+1
  1.  D SETMULT(RST,INDEX,"B")
  1.  I $D(@RST@(SOLN1)),$L($P(FIELDS,U,2)) S @RST@(SOLN1)="in "_@RST@(SOLN1)
  1.  S SOLN1=@RST+1
  1.  S CNT=@RST
  1.  D SETMULT(RST,INDEX,"MDR")
  1.  I $D(^TMP("PS",$J,INDEX,"SCH",1,0)) S @RST@(@RST)=@RST@(@RST)_" "_^TMP("PS",$J,INDEX,"SCH",1,0)
  1.  F I=1:1:@RST S @RST@(I)="\"_$TR(@RST@(I),U," ")
  1.  I $D(@RST@(1)) S @RST@(1)=" "_$E(@RST@(1),2,999)
  1.  S @RST@(@RST)=@RST@(@RST)_" "_$P(^TMP("PS",$J,INDEX,0),U,3)
  1.  S:$D(^TMP("PS",$J,INDEX,"IVLIM",0)) IVDUR=$G(^TMP("PS",$J,INDEX,"IVLIM",0))
  1.  I $L(IVDUR) D
  1.  . N DURU,DURV S DURU="",DURV=0
  1.  . I IVDUR["dose" D  Q
  1.  . .S DURV=$P(IVDUR,"doses",2)
  1.  . .S IVDUR="for a total of "_+DURV_$S(+DURV=1:"dose",+DURV>1:" doses",1:" dose")
  1.  . .S @RST@(@RST)=@RST@(@RST)_" "_IVDUR
  1.  . S DURU=$E(IVDUR,1),DURV=$E(IVDUR,2,$L(IVDUR))
  1.  . I (DURU="D")!(DURU="d") S IVDUR="for "_+DURV_$S(+DURV=1:" day",+DURV>1:" days",1:" day")
  1.  . I (DURU="H")!(DURU="h") S IVDUR="for "_+DURV_$S(+DURV=1:" hours",+DURV>1:" hours",1:" hour")
  1.  . I (DURU="M")!(DURU="m") S IVDUR="with total volume "_+DURV_" ml"
  1.  . I (DURU="L")!(DURU="l") S IVDUR="with total volume "_+DURV_" L"
  1.  . S @RST@(@RST)=@RST@(@RST)_" "_IVDUR
  1.  M Y=@RST K @RST
  1.  Q
  1. NVINST(Y,INDEX) ; assembles instructions for a non-VA med
  1.  N I,X,RST
  1.  S X=^TMP("PS",$J,INDEX,0)
  1.  S RST="^TMP(""ORACT"",$J,""INSTRUCT"")"
  1.  S @RST@(1)=" "_$P(X,U,2),@RST=1
  1.  D SETMULT(RST,INDEX,"SIG")
  1.  I @RST=1 D
  1.  . D SETMULT(RST,INDEX,"SIO")
  1.  . D SETMULT(RST,INDEX,"MDR")
  1.  . D SETMULT(RST,INDEX,"SCH")
  1.  S @RST@(2)="\ "_$G(@RST@(2))
  1.  F I=3:1:@RST S @RST@(I)=" "_@RST@(I)
  1.  M Y=@RST K @RST
  1.  Q
  1. NVREASON(ORR,NVSDT,INDEX) ; assembles start date and reasons for a non-VA med
  1.  N ORI,J,X,ORN,ORA
  1.  S ORI=0 K ORR
  1.  S X=^TMP("PS",$J,INDEX,0)
  1.  S ORN=+$P(X,U,8)
  1.  I $D(^OR(100,ORN,0)) D
  1.  .S NVSDT=$P(^OR(100,ORN,0),U,8)
  1.  .D WPVAL^ORWDXR(.ORA,ORN,"STATEMENTS") I $D(ORA) D
  1.  ..S J=0 F  S J=$O(ORA(J)) Q:J<1  S ORI=ORI+1,ORR(ORI)=ORA(J)
  1.  Q
  1. SETMULT(Y,INDEX,SUB) ; appends the multiple at the subscript to Y
  1.  N I,X,J
  1.  S J=$G(@Y)
  1.  S I=0 F  S I=$O(^TMP("PS",$J,INDEX,SUB,I)) Q:'I  S X=$G(^(I,0)) D
  1.  . I SUB="B",$L($P(X,U,3)) S X=$P(X,U)_" "_$P(X,U,3)_"^"_$P(X,U,2)
  1.  . S J=J+1,@Y@(J)=X
  1.  S @Y=J
  1.  Q
  1. COMPRESS(Y) ; concatenate Y subscripts into smallest possible number
  1.  N I,J,X S J=1,X(J)=""
  1.  S I=0 F  S I=$O(Y(I)) Q:'I  D
  1.  . I ($L(Y(I))+$L(X(J)))>245 S J=J+1,X(J)=""
  1.  . S X(J)=X(J)_$S($L(X(J)):" ",1:"")_Y(I)
  1.  K Y M Y=X
  1.  Q
  1. DETAIL(ROOT,DFN,ID) ; -- show details for a med order
  1.  K ^TMP("ORXPND",$J)
  1.  N LCNT,ORVP
  1.  S LCNT=0,ORVP=DFN_";DPT("
  1.  D MEDS^ORCXPND1
  1.  S ROOT=$NA(^TMP("ORXPND",$J))
  1.  Q
  1. MEDHIST(ORROOT,DFN,ORIFN) ; -- show admin history for a med  (RV)
  1.  N ORPSID,HPIV,ISIV,CKPKG,ORPHMID
  1.  N CLINDISP,IVDIAL
  1.  S ORPSID=+$P($$OI^ORX8(ORIFN),U,3),ISIV=0,HPIV=0
  1.  S ORROOT=$NA(^TMP("ORHIST",$J)) K @ORROOT
  1.  S ORPHMID=$G(^OR(100,+ORIFN,4))  ;Pharmacy order number
  1.  S ISIV=$O(^ORD(100.98,"B","IV RX",ISIV))
  1.  S HPIV=$O(^ORD(100.98,"B","TPN",HPIV))
  1.  S CLINDISP=$O(^ORD(100.98,"B","C RX",""))
  1.  S IVDIAL=$O(^ORD(101.41,"B","PSJI OR PAT FLUID OE",""))
  1.  S CKPKG=$$PATCH^XPDUTL("PSB*2.0*19")
  1.  ;if the order is pending or the order has no pharmacy # 
  1.  ;or the order is not in the Display Group IV MEDICATION
  1.  ; then use the Orderable item number to get the MAH.
  1.  I (ORPHMID["P")!(ORPHMID="") D  Q
  1.  . I '$L($T(HISTORY^PSBMLHS)) D  Q
  1.  . . S @ORROOT@(0)="This report is only available using BCMA version 2.0."
  1.  . D HISTORY^PSBMLHS(.ORROOT,DFN,ORPSID)  ; DBIA #3459 for BCMA v2.0
  1.  ; If the order has a Display Group of IV MEDICATION the use the Pharmacy order number to get the MA
  1.  I ($P($G(^OR(100,+ORIFN,0)),U,11)=ISIV)!($P($G(^OR(100,+ORIFN,0)),U,11)=HPIV)!(($P($G(^OR(100,+ORIFN,0)),U,11)=CLINDISP)&(+$P($G(^OR(100,+ORIFN,0)),U,5)=IVDIAL)) D  Q
  1.  . I 'CKPKG S @ORROOT@(0)="Medication Administration History is not available at this time for IV fluids."
  1.  . I CKPKG D
  1.  . . D RPC^PSBO(.ORROOT,"PM",DFN,"","","","","","","","","",ORPHMID)  ;DBIA #3955
  1.  . . I '$D(@ORROOT) S @ORROOT@(0)="No Medication Administration History found for the IV order."
  1.  I '$L($T(HISTORY^PSBMLHS)) D  Q
  1.  . S @ORROOT@(0)="This report is only available using BCMA version 2.0."
  1.  D HISTORY^PSBMLHS(.ORROOT,DFN,ORPSID)  ; DBIA #3459 for BCMA v2.0
  1.  Q
  1.  ;
  1. REASON(ORY) ; -- Return Non-VA Med Statement/Reasons
  1.  N ORE
  1.  D GETLST^XPAR(.ORY,"ALL","ORWD NONVA REASON","E")
  1.  Q