Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: ORXTABS1

ORXTABS1.m

Go to the documentation of this file. 
  1. ORXTABS1 ; SLC/PKS - Edit tab parameters preferences.  [9/11/00 1:40pm]
  1.  ;;3.0;ORDER ENTRY/RESULTS REPORTING;**9,47,84**;Dec 17, 1997
  1.  ;
  1.  ; Additional control code for Tab Preferences Editing - works in
  1.  ;    conjunction with the main routine, ORXTABS.
  1.  ;
  1.  ; NOTE: Most ORX* variables used herein NEW'd in calling routine.
  1.  ;
  1.  Q
  1.  ;
  1. EDIT ; Display list of this tab's parameter values, allow edit selection.
  1.  ;
  1.  ; Variables used herein:
  1.  ;
  1.  ;    ORXCNT2  = Loop counter for concantenated user input.
  1.  ;    ORXHI    = High end of hyphenated entry.
  1.  ;    ORXINPUT = Input string (DIR's Y var) from user's entry.
  1.  ;    ORXLO    = Low end of hyphenated entry.
  1.  ;    ORXNUM2  = Number of pieces in concantenated user input.
  1.  ;    ORXTEMP  = Temporary value holder.
  1.  ;    ORXTOT   = Total holder.
  1.  ;
  1.  N ORXCNT2,ORXHI,ORXINPUT,ORXLO,ORXNUM2,ORXTEMP,ORXTOT
  1.  ;
  1.  ; Create overall control loop:
  1.  K ORXPCS                                  ; Clear each time.
  1.  S ORXANY=0                                ; Set to check for changes.
  1.  F  Q:ORXSTOP  D
  1.  .;
  1.  .; Get matching prompt strings:
  1.  .K ORXPSTR,ORXPRO,ORXPDIS                 ; Prompts variables.
  1.  .S ORXTAG="PROMPTS+"_ORXTCNT_"^ORXTABS"   ; Data tag for prompts.
  1.  .S ORXPSTR=$P($T(@ORXTAG),";;",2)         ; Current prompts line.
  1.  .S ORXPDIR=$P(ORXPSTR,U)                  ; Get first prompt piece.
  1.  .I ORXPDIR'=ORXTNM D  Q                   ; Check for mismatch.
  1.  ..W !!,"   Problem reading PROMPTS data!" ; On error, leave message.
  1.  ..S ORXSTOP=1                             ; Set flag for abort.
  1.  .S ORXPSTR=$P(ORXPSTR,U,2)                ; Get prompts list string.
  1.  .S ORXPCS=$P($G(ORXPARS(ORXTCNT)),U,3)    ; Get "pieces" map string.
  1.  .;
  1.  .; Clear, reset DIR variables:
  1.  .K DIR,X,Y
  1.  .S DIR("T")=120 ; Two minute maximum timeout for response.
  1.  .S DIR("A")="   Select "_ORXPDIR_" value to edit"
  1.  .S DIR("?")="   Enter individual item number or comma-delimited string (within ranges listed)"
  1.  .;
  1.  .; Assign individual DIR display array items:
  1.  .S ORXVAL=""
  1.  .S ORXNUM=$L(ORXSETS,";")             ; # pieces = loop end counter.
  1.  .F ORXCNT=1:1:ORXNUM  D               ; Each piece of param setting.
  1.  ..S ORXVAL=$P($G(ORXSETS),";",ORXCNT) ; Each setting.
  1.  ..S ORXVAL=$$LJ^XLFSTR(ORXVAL,9)      ; Format for 9 characters.
  1.  ..S ORXPRO=$P(ORXPSTR,";",ORXCNT)     ; Prompt for this piece.
  1.  ..S ORXPRO=$$LJ^XLFSTR(ORXPRO,24)     ; Format for 24 characters.
  1.  ..;
  1.  ..; Assign DIR display values:
  1.  ..S ORXCDIS=ORXCNT                    ; Set display counter to same.
  1.  ..S ORXCDIS=$$RJ^XLFSTR(ORXCDIS,2)    ; Right justify to 2 places.
  1.  ..S DIR("A",ORXCNT)="     "_ORXCDIS_"     "_ORXVAL_"     "_ORXPRO
  1.  .;
  1.  .; Add one additional choice for editing "ALL" items:
  1.  .I (ORXCNT>1) D
  1.  ..S ORXCNT=ORXCNT+1                   ; Increment counter.
  1.  ..S ORXNUM=ORXCNT                     ; Keep totaller up to date.
  1.  ..S ORXCDIS=ORXCNT                    ; Set display counter to match.
  1.  ..S ORXCDIS=$$RJ^XLFSTR(ORXCDIS,2)    ; Right justify to 2 places.
  1.  ..S DIR("A",ORXCNT)="     "_ORXCDIS_"     ALL      "_"     Edit All Above Items"
  1.  .;
  1.  .; Define DIR input requirements:
  1.  .S DIR(0)="LO^1:"_ORXNUM              ; List, from 1 to max choices.
  1.  .;
  1.  .; Call DIR for user choice:
  1.  .W !! ; Spacing for screen display.
  1.  .I ORXPDIR="REPORTS" D                ; Special note for reports.
  1.  ..W !,"     NOTE: At present, the following settings affect only the list of"
  1.  ..W !,"           Imaging report selections shown under Reports:"
  1.  ..W !,"           ---------------------------------------------"
  1.  .D ^DIR
  1.  .;
  1.  .; Check user response:
  1.  .I '$L($G(Y)) S ORXSTOP=1 Q           ; Punt if Y isn't assigned.
  1.  .I Y="" S ORXSTOP=1 Q                 ; Punt if Y is null.
  1.  .I Y="^" S ORXSTOP=1 Q                ; Punt if Y is "^" character.
  1.  .;
  1.  .; Entry valid - assign ORXINPUT variable to user entry:
  1.  .K ORXINPUT                           ; Clean up each time through.
  1.  .S ORXINPUT=Y                         ; Now holds input string.
  1.  .K DIR,X,Y                            ; Clean up after call to DIR.
  1.  .;
  1.  .; If user made a concantenated entry, deal with it:
  1.  .I (($L($P(ORXINPUT,",",2)))!($L($P(ORXINPUT,"-",2)))) D  Q
  1.  ..;
  1.  ..; Deal with an entry string:
  1.  ..S ORXTOT=1                                 ; Initial setting.
  1.  ..S ORXNUM2=($L(ORXINPUT,",")-1)             ; Total pieces entered.
  1.  ..;
  1.  ..; Establish loop to tear the string apart:
  1.  ..F ORXCNT=1:1:ORXNUM2  D                    ; Each piece in entry.
  1.  ...I ORXCNT>ORXTOT S ORXTOT=ORXCNT           ; Reset higher?
  1.  ...S ORXTEMP=$P(ORXINPUT,",",ORXCNT)         ; Get each entry piece.
  1.  ...;
  1.  ...; Check for a hyphenated entry:
  1.  ...I $L($P(ORXTEMP,"-",2)) D  Q              ; To next piece after.
  1.  ....S ORXLO=$P(ORXTEMP,"-")                  ; Lower number.
  1.  ....S ORXHI=$P(ORXTEMP,"-",2)                ; Higher number.
  1.  ....S ORXHI=+ORXHI                           ; Eliminate comma.
  1.  ....I ORXHI>ORXTOT S ORXTOT=ORXHI            ; Reset higher?
  1.  ....;
  1.  ....; Use another loop to assign the range of hyphenated elements:
  1.  ....F ORXCNT2=ORXLO:1:ORXHI D
  1.  .....S ORXINPUT(ORXCNT2)=ORXCNT2             ; ORXCNT2 is default #.
  1.  ...;
  1.  ...; If piece isn't hyphenated, use it directly:
  1.  ...S ORXINPUT(+ORXTEMP)=+ORXTEMP
  1.  ...I +ORXTEMP>ORXTOT S ORXTOT=+ORXTEMP       ; Reset higher?
  1.  ..;
  1.  ..; Check and eliminate "ALL" selection if necessary:
  1.  ..I ORXTOT=ORXNUM K ORXINPUT(ORXTOT) S ORXTOT=ORXTOT-1
  1.  ..;
  1.  ..; ORXTOT should now equal the highest-numbered user selection.
  1.  ..; Each assigned ORXINPUT(xx) element should resemble:
  1.  ..;    ORXINPUT(5)=5
  1.  ..;
  1.  ..; Call tag to process the entries:
  1.  ..D SOME
  1.  .;
  1.  .; No more than one entry, so assign ORXCNT and proceed:
  1.  .S ORXCNT=+ORXINPUT
  1.  .;
  1.  .; Unless "ALL" was selected, assign current value variables:
  1.  .I ORXCNT<ORXNUM D
  1.  ..S ORXNOW=$P($G(ORXCUR),";",$P($G(ORXPCS),";",ORXCNT))
  1.  ..S ORXPDIS=$P(ORXPSTR,";",ORXCNT)     ; Display prompt, this piece.
  1.  .;
  1.  .; Deal with "ALL" choice:
  1.  .I ORXCNT=ORXNUM S ORXSTOP=1 D ALL  Q  ; "ALL" choice.
  1.  .;
  1.  .; Process individual selections:
  1.  .S ORXVAL=$P($G(ORXSETS),";",ORXCNT)   ; Any of individual choices.
  1.  .D EACH
  1.  ;
  1.  Q
  1.  ;
  1. ALL ; Process each value (piece) of selected parameter in turn.
  1.  ;
  1.  S ORXNEW=""                                 ; Reset.
  1.  ;
  1.  ; Establish control loop:
  1.  F ORXCNT=1:1:(ORXNUM-1) Q:ORXNEW="^"  D
  1.  .;
  1.  .; Set tag to match each value:
  1.  .S ORXVAL=$P($G(ORXSETS),";",ORXCNT)
  1.  .;
  1.  .; Assign current value and prompt variables each time:
  1.  .S ORXNOW=$P($G(ORXCUR),";",$P($G(ORXPCS),";",ORXCNT))
  1.  .S ORXPDIS=$P(ORXPSTR,";",ORXCNT)
  1.  .;
  1.  .; Process each value:
  1.  .W !!,"     (Entry of ^ will cancel entry process.)"
  1.  .D EACH
  1.  ;
  1.  Q
  1.  ;
  1. SOME ; Process specific values of selected parameter in turn.
  1.  ;
  1.  S ORXNEW=""                                 ; Reset.
  1.  ;
  1.  ; Establish control loop:
  1.  S ORXCNT=0                                  ; Initialize.
  1.  F  Q:((ORXCNT>(ORXTOT))!(ORXNEW="^"))  D
  1.  .S ORXCNT=ORXCNT+1                          ; Increment each time.
  1.  .I '$D(ORXINPUT(ORXCNT)) Q                  ; Non-existant entries.
  1.  .;
  1.  .; Set tag to match each value:
  1.  .S ORXVAL=$P($G(ORXSETS),";",ORXCNT)        ; ORXCNT is # by default.
  1.  .;
  1.  .; Assign current value and prompt variables each time:
  1.  .S ORXNOW=$P($G(ORXCUR),";",$P($G(ORXPCS),";",ORXCNT))
  1.  .S ORXPDIS=$P(ORXPSTR,";",ORXCNT)
  1.  .;
  1.  .; Process each value:
  1.  .W !!,"     (Entry of ^ will cancel entry process.)"
  1.  .D EACH
  1.  ;
  1.  Q
  1.  ;
  1. EACH ; Process and update an edited value.
  1.  ;
  1.  ; Get tag name in ORXTABS2 to process the user's entry:
  1.  K DIR,X,Y
  1.  S ORXANY=ORXANY+1
  1.  ;
  1.  ; Assign command string with passed variable for execution:
  1.  S ORXNEW="S ORXNEW=$$"_ORXVAL_"^ORXTABS2("_""""_ORXNOW_""""_")"
  1.  ;
  1.  X ORXNEW                               ; Execute call to tag.
  1.  ;
  1.  ; Don't update value if user opted out with "^" entry:
  1.  I ORXNEW="^" S ORXANY=ORXANY-1 Q
  1.  ;
  1.  ; Stuff new value into current value string:
  1.  S $P(ORXCUR,";",$P($G(ORXPCS),";",ORXCNT))=ORXNEW
  1.  ;
  1.  Q
  1.  ;
  1. SAVE ; Obtain user input, then save or discard changes.
  1.  ;
  1.  S ORXANY=$$CONFIRM                       ; Re-use ORXANY variable.
  1.  I 'ORXANY W !!,"   No changes saved...." Q
  1.  ;
  1.  ; Write changes back to parameters file:
  1.  K ORXERR
  1.  D PUT^XPAR(DUZ_";VA(200,",ORXPNAM,,ORXCUR,.ORXERR)
  1.  ;
  1.  ; Check for an error in the write process:
  1.  I (+ORXERR'=0) D  Q
  1.  .W !,"   ERROR: Parameter not updated!"  ; Notify user of error.
  1.  .W !,"   ("_$P(ORXERR,U,2)_")"           ; Display error message.
  1.  ;
  1.  W !!,"Tab parameter setting(s) updated/saved."
  1.  W !,"(GUI Users must close, re-start application to activate changes.)",!
  1.  ;
  1.  Q 
  1.  ;
  1. CONFIRM() ; Confirm to save changes.
  1.  ;
  1.  ; Clear, reset DIR variables:
  1.  K DIR,X,Y
  1.  S DIR("T")=120 ; Two minute maximum timeout for response.
  1.  S DIR("A")="   Save changes"
  1.  S DIR("?")="   Write changes to parameter file? (Y/N)"
  1.  S DIR("A",1)="     YES"
  1.  S DIR("A",2)="     NO"
  1.  S DIR("B")="YES"
  1.  ;
  1.  ; Define DIR input requirements:
  1.  S DIR(0)="YO^1:2:0"
  1.  ;
  1.  ; Call DIR for user choice:
  1.  W !! ; Spacing for screen display.
  1.  D ^DIR
  1.  ;
  1.  ; Check user response:
  1.  I '$L($G(Y)) Q 0                      ; Skip if Y isn't assigned.
  1.  I Y="" Q 0                            ; Skip if Y is null.
  1.  I Y="^" Q 0                           ; Skip if Y is "^" character.
  1.  I Y<1 Q 0                             ; Skip if Y is less than one.
  1.  I Y>2 Q 0                             ; "No" choice.
  1.  I Y=1 Q 1                             ; "Yes" choice.
  1.  ;
  1.  Q 0                                   ; Default return of "No."
  1.  ;