Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: PSBOML

PSBOML.m

Go to the documentation of this file. 
  1. PSBOML ;BIRMINGHAM/EFC-MEDICATION LOG ;29-May-2012 14:20;PLS
  1.  ;;3.0;BAR CODE MED ADMIN;**3,11,1005,50,1015**;Mar 2004;Build 62
  1.  ;
  1.  ; Modified - IHS/CIA/PLS - 06/21/04 - Line EN+6
  1.  ;            IHS/MSC/PLS - 02/22/07 - Line EN+35
  1.  ;                                     Added PTID API
  1.  ; Reference/IA
  1.  ; ^DPT/10035
  1.  ;
  1.  ;
  1. EN ; Begin printing
  1.  N PSBSTRT,PSBSTOP,PSBHDR,DFN
  1.  S PSBSTRT=$P(PSBRPT(.1),U,6)+$P(PSBRPT(.1),U,7)
  1.  S PSBSTOP=$P(PSBRPT(.1),U,8)+$P(PSBRPT(.1),U,9)
  1.  S PSBAUDF=$P(PSBRPT(.2),U,9)
  1.  S PSBHDR(0)="Medication Log Report"
  1.  ; IHS/CIA/PLS - 06/21/04 - Removed reference to VA Form
  1.  ;S PSBHDR(1)="Continuing/PRN/Stat/One Time Medication/Treatment Record (Detailed Log) (VAF 10-2970 B, C, D)"
  1.  S PSBHDR(1)="Continuing/PRN/Stat/One Time Medication/Treatment Record (Detailed Log)"
  1.  ;
  1.  ; Patient Report
  1.  ;
  1.  D:$P(PSBRPT(.1),U,1)="P"
  1.  .S PSBHDR(2)="Log Type: INDIVIDUAL PATIENT"
  1.  .S DFN=+$P(PSBRPT(.1),U,2)
  1.  .W $$PTHDR()
  1.  .S X=$O(^PSB(53.79,"AADT",DFN,PSBSTRT-.0000001))
  1.  .I X>PSBSTOP!(X="") W !!?10,"<<<< NO MEDICATIONS FOUND FOR THIS TIME FRAME >>>>",!! Q
  1.  .S PSBGBL=$NAME(^PSB(53.79,"AADT",DFN,PSBSTRT-.0000001))
  1.  .F  S PSBGBL=$Q(@PSBGBL) Q:PSBGBL=""  Q:$QS(PSBGBL,2)'="AADT"!($QS(PSBGBL,3)'=DFN)!($QS(PSBGBL,4)>PSBSTOP)  D
  1.  ..S PSBIEN=$QS(PSBGBL,5) Q:'$D(^PSB(53.79,PSBIEN))
  1.  ..I $P(^PSB(53.79,PSBIEN,0),U,6)'=$QS(PSBGBL,4) Q
  1.  ..I $Y>(IOSL-10) W $$PTFTR^PSBOHDR(),$$PTHDR()
  1.  ..W $$LINE(PSBIEN)
  1.  .W $$PTFTR^PSBOHDR()
  1.  ;
  1.  ; Ward Output
  1.  ;
  1.  D:$P(PSBRPT(.1),U,1)="W"
  1.  .S PSBHDR(2)="LOG TYPE: WARD"
  1.  .W $$WDHDR(PSBWRD)
  1.  .S PSBTMPG=$NAME(^TMP("PSBO",$J,"B"))
  1.  .F  S PSBTMPG=$Q(@PSBTMPG) Q:PSBTMPG=""  Q:$QS(PSBTMPG,1)'="PSBO"!($QS(PSBTMPG,2)'=$J)  D
  1.  ..S DFN=$QS(PSBTMPG,5)
  1.  ..I $Y>(IOSL-14) W $$WDHDR(PSBWRD)
  1.  ..; IHS/MSC/PLS - 02/22/07 - Next line commented out, following line added
  1.  ..;W !,$P(^DPT(DFN,0),U),"  (",$P(^(0),U,9),")"
  1.  ..W !,$P(^DPT(DFN,0),U),"  (",$$PTID(DFN),")"
  1.  ..W !,"Ward: ",$G(^DPT(DFN,.1),"***"),"  Rm-Bed: ",$G(^DPT(DFN,.101),"***"),!
  1.  ..S X=$O(^PSB(53.79,"AADT",DFN,PSBSTRT-.0000001))
  1.  ..I X>PSBSTOP!(X="") W !!?10,"<<<< NO MEDICATIONS FOUND FOR THIS TIME FRAME >>>>",!! Q
  1.  ..S PSBGBL=$NAME(^PSB(53.79,"AADT",DFN,PSBSTRT-.0000001))
  1.  ..F  S PSBGBL=$Q(@PSBGBL) Q:PSBGBL=""  Q:$QS(PSBGBL,2)'="AADT"!($QS(PSBGBL,3)'=DFN)!($QS(PSBGBL,4)>PSBSTOP)  D
  1.  ...S PSBIEN=$QS(PSBGBL,5) I $P(^PSB(53.79,PSBIEN,0),U,6)'=$QS(PSBGBL,4) Q
  1.  ...W:$Y>(IOSL-10) $$WDHDR(PSBWRD)
  1.  ...W $$LINE(PSBIEN)
  1.  Q
  1.  ;
  1. LINE(PSBIEN) ; Displays the med log entry in PSBIEN
  1.  N PSBX,PSBASTUS
  1.  S X=$P($G(^PSB(53.79,PSBIEN,.1)),U)
  1.  I X="" W !,"Error: Med Log Entry ",PSBIEN," has no order reference number!" Q ""
  1.  I 'PSBAUDF,$P(^PSB(53.79,PSBIEN,0),U,9)="N" Q ""
  1.  D CLEAN^PSBVT
  1.  D PSJ1^PSBVT(DFN,X)
  1.  I PSBDFN="-1" W !,"Error: Inpatient Meds API Failure!" Q ""
  1.  M PSBX=^PSB(53.79,PSBIEN)
  1.  S Y=$P(PSBX(0),U,4)+.0000001
  1.  W !,$E(Y,4,5),"/",$E(Y,6,7),"/",$E(Y,2,3)
  1.  W " ",$E(Y,9,10),":",$E(Y,11,12)
  1.  S Y=$$GET1^DIQ(53.79,PSBIEN_",",.08)
  1.  S Y=Y_" ["_PSBDOSE_PSBIFR_" "_PSBSCH
  1.  S Y=Y_" "_PSBMRAB
  1.  S:$P($G(^PSB(53.79,PSBIEN,.1)),U,6)]"" Y=Y_" Inj Site: "_$P(^(.1),U,6)
  1.  S Y=Y_"]"
  1.  W $$WRAP^PSBO(16,32,Y)
  1.  W ?50,$$GET1^DIQ(53.79,PSBIEN_",","ACTION BY:INITIAL")
  1.  S X=$P(PSBX(0),U,9)
  1.  S PSBASTUS=$S(X="G":"Given",X="H":"Held",X="R":"Refused",X="I":"Infusing",X="C":"Completed",X="S":"Stopped",X="N":"Not Given",X="RM":"Removed",X="M":"Missing dose",1:"Status Unknown")
  1.  S Y=$P(PSBX(0),U,6)+.0000001
  1.  S Y=$E(Y,4,5)_"/"_$E(Y,6,7)_"/"_$E(Y,2,3)_" "_$E(Y,9,10)_":"_$E(Y,11,12)
  1.  S Y=Y_" "_PSBASTUS
  1.  W $$WRAP^PSBO(57,15,Y)
  1.  W:$P(PSBX(.1),U)["V" ?75,"Bag ID #",$$GET1^DIQ(53.79,PSBIEN,"IV UNIQUE ID")
  1.  W:$P(PSBX(.1),U)["V" ?107,"NA",?115,"NA",?120,"NA"
  1.  W !,$TR($$FMTE^XLFDT(PSBOST,2),"@"," ")_">"
  1.  F PSBZ=.5,.6,.7 S PSBDHIT=0 F PSBY=0:0 S PSBY=$O(PSBX(PSBZ,PSBY)) Q:'PSBY  D
  1.  .W:$X>75 !
  1.  .S PSBDD=$S(PSBZ=.5:53.795,PSBZ=.6:53.796,1:53.797)
  1.  .S Y=$$EXTERNAL^DILFD(PSBDD,.01,"",$P(PSBX(PSBZ,PSBY,0),U,1))
  1.  .W $$WRAP^PSBO(75,28,Y)
  1.  .I $P(PSBX(.1),U)["U" W ?105,$J($P(PSBX(PSBZ,PSBY,0),U,2),6,2),?113,$J($P(PSBX(PSBZ,PSBY,0),U,3),6,2) W $$WRAP^PSBO(120,12,$P(PSBX(PSBZ,PSBY,0),U,4)) S PSBDHIT=1
  1.  .W:$P(PSBX(.1),U)["V"&($X+3+$L($P(PSBX(PSBZ,PSBY,0),U,3))>105) !?75
  1.  .W:$P(PSBX(.1),U)["V" " - ",$P(PSBX(PSBZ,PSBY,0),U,3)
  1.  D:$P($G(^PSB(53.79,PSBIEN,.1)),U,2)="P"
  1.  .W !?16,"PRN Reason: ",?30,$$GET1^DIQ(53.79,PSBIEN_",",.21)
  1.  .W !?16,"PRN Effectiveness: "
  1.  .I $P($G(^PSB(53.79,PSBIEN,.2)),U,2)="" W "<No PRN Effectiveness Entered>" Q
  1.  .N PSBEIECMT S PSBEIECMT="" I $P($G(^PSB(53.79,PSBIEN,.2)),U,2)'="",$P(PSBRPT(.2),U,8)=0 S PSBEIECMT=$$PRNEFF^PSBO(PSBEIECMT,PSBIEN)
  1.  .W $$WRAP^PSBO(20,100,$$GET1^DIQ(53.79,PSBIEN_",",.22)_PSBEIECMT)
  1.  .W !?20,"Entered By: ",$$GET1^DIQ(53.79,PSBIEN_",",.23)
  1.  .W " Date/Time: ",$$GET1^DIQ(53.79,PSBIEN_",",.24)
  1.  .W " Minutes: ",$$GET1^DIQ(53.79,PSBIEN_",",.25)
  1.  D:$P(PSBRPT(.2),U,8)
  1.  .W !?16,"Comments: ",?30 I '$O(PSBX(.3,0)) W "<No Comments>"
  1.  .F PSBY=0:0 S PSBY=$O(PSBX(.3,PSBY)) Q:'PSBY  D
  1.  ..W:$X>30 !?30
  1.  ..S Y=$P(PSBX(.3,PSBY,0),U,3)+.0000001
  1.  ..W $E(Y,4,5),"/",$E(Y,6,7),"/",$E(Y,2,3)
  1.  ..W " ",$E(Y,9,10),":",$E(Y,11,12)
  1.  ..W ?46,$$GET1^DIQ(53.793,PSBY_","_PSBIEN_",","ENTERED BY:INITIAL")
  1.  ..W $$WRAP^PSBO(52,70,$P(PSBX(.3,PSBY,0),U,1))
  1.  W !,$TR($$FMTE^XLFDT(PSBOSP,2),"@"," ")_"<"
  1.  D:PSBAUDF
  1.  .W !?16,"Audits: ",?30 I '$O(PSBX(.9,0)) W "<No Audits>" Q
  1.  .F PSBY=0:0 S PSBY=$O(PSBX(.9,PSBY)) Q:'PSBY  D
  1.  ..W:$X>30 !?30
  1.  ..S Y=$P(PSBX(.9,PSBY,0),U,1)+.0000001
  1.  ..W $E(Y,4,5),"/",$E(Y,6,7),"/",$E(Y,2,3)
  1.  ..W " ",$E(Y,9,10),":",$E(Y,11,12)
  1.  ..W ?46,$$GET1^DIQ(53.799,PSBY_","_PSBIEN_",","USER:INITIAL")
  1.  ..W $$WRAP^PSBO(52,70,$P(PSBX(.9,PSBY,0),U,3))
  1.  W !,$TR($J("",IOM)," ","-")
  1.  Q ""
  1.  ;
  1. WDHDR(PSBWARD) ;
  1.  D WARD^PSBOHDR(PSBWARD,.PSBHDR)
  1.  W $$SUB()
  1.  Q ""
  1.  ;
  1. PTHDR() ;
  1.  D PT^PSBOHDR(DFN,.PSBHDR)
  1.  W $$SUB()
  1.  Q ""
  1.  ;
  1. SUB() ; Med Log Sub Header
  1.  W:$X>1 !
  1.  W "Activity Date",?16,"Orderable Item",?50,"Action",?57,"Action"
  1.  W !,"Start Date>",?16,"[Dose/Sched/Route/Inj Site]",?50,"By"
  1.  W ?57,"Date/Time",?75,"Drug/Additive/Solution",?105," U/Ord"
  1.  W ?113," U/Gvn",?120,"Unit",!,"Stop Date<"
  1.  W !,$TR($J("",IOM)," ","-")
  1.  Q ""
  1.  ;
  1.  ;
  1. PTID(DFN,TYP) ;
  1.  N VADM,VAERR,VA
  1.  D DEM^VADPT
  1.  Q $S($G(TYP):$G(VA("BID")),1:$G(VA("PID")))