Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: PSBVDLPB

PSBVDLPB.m

Go to the documentation of this file. 
  1. PSBVDLPB ;BIRMINGHAM/EFC-BCMA IV VIRTUAL DUE LIST ;Mar 2004
  1.  ;;3.0;BAR CODE MED ADMIN;**11,13,38,32**;Mar 2004;Build 32
  1.  ;Per VHA Directive 2004-038 (or future revisions regarding same), this routine should not be modified.
  1.  ;
  1.  ; Reference/IA
  1.  ; EN^PSJBCMA/2828
  1.  ; $$GET^XPAR/2263
  1.  ; File 200/10060
  1.  ;
  1. EN(DFN,PSBDT) ; Default Order List Return for Today
  1.  ;
  1.  ; RPC: PSB GETORDERLIST
  1.  ;
  1.  ; Description:
  1.  ; Returns the current IV order set for today to display on the
  1.  ; client VDL
  1.  ;
  1.  ;
  1.  N PSBDATA,PSBTBOUT
  1.  S PSBTBOUT=0,PSBDOADD=0
  1.  S:PSBTAB="PBTAB" PSBDOADD=1
  1.  ;
  1.  ;This routine now re-uses the ^TMP("PSJ",$J global built in PSBVDLTB
  1.  ;
  1.  I $G(^TMP("PSJ",$J,1,0))=-1 Q  ; No orders
  1.  ;
  1.  F PSBX=0:0 S PSBX=$O(^TMP("PSJ",$J,PSBX)) Q:('PSBX)!(PSBTBOUT)  D
  1.  .D CLEAN^PSBVT,PSJ^PSBVT(PSBX)
  1.  .;
  1.  .; << Standard checks for ALL orders >>
  1.  .;
  1.  .Q:PSBONX["P"  ;     No Pending Orders
  1.  .Q:'$$IVPTAB^PSBVDLU3(PSBOTYP,PSBIVT,PSBISYR,PSBCHEMT,PSBIVPSH)
  1.  .Q:PSBOST>PSBWADM  ; Order Start Date/Time > admin window
  1.  .Q:PSBOSP<PSBWBEG  ; For all Order Stop Date/Time < vdl window
  1.  .Q:PSBOSTS["D"  ;     Is it DC'd
  1.  .Q:PSBNGF  ;  Is it marked DO NOT GIVE!
  1.  .; Non One-Times with stop date/time < now
  1.  .;
  1.  .D NOW^%DTC
  1.  .Q:PSBOSP<%
  1.  .;
  1.  .; include Active, Renewed, ReInstated and On Call
  1.  .; (Is it not one time)&(Is it not active or renewed or On Call)
  1.  .Q:PSBSCHT'="O"&((PSBOSTS'="A")&(PSBOSTS'="R")&(PSBOSTS'="RE")&(PSBOSTS'="O")&(PSBOSTS'="H"))
  1.  .;
  1.  .; Is One Time Given
  1.  .;
  1.  .I PSBSCHT="O" D  Q:PSBGVN
  1.  ..S (PSBGVN,X,Y)=""
  1.  ..F  S X=$O(^PSB(53.79,"AOIP",DFN,PSBOIT,X),-1) Q:'X  D
  1.  ...F  S Y=$O(^PSB(53.79,"AOIP",DFN,PSBOIT,X,Y),-1) Q:'Y  S:($P(^PSB(53.79,Y,.1),U)=PSBONX)&($P(^PSB(53.79,Y,0),U,9)="G") PSBGVN=1,(X,Y)=0
  1.  .;
  1.  .; How long does One Time remain on VDL ?
  1.  .S PSBRMN=1
  1.  .I PSBSCHT="O",PSBOSP'=PSBOST,%>PSBOSP S PSBRMN=0
  1.  .Q:'PSBRMN
  1.  .;
  1.  .; Is On-Call Given, Can it be given more than once
  1.  .;
  1.  .I PSBSCHT="OC" D  Q:PSBGVN&('$$GET^XPAR("DIV","PSB ADMIN MULTIPLE ONCALL"))
  1.  ..S (PSBGVN,X,Y)=""
  1.  ..F  S X=$O(^PSB(53.79,"AOIP",DFN,PSBOIT,X),-1) Q:'X  D
  1.  ...F  S Y=$O(^PSB(53.79,"AOIP",DFN,PSBOIT,X,Y),-1) Q:'Y  S:($P(^PSB(53.79,Y,.1),U)=PSBON)&($P(^PSB(53.79,Y,0),U,9)="G") PSBGVN=1,(X,Y)=0
  1.  .;
  1.  .S PSBSTRT=PSBOST ; Order Start Date/Time
  1.  .S PSBSTOP=PSBOSP ; Order Stop Date/Time
  1.  .;
  1.  .S PSBREC=""
  1.  .S $P(PSBREC,U,1)=DFN ; dfn
  1.  .S $P(PSBREC,U,2)=PSBONX ; Order
  1.  .S $P(PSBREC,U,3)=+PSBON ; order ien
  1.  .S $P(PSBREC,U,4)=PSBOTYP ; iv/ud/pending
  1.  .S $P(PSBREC,U,5)=PSBSCHT ; schedule type
  1.  .S $P(PSBREC,U,6)=PSBSCH ; schedule
  1.  .S Y=""
  1.  .S:PSBSM Y="SM"
  1.  .S:PSBHSM Y="HSM"
  1.  .S $P(PSBREC,U,7)=Y ; self med
  1.  .S $P(PSBREC,U,8)=PSBOITX ; drugname
  1.  .S $P(PSBREC,U,9)=PSBDOSE_" "_PSBIFR ; dosage
  1.  .S $P(PSBREC,U,10)=PSBMR ;med route
  1.  .; Last Given from the AOIP X-Ref - not given status not excepted
  1.  .S (YZ,PSBSTUS,PSBADMER)="" K PSBHSTA,PSBHSTAX
  1.  .F XZ=1:1:20 S YZ=$O(^PSB(53.79,"AOIP",DFN,PSBOIT,YZ),-1),(PSBCNT,PSBFLAG)=0 Q:YZ=""  D
  1.  ..S:YZ>0 $P(PSBREC,U,11)=YZ
  1.  ..S X="" F  S X=$O(^PSB(53.79,"AOIP",DFN,PSBOIT,YZ,X),-1) Q:X=""  D
  1.  ...K PSBLCK L +^PSB(53.79,X):1  I  L -^PSB(53.79,X) S PSBLCK=1
  1.  ...S PSBSTUS=$P(^PSB(53.79,X,0),U,9)
  1.  ...I $G(PSBSTUS)="" S:'$G(PSBLCK) PSBSTUS="X" I $G(PSBLCK) S PSBADMER=1 D
  1.  ....K PSBPARM3,PSBPARM5,PSBPARM6,PSBPARM7
  1.  ....S PSBPARM6=X,Y=$P(^PSB(53.79,X,.1),U,3) D DD^%DT S PSBPARM3=Y,Y=$P(^PSB(53.79,X,0),U,6) D DD^%DT S PSBPARM5=Y
  1.  ....S PSBPARM7=$P(^PSB(53.79,X,0),U,7) S PSBPARM7="( # "_PSBPARM7_" ) "_$$GET1^DIQ(200,PSBPARM7_",",.01)
  1.  ....K PSBXTMP S PSBXTMP=PSBONX
  1.  ....D CLEAN^PSBVT,PSJ1^PSBVT(DFN,$$GET1^DIQ(53.79,PSBPARM6_",",.11))
  1.  ....D ERROR^PSBMLU(PSBONX,PSBOITX,DFN,PSBPARM3_" admin's ACTION STATUS is ""UNKNOWN"".",PSBSCH,PSBPARM5,PSBPARM6,PSBPARM7) ;  SEND AN E-MAIL
  1.  ....D CLEAN^PSBVT,PSJ1^PSBVT(DFN,PSBXTMP)  ;Reset Variables
  1.  ....S X=PSBPARM6 K PSBPARM3,PSBPARM5,PSBPARM6,PSBPARM7
  1.  ...K PSBLCK S:(PSBSTUS']"") PSBSTUS="U"  I PSBSTUS'="N",($G(PSBSTUS)'="X") S PSBFLAG=1,PSBHSTA(YZ,$G(PSBSTUS))="ORIG"_U_X
  1.  ...D:PSBSTUS="N"
  1.  ....S $P(PSBREC,U,11)=""
  1.  ....S Z="" F  S Z=$O(^PSB(53.79,X,.9,Z),-1) Q:'Z  Q:PSBFLAG=1  S PSBDATA=$G(^(Z,0)) D
  1.  .....I (PSBDATA["Set to 'NOT GIVEN'")!(PSBDATA["Set to 'GIVEN'")!(PSBDATA["Set to 'REFUSED'")!(PSBDATA["Set to 'HELD'")!(PSBDATA["Set to 'MISSING DOSE'")!(PSBDATA["Set to 'REMOVED'") S PSBCNT=PSBCNT+1
  1.  .....I (PSBDATA["STATUS 'HELD'")!(PSBDATA["STATUS 'GIVEN'")!(PSBDATA["STATUS 'REFUSED'")!(PSBDATA["STATUS 'MISSING DOSE'")!(PSBDATA["STATUS 'REMOVED'") S PSBCNT=PSBCNT+1
  1.  .....I PSBCNT#2=0,PSBDATA["'REFUSED'" S PSBSTUS="R" D LAST^PSBVDLU1
  1.  .....I PSBCNT#2=0,PSBDATA["'HELD'" S PSBSTUS="H" D LAST^PSBVDLU1
  1.  .....I PSBCNT#2=0,PSBDATA["'MISSING DOSE'" S PSBSTUS="M" D LAST^PSBVDLU1
  1.  .....I PSBCNT#2=0,PSBDATA["'REMOVED'" S PSBSTUS="RM" D LAST^PSBVDLU1
  1.  .....I PSBFLAG=1,'$D(PSBHSTA($P(PSBREC,U,11),$G(PSBSTUS))) S PSBHSTA($P(PSBREC,U,11),$G(PSBSTUS))=Z_U_X
  1.  .I $D(PSBHSTA) S $P(PSBREC,U,11)=$O(PSBHSTA(""),-1),PSBSTUS=$O(PSBHSTA($P(PSBREC,U,11),""),-1) M PSBHSTAX(PSBOIT)=PSBHSTA K PSBHSTA  ;last action date/time
  1.  .S $P(PSBREC,U,12)=""  ;med log ien inserted below for actual date
  1.  .S $P(PSBREC,U,13)=""  ;med log status inserted below for actual date
  1.  .S $P(PSBREC,U,14)="" ;admin date inserted below
  1.  .S $P(PSBREC,U,15)=PSBOIT ; OI Pointer
  1.  .S $P(PSBREC,U,16)=PSBNJECT  ;Set injectable med route flag
  1.  .; Variable dosage entered as ####-####?
  1.  .I $P(PSBREC,U,9)?1.4N1"-"1.4N.E S $P(PSBREC,U,17)=1
  1.  .E  S $P(PSBREC,U,17)=0
  1.  .S $P(PSBREC,U,18)=PSBIVT  ;IV TYPE - dosage form
  1.  .S $P(PSBREC,U,20)=$S((PSBSTUS="X")!(PSBSTUS="N"):"",1:PSBSTUS) ;last action status
  1.  .S $P(PSBREC,U,21)=PSBOST
  1.  .S $P(PSBREC,U,22)=PSBOSTS
  1.  .S $P(PSBREC,U,26)=PSBSTOP
  1.  .S $P(PSBREC,U,27)=$$LASTG^PSBCSUTL(DFN,PSBOIT)
  1.  .;
  1.  .; Gather Dispense Drugs
  1.  .D NOW^%DTC
  1.  .S (PSBDDS,PSBSOLS,PSBADDS)="0"
  1.  .F Y=0:0 S Y=$O(PSBDDA(Y)) Q:'Y  D
  1.  ..Q:$P(PSBDDA(Y),U,4)&($P(PSBDDA(Y),U,4)<%)  ; Inactive
  1.  ..S:$P(PSBDDA(Y),U,3)="" $P(PSBDDA(Y),U,3)=1
  1.  ..S PSBDDS=PSBDDS_U_$P(PSBDDA(Y),U,1,3)
  1.  ..S $P(PSBDDS,U,1)=PSBDDS+1
  1.  .; On-Call One Time PRN orders
  1.  .S PSBQRR=0
  1.  .I "^O^OC^P^"[(U_PSBSCHT_U) D  Q
  1.  ..I 'PSBDOADD S PSBTBOUT=1,^TMP("PSB",$J,"PBTAB",0)=2,^TMP("PSB",$J,"PBTAB",1)=1,^TMP("PSB",$J,"PBTAB",2)=1 Q
  1.  ..D ADD^PSBVDLU1(PSBREC,PSBOTXT,PSBNOW\1,PSBDDS,PSBSOLS,PSBADDS,"PBTAB")
  1.  .;
  1.  .; IV's - don't worry about admin times if blank
  1.  .I PSBONX["V","PSC"'[PSBIVT,PSBADST="" D  Q
  1.  ..I 'PSBDOADD S PSBTBOUT=1,^TMP("PSB",$J,"PBTAB",0)=2,^TMP("PSB",$J,"PBTAB",1)=1,^TMP("PSB",$J,"PBTAB",2)=1 Q
  1.  ..D ADD^PSBVDLU1(PSBREC,PSBOTXT,PSBNOW\1_".",PSBDDS,PSBSOLS,PSBADDS,"PBTAB")
  1.  .;
  1.  .; Now we deal with only continuous
  1.  .; process admintimes
  1.  .S (PSBYES,PSBODD,PSBYTF)=0
  1.  .S:$$PSBDCHK1^PSBVT1(PSBSCH) PSBYES=1
  1.  .I PSBYES,PSBADST="" D ERROR^PSBMLU(PSBONX,PSBOITX,DFN,"Admin times required",PSBSCH) Q
  1.  .F I=1:1 Q:$P(PSBSCH,"-",I)=""  I $P(PSBSCH,"-",I)?2N!($P(PSBSCH,"-",I)?4N) S PSBYES=1,PSBYTF=1
  1.  .I PSBSCHT="C",PSBYTF="1",PSBADST="" D ERROR^PSBMLU(PSBONX,PSBOITX,DFN,"Admin times required",PSBSCH) Q
  1.  .S PSBFREQ=$$GETFREQ^PSBVDLU1(DFN,PSBONX)
  1.  .I PSBFREQ="O" S PSBFREQ=1440
  1.  .I PSBFREQ="D" S PSBFREQ=""
  1.  .I 'PSBYES,PSBFREQ<1 D ERROR^PSBMLU(PSBONX,PSBOITX,DFN,"Invalid frequency received from order",PSBSCH) Q
  1.  .S PSBADMIN=PSBADST
  1.  .I (PSBADMIN="")&(+PSBFREQ>0) D ODDSCH^PSBVDLU1("PBTAB") Q  ;calculate admin times based on frequency
  1.  .; No admin times, MAYDAY MAYDAY!!
  1.  .I +PSBFREQ>0 I (PSBFREQ#1440'=0),(1440#PSBFREQ'=0) S PSBODD=1
  1.  .I PSBODD,PSBADST'="" D ERROR^PSBMLU(PSBONX,PSBOITX,DFN,"Administration Times on ODD SCHEDULE",PSBSCH) Q
  1.  .; process admin times against beginning and ending date
  1.  .; build all orders for both days.
  1.  .F PSBY=1:1 Q:$P(PSBADMIN,"-",PSBY)=""  D
  1.  ..;For invalid admin times
  1.  ..I ($P(PSBADST,"-",PSBY)'?2N)&($P(PSBADST,"-",PSBY)'?4N) D ERROR^PSBMLU(PSBONX,PSBOITX,DFN,"Invalid Admin times",PSBSCH)
  1.  ..; apply this time to the beginning window date
  1.  ..S PSB=+(PSBWBEG\1_"."_$P(PSBADMIN,"-",PSBY))
  1.  ..D:(PSB'<PSBWBEG)&(PSB'>PSBWEND)  ; Make sure it is in the window
  1.  ...D:(PSB'<PSBSTRT)&(PSB<PSBSTOP)  ; Make sure this time is active
  1.  ....D:$$OKAY^PSBVDLU1(PSBSTRT,PSB,PSBSCH,PSBON,PSBOITX,PSBFREQ,PSBOSTS)  ; Okay on this date?
  1.  .....I 'PSBDOADD S PSBTBOUT=1,^TMP("PSB",$J,"PBTAB",0)=2,^TMP("PSB",$J,"PBTAB",1)=1,^TMP("PSB",$J,"PBTAB",2)=1 Q
  1.  .....D ADD^PSBVDLU1(PSBREC,PSBOTXT,PSB,PSBDDS,PSBSOLS,PSBADDS,"PBTAB")
  1.  ..;
  1.  ..Q:(PSBWBEG\1)=(PSBWEND\1)  ; Window only has one day rare but possible
  1.  ..;
  1.  ..; apply this time to the ending window date
  1.  ..S PSB=+(PSBWEND\1_"."_$P(PSBADMIN,"-",PSBY))
  1.  ..D:(PSB'<PSBWBEG)&(PSB'>PSBWEND)  ; Make sure it is in the window
  1.  ...D:(PSB'<PSBSTRT)&(PSB<PSBSTOP)  ; Make sure this time is active
  1.  ....D:$$OKAY^PSBVDLU1(PSBSTRT,PSB,PSBSCH,PSBON,PSBOITX,PSBFREQ,PSBOSTS)  ; Okay on this date?
  1.  .....I 'PSBDOADD S PSBTBOUT=1,^TMP("PSB",$J,"PBTAB",0)=2,^TMP("PSB",$J,"PBTAB",1)=1,^TMP("PSB",$J,"PBTAB",2)=1 Q
  1.  .....D ADD^PSBVDLU1(PSBREC,PSBOTXT,PSB,PSBDDS,PSBSOLS,PSBADDS,"PBTAB")
  1.  ;
  1.  ;add initials of verifying pharmacist/verifying nurse
  1.  D:PSBDOADD VNURSE^PSBVDLU1("PBTAB")
  1.  Q
  1.  ;