- PSDCOR ;BIR/JPW-CS Correction Action ; 6 July 94
- ;;3.0; CONTROLLED SUBSTANCES ;**66**;13 Feb 97;Build 3
- EN1 ;sets type=1
- S TYPE=1 G START
- EN2 ;sets type=2
- S TYPE=2 G START
- EN3 ;sets type=3
- S TYPE=3
- START ;start proc
- I '$D(PSDSITE) D ^PSDSET Q:'$D(PSDSITE)
- I '$D(^XUSEC("PSDMGR",DUZ)) W $C(7),!!,?9,"** Please contact your Pharmacy Coordinator for access to correct",!,?12,"narcotic orders.",!!,"PSDMGR security key required.",! K TYPE Q
- W !!,"Controlled Substances Correction Action" S PSDUZ=DUZ
- G:TYPE=2 ^PSDCOR1 G:TYPE=3 ^PSDCOR2
- ASKN ;ask naou
- W ! K DA,DIC S DIC=58.8,DIC(0)="QEAZ",DIC("A")="Select NAOU: "
- S DIC("S")="I $P(^(0),""^"",3)=+PSDSITE,$S('$D(^(""I"")):1,'^(""I""):1,+^(""I"")>DT:1,1:0),$P(^(0),""^"",2)=""N"",'$P(^(0),""^"",7)"
- D ^DIC K DIC G:Y<0 END S AOU=+Y,AOUN=$P(Y,"^",2)
- GS ;select green sheet #
- W $C(7),!!,?15,"** NOTE **",!,"Your Green Sheet selection is limited to those Green Sheets flagged as",!,"'COMPLETED - GREEN SHEET READY FOR PICKUP' on the selected NAOU.",!
- W ! K DA,DIC S DIC("A")="Select the Green Sheet #: ",DIC=58.81,DIC(0)="QEASZ",D="D"
- S DIC("S")="I $P(^(0),""^"",11)=5,$P(^(0),""^"",18)=AOU"
- D IX^DIC K DIC G:Y<0 END S PSDA=+Y
- S STAT=+$P(Y(0),"^",11),PSDPN=$P(Y(0),"^",17),STATN="" I STAT S STATN=$P($G(^PSD(58.82,STAT,0)),"^")
- S PSDS=+$P(Y(0),"^",3)
- S ORD=+$P(Y(0),"^",20),NAOU=+$P(Y(0),"^",18),NAOUN=$P($G(^PSD(58.8,NAOU,0)),"^"),PSDR=+$P(Y(0),"^",5)
- S NURS=$P($G(^PSD(58.81,PSDA,1)),"^",10)
- I AOU'=NAOU W $C(7),!!,"The Green Sheet # ",PSDPN," is assigned to ",NAOUN,".",!,"Please select another Green Sheet.",! G GS
- I '$D(^PSD(58.8,NAOU,1,PSDR,3,ORD,0)) W $C(7),!!,"There's no data on ",NAOUN," for Green Sheet # ",PSDPN,".",!,"Contact your Pharmacy Coordinator for assistance.",! G END
- I STAT'=5 W $C(7),!!,"This Green Sheet has a status of "_$S(STATN]"":STATN,1:"UNKNOWN")_".",!,"Please select another Green Sheet.",! G GS
- ASK W !!,"This action will update Green Sheet #",PSDPN," as ",!,?5,"** DELIVERED - ACTIVELY ON NAOU **",!
- W ! K DA,DIR,DIRUT S DIR(0)="Y",DIR("A")="Are you sure",DIR("B")="NO"
- S DIR("?",1)="Answer 'YES' to update the status to 'DELIVERED - ACTIVELY ON NAOU' or",DIR("?")="answer 'NO' to quit and the status will remain 'COMPLETED - GREEN SHEET READY FOR PICKUP'."
- D ^DIR K DIR I 'Y W !!,"No action taken.",!! G END
- COM ;complete correction
- D NOW^%DTC S RECDT=+$E(%,1,12)
- W !!,"Accessing Green Sheet #",PSDPN," information...",!!
- F L +^PSD(58.87,0):$S($G(DILOCKTM)>0:DILOCKTM,1:3) I Q
- FIND S PSDCOR=$P(^PSD(58.87,0),"^",3)+1 I $D(^PSD(58.87,PSDCOR)) S $P(^PSD(58.87,0),"^",3)=PSDCOR G FIND
- K DA,DIC,DLAYGO S (DIC,DLAYGO)=58.87,DIC(0)="L",X=PSDCOR D ^DIC K DIC,DLAYGO
- L -^PSD(58.87,0)
- K DA,DIE,DR S DIE=58.87,DA=PSDCOR,DR="1////"_RECDT_";2////"_PSDUZ_";3////"_PSDPN_";4////"_PSDR_";5////"_NAOU_";6////"_NURS_";8////"_ORD_";11////"_TYPE_";12////"_PSDS
- D ^DIE K DA,DIE,DR
- W !!,"Updating your records now..."
- ;update transaction file (58.81)
- K DA,DIE,DR S DA=PSDA,DIE=58.81,DR="10////4" D ^DIE K DA,DIE,DR
- I $D(Y)!$D(DTOUT) W $C(7),!!,"** THIS GREEN SHEET HAS NOT BEEN CORRECTED **",!!,"The status remains "_STATN,! G END
- K DA,DIE,DR S DA=ORD,DA(1)=PSDR,DA(2)=NAOU,DIE="^PSD(58.8,"_DA(2)_",1,"_DA(1)_",3,",DR="10////4" D ^DIE K DA,DIE,DR
- S STAT=$P($G(^PSD(58.81,PSDA,0)),"^",11) W ?2,!,"*** Your Green Sheet #"_PSDPN_" is now "_$S($P($G(^PSD(58.82,STAT,0)),"^")]"":$P(^(0),"^"),1:"UNKNOWN")_" ***",!
- END K %,%DT,%H,%I,AOU,AOUN,D,DA,DIC,DIE,DIR,DIROUT,DIRUT,DR,DTOUT,DUOUT
- K NAOU,NAOUN,NURS,OK,ORD,PSDA,PSDCOR,PSDPN,PSDR,PSDS,PSDUZ,RECDT,STAT,STATN,TYPE,X,Y
- Q
- PSDCOR ;BIR/JPW-CS Correction Action ; 6 July 94
- +1 ;;3.0; CONTROLLED SUBSTANCES ;**66**;13 Feb 97;Build 3
- EN1 ;sets type=1
- +1 SET TYPE=1
- GOTO START
- EN2 ;sets type=2
- +1 SET TYPE=2
- GOTO START
- EN3 ;sets type=3
- +1 SET TYPE=3
- START ;start proc
- +1 IF '$DATA(PSDSITE)
- DO ^PSDSET
- IF '$DATA(PSDSITE)
- QUIT
- +2 IF '$DATA(^XUSEC("PSDMGR",DUZ))
- WRITE $CHAR(7),!!,?9,"** Please contact your Pharmacy Coordinator for access to correct",!,?12,"narcotic orders.",!!,"PSDMGR security key required.",!
- KILL TYPE
- QUIT
- +3 WRITE !!,"Controlled Substances Correction Action"
- SET PSDUZ=DUZ
- +4 IF TYPE=2
- GOTO ^PSDCOR1
- IF TYPE=3
- GOTO ^PSDCOR2
- ASKN ;ask naou
- +1 WRITE !
- KILL DA,DIC
- SET DIC=58.8
- SET DIC(0)="QEAZ"
- SET DIC("A")="Select NAOU: "
- +2 SET DIC("S")="I $P(^(0),""^"",3)=+PSDSITE,$S('$D(^(""I"")):1,'^(""I""):1,+^(""I"")>DT:1,1:0),$P(^(0),""^"",2)=""N"",'$P(^(0),""^"",7)"
- +3 DO ^DIC
- KILL DIC
- IF Y<0
- GOTO END
- SET AOU=+Y
- SET AOUN=$PIECE(Y,"^",2)
- GS ;select green sheet #
- +1 WRITE $CHAR(7),!!,?15,"** NOTE **",!,"Your Green Sheet selection is limited to those Green Sheets flagged as",!,"'COMPLETED - GREEN SHEET READY FOR PICKUP' on the selected NAOU.",!
- +2 WRITE !
- KILL DA,DIC
- SET DIC("A")="Select the Green Sheet #: "
- SET DIC=58.81
- SET DIC(0)="QEASZ"
- SET D="D"
- +3 SET DIC("S")="I $P(^(0),""^"",11)=5,$P(^(0),""^"",18)=AOU"
- +4 DO IX^DIC
- KILL DIC
- IF Y<0
- GOTO END
- SET PSDA=+Y
- +5 SET STAT=+$PIECE(Y(0),"^",11)
- SET PSDPN=$PIECE(Y(0),"^",17)
- SET STATN=""
- IF STAT
- SET STATN=$PIECE($GET(^PSD(58.82,STAT,0)),"^")
- +6 SET PSDS=+$PIECE(Y(0),"^",3)
- +7 SET ORD=+$PIECE(Y(0),"^",20)
- SET NAOU=+$PIECE(Y(0),"^",18)
- SET NAOUN=$PIECE($GET(^PSD(58.8,NAOU,0)),"^")
- SET PSDR=+$PIECE(Y(0),"^",5)
- +8 SET NURS=$PIECE($GET(^PSD(58.81,PSDA,1)),"^",10)
- +9 IF AOU'=NAOU
- WRITE $CHAR(7),!!,"The Green Sheet # ",PSDPN," is assigned to ",NAOUN,".",!,"Please select another Green Sheet.",!
- GOTO GS
- +10 IF '$DATA(^PSD(58.8,NAOU,1,PSDR,3,ORD,0))
- WRITE $CHAR(7),!!,"There's no data on ",NAOUN," for Green Sheet # ",PSDPN,".",!,"Contact your Pharmacy Coordinator for assistance.",!
- GOTO END
- +11 IF STAT'=5
- WRITE $CHAR(7),!!,"This Green Sheet has a status of "_$SELECT(STATN]"":STATN,1:"UNKNOWN")_".",!,"Please select another Green Sheet.",!
- GOTO GS
- ASK WRITE !!,"This action will update Green Sheet #",PSDPN," as ",!,?5,"** DELIVERED - ACTIVELY ON NAOU **",!
- +1 WRITE !
- KILL DA,DIR,DIRUT
- SET DIR(0)="Y"
- SET DIR("A")="Are you sure"
- SET DIR("B")="NO"
- +2 SET DIR("?",1)="Answer 'YES' to update the status to 'DELIVERED - ACTIVELY ON NAOU' or"
- SET DIR("?")="answer 'NO' to quit and the status will remain 'COMPLETED - GREEN SHEET READY FOR PICKUP'."
- +3 DO ^DIR
- KILL DIR
- IF 'Y
- WRITE !!,"No action taken.",!!
- GOTO END
- COM ;complete correction
- +1 DO NOW^%DTC
- SET RECDT=+$EXTRACT(%,1,12)
- +2 WRITE !!,"Accessing Green Sheet #",PSDPN," information...",!!
- +3 FOR
- LOCK +^PSD(58.87,0):$SELECT($GET(DILOCKTM)>0:DILOCKTM,1:3)
- IF $TEST
- QUIT
- FIND SET PSDCOR=$PIECE(^PSD(58.87,0),"^",3)+1
- IF $DATA(^PSD(58.87,PSDCOR))
- SET $PIECE(^PSD(58.87,0),"^",3)=PSDCOR
- GOTO FIND
- +1 KILL DA,DIC,DLAYGO
- SET (DIC,DLAYGO)=58.87
- SET DIC(0)="L"
- SET X=PSDCOR
- DO ^DIC
- KILL DIC,DLAYGO
- +2 LOCK -^PSD(58.87,0)
- +3 KILL DA,DIE,DR
- SET DIE=58.87
- SET DA=PSDCOR
- SET DR="1////"_RECDT_";2////"_PSDUZ_";3////"_PSDPN_";4////"_PSDR_";5////"_NAOU_";6////"_NURS_";8////"_ORD_";11////"_TYPE_";12////"_PSDS
- +4 DO ^DIE
- KILL DA,DIE,DR
- +5 WRITE !!,"Updating your records now..."
- +6 ;update transaction file (58.81)
- +7 KILL DA,DIE,DR
- SET DA=PSDA
- SET DIE=58.81
- SET DR="10////4"
- DO ^DIE
- KILL DA,DIE,DR
- +8 IF $DATA(Y)!$DATA(DTOUT)
- WRITE $CHAR(7),!!,"** THIS GREEN SHEET HAS NOT BEEN CORRECTED **",!!,"The status remains "_STATN,!
- GOTO END
- +9 KILL DA,DIE,DR
- SET DA=ORD
- SET DA(1)=PSDR
- SET DA(2)=NAOU
- SET DIE="^PSD(58.8,"_DA(2)_",1,"_DA(1)_",3,"
- SET DR="10////4"
- DO ^DIE
- KILL DA,DIE,DR
- +10 SET STAT=$PIECE($GET(^PSD(58.81,PSDA,0)),"^",11)
- WRITE ?2,!,"*** Your Green Sheet #"_PSDPN_" is now "_$SELECT($PIECE($GET(^PSD(58.82,STAT,0)),"^")]"":$PIECE(^(0),"^"),1:"UNKNOWN")_" ***",!
- END KILL %,%DT,%H,%I,AOU,AOUN,D,DA,DIC,DIE,DIR,DIROUT,DIRUT,DR,DTOUT,DUOUT
- +1 KILL NAOU,NAOUN,NURS,OK,ORD,PSDA,PSDCOR,PSDPN,PSDR,PSDS,PSDUZ,RECDT,STAT,STATN,TYPE,X,Y
- +2 QUIT
