PSDORP2.m

PSDORP2 ;BIR/JPW,LTL-Pharm CS Order Request Entry ; 22 Jun 94

 ;;3.0; CONTROLLED SUBSTANCES ;;13 Feb 97

QTY K ORD S (CNT,PSDR(2),PSDOUT)=0

 ;DISPLAY STOCK LEVEL

 W:$P($G(^PSD(58.8,+NAOU,1,+PSDR,0)),U,3) !,"Stock Level:  ",$P($G(^(0)),U,3)," ",NBKU,!

 ;Dispensing Sites's Max Qty per order

 S PSDR(1)=$P($G(^PSD(58.8,+PSDS,1,+PSDR,0)),U,7)

 ;ASK QUANTITY

 S DIR(0)="NA^1:999999:0"

 S DIR("A")="QUANTITY ("_NBKU_"/"_NPKG_"): ",DIR("B")=NPKG

 S:PSDR(1) DIR("A",1)="Maximum quantity per order:  "_PSDR(1)_" "_NBKU,DIR("A",2)=""

 S DIR("?",1)="Because "_NAOUN_" is keeping a perpetual inventory,"

 S DIR("?",2)=$S(PSDR(1):"a maximum quantity of "_PSDR(1)_" "_NBKU_" per order",1:"no maximum order quantity")_" has been set for "_PSDRN_"."

 S:PSDR(1) DIR("?")="If you request more than "_PSDR(1)_" "_NBKU_", multiple orders will be generated.",DIR("?",3)="for "_PSDRN_".",DIR("?",4)=""

 D ^DIR K DIR G:Y<1 END S PSDQTY=Y

 ;quantity ordered is equal to or less than max ord qty

NOMAX I 'PSDR(1)!(Y'>PSDR(1)) D DIE,ASK^PSDORP1 G:PSDOUT END G DRUG^PSDORP

 ;QUANTITY EXCEEDS MAX ORD QTY, MULTIPLE ORDERS

 S:(PSDQTY#PSDR(1)) CNT=1,PSDR(2)=(PSDQTY#PSDR(1))

 S CNT=$G(CNT)+(Y\PSDR(1))

 W !!,"This will be "_CNT_" separate order requests,"

 W:PSDR(2) !!,"One order for ",PSDR(2)," ",NBKU,", and"

 W !!,(PSDQTY\PSDR(1))," order"

 W:CNT>2!('PSDR(2)&(CNT=2)) "s"

 W " for ",PSDR(1)," ",NBKU,"."

 W ! K DA,DIR,DIRUT S DIR(0)="Y",DIR("A")="Do you want me to generate the "_CNT_" separate order requests",DIR("B")="YES",DIR("?",1)="Answer 'YES' to create the multiple order requests,"

 S DIR("?")="Answer 'NO' to edit your quantity or '^' to quit." D ^DIR K DIR G:$D(DIRUT) END

 I 'Y W !,"No order request created.  You must edit quantity.",! G QTY

 I Y W !!,"The "_CNT_" requests are being created.  You must review every request.",! S PSDQTY=$S(PSDR(2):PSDR(2),1:PSDR(1)) D  D ^PSDORP1 S PSDQTY=PSDR(1)

 .F ORD=1:1:CNT W !!,"Creating your order request # "_ORD_" of "_CNT_" for "_PSDRN D DIE S ORD(ORD)=PSDA

 G:'PSDOUT DRUG^PSDORP

END K %,%DT,%H,%I,CNT,CNT1,DA,DIC,DIE,DINUM,DIR,DIROUT,DIRUT,DIWF,DIWL,DIWR,DR,DTOUT,DUOUT,LN,MSG,MSG1

 K NAOU,NAOUN,NBKU,NPKG,OK,OKTYP,ORD,PSDA,PSDOUT,PSDQTY,PSDRD,PSDR,PSDRN,PSDS,PSDT,PSDUZ,PSDUZA,PSDUZN,REQD,TEXT,TYPE,WORD,X,Y

 Q

DIE ;create the order request

 S:'$D(^PSD(58.8,NAOU,1,PSDR,3,0)) ^(0)="^58.800118A^^"

 S PSDA=$P(^PSD(58.8,NAOU,1,PSDR,3,0),"^",3)+1 I $D(^PSD(58.8,NAOU,1,PSDR,3,PSDA)) S $P(^PSD(58.8,NAOU,1,PSDR,3,0),"^",3)=$P(^PSD(58.8,NAOU,1,PSDR,3,0),"^",3)+1 G DIE

 K DA,DIC,DIE,DD,DR,DO S DIC(0)="L",(DIC,DIE)="^PSD(58.8,"_NAOU_",1,"_PSDR_",3,",DA(2)=NAOU,DA(1)=PSDR,(X,DINUM)=PSDA D FILE^DICN K DIC

 D NOW^%DTC S PSDT=+$E(%,1,12) W ?10,!!,"processing now..."

 S DA=PSDA,DA(1)=PSDR,DA(2)=NAOU,DR="1////"_PSDT_";2////"_PSDS_";10////1;5////"_PSDQTY_";13;3//^S X=PSDUZN" D ^DIE K DIE,DR

 S PSDUZA=+$P($G(^PSD(58.8,NAOU,1,PSDR,3,PSDA,0)),"^",4)

 Q

MSG ;display error message

 W $C(7),!!,?10,"Contact your Pharmacy Coordinator.",!,?10,"This "_$S(MSG=2:"Dispensing Site",MSG=1:"NAOU",1:"PSDR")_" is missing "

 W $S(MSG1=1:"Primary Disp. Site",MSG1=2:"stocked drugs",MSG1=3:"narcotic breakdown unit",MSG1=4:"narcotic package size",1:"data")_".",!

 Q

PSDORP2   ;BIR/JPW,LTL-Pharm CS Order Request Entry ; 22 Jun 94

 +1       ;;3.0; CONTROLLED SUBSTANCES ;;13 Feb 97

QTY        KILL ORD

           SET (CNT,PSDR(2),PSDOUT)=0

 +1       ;DISPLAY STOCK LEVEL

 +2        IF $PIECE($GET(^PSD(58.8,+NAOU,1,+PSDR,0)),U,3)

               WRITE !,"Stock Level:  ",$PIECE($GET(^(0)),U,3)," ",NBKU,!

 +3       ;Dispensing Sites's Max Qty per order

 +4        SET PSDR(1)=$PIECE($GET(^PSD(58.8,+PSDS,1,+PSDR,0)),U,7)

 +5       ;ASK QUANTITY

 +6        SET DIR(0)="NA^1:999999:0"

 +7        SET DIR("A")="QUANTITY ("_NBKU_"/"_NPKG_"): "

           SET DIR("B")=NPKG

 +8        IF PSDR(1)

               SET DIR("A",1)="Maximum quantity per order:  "_PSDR(1)_" "_NBKU

               SET DIR("A",2)=""

 +9        SET DIR("?",1)="Because "_NAOUN_" is keeping a perpetual inventory,"

 +10       SET DIR("?",2)=$SELECT(PSDR(1):"a maximum quantity of "_PSDR(1)_" "_NBKU_" per order",1:"no maximum order quantity")_" has been set for "_PSDRN_"."

 +11       IF PSDR(1)

               SET DIR("?")="If you request more than "_PSDR(1)_" "_NBKU_", multiple orders will be generated."

               SET DIR("?",3)="for "_PSDRN_"."

               SET DIR("?",4)=""

 +12       DO ^DIR

           KILL DIR

           IF Y<1

               GOTO END

           SET PSDQTY=Y

 +13      ;quantity ordered is equal to or less than max ord qty

NOMAX      IF 'PSDR(1)!(Y'>PSDR(1))

               DO DIE

               DO ASK^PSDORP1

               IF PSDOUT

                   GOTO END

               GOTO DRUG^PSDORP

 +1       ;QUANTITY EXCEEDS MAX ORD QTY, MULTIPLE ORDERS

 +2        IF (PSDQTY#PSDR(1))

               SET CNT=1

               SET PSDR(2)=(PSDQTY#PSDR(1))

 +3        SET CNT=$GET(CNT)+(Y\PSDR(1))

 +4        WRITE !!,"This will be "_CNT_" separate order requests,"

 +5        IF PSDR(2)

               WRITE !!,"One order for ",PSDR(2)," ",NBKU,", and"

 +6        WRITE !!,(PSDQTY\PSDR(1))," order"

 +7        IF CNT>2!('PSDR(2)&(CNT=2))

               WRITE "s"

 +8        WRITE " for ",PSDR(1)," ",NBKU,"."

 +9        WRITE !

           KILL DA,DIR,DIRUT

           SET DIR(0)="Y"

           SET DIR("A")="Do you want me to generate the "_CNT_" separate order requests"

           SET DIR("B")="YES"

           SET DIR("?",1)="Answer 'YES' to create the multiple order requests,"

 +10       SET DIR("?")="Answer 'NO' to edit your quantity or '^' to quit."

           DO ^DIR

           KILL DIR

           IF $DATA(DIRUT)

               GOTO END

 +11       IF 'Y

               WRITE !,"No order request created.  You must edit quantity.",!

               GOTO QTY

 +12       IF Y

               WRITE !!,"The "_CNT_" requests are being created.  You must review every request.",!

               SET PSDQTY=$SELECT(PSDR(2):PSDR(2),1:PSDR(1))

               Begin DoDot:1

 +13               FOR ORD=1:1:CNT

                       WRITE !!,"Creating your order request # "_ORD_" of "_CNT_" for "_PSDRN

                       DO DIE

                       SET ORD(ORD)=PSDA

               End DoDot:1

               DO ^PSDORP1

               SET PSDQTY=PSDR(1)

 +14       IF 'PSDOUT

               GOTO DRUG^PSDORP

END        KILL %,%DT,%H,%I,CNT,CNT1,DA,DIC,DIE,DINUM,DIR,DIROUT,DIRUT,DIWF,DIWL,DIWR,DR,DTOUT,DUOUT,LN,MSG,MSG1

 +1        KILL NAOU,NAOUN,NBKU,NPKG,OK,OKTYP,ORD,PSDA,PSDOUT,PSDQTY,PSDRD,PSDR,PSDRN,PSDS,PSDT,PSDUZ,PSDUZA,PSDUZN,REQD,TEXT,TYPE,WORD,X,Y

 +2        QUIT 

DIE       ;create the order request

 +1        IF '$DATA(^PSD(58.8,NAOU,1,PSDR,3,0))

               SET ^(0)="^58.800118A^^"

 +2        SET PSDA=$PIECE(^PSD(58.8,NAOU,1,PSDR,3,0),"^",3)+1

           IF $DATA(^PSD(58.8,NAOU,1,PSDR,3,PSDA))

               SET $PIECE(^PSD(58.8,NAOU,1,PSDR,3,0),"^",3)=$PIECE(^PSD(58.8,NAOU,1,PSDR,3,0),"^",3)+1

               GOTO DIE

 +3        KILL DA,DIC,DIE,DD,DR,DO

           SET DIC(0)="L"

           SET (DIC,DIE)="^PSD(58.8,"_NAOU_",1,"_PSDR_",3,"

           SET DA(2)=NAOU

           SET DA(1)=PSDR

           SET (X,DINUM)=PSDA

           DO FILE^DICN

           KILL DIC

 +4        DO NOW^%DTC

           SET PSDT=+$EXTRACT(%,1,12)

           WRITE ?10,!!,"processing now..."

 +5        SET DA=PSDA

           SET DA(1)=PSDR

           SET DA(2)=NAOU

           SET DR="1////"_PSDT_";2////"_PSDS_";10////1;5////"_PSDQTY_";13;3//^S X=PSDUZN"

           DO ^DIE

           KILL DIE,DR

 +6        SET PSDUZA=+$PIECE($GET(^PSD(58.8,NAOU,1,PSDR,3,PSDA,0)),"^",4)

 +7        QUIT 

MSG       ;display error message

 +1        WRITE $CHAR(7),!!,?10,"Contact your Pharmacy Coordinator.",!,?10,"This "_$SELECT(MSG=2:"Dispensing Site",MSG=1:"NAOU",1:"PSDR")_" is missing "

 +2        WRITE $SELECT(MSG1=1:"Primary Disp. Site",MSG1=2:"stocked drugs",MSG1=3:"narcotic breakdown unit",MSG1=4:"narcotic package size",1:"data")_".",!

 +3        QUIT