PSDRPGS.m

PSDRPGS ;BIR/JPW-Reprint Green Sheet (VA FORM 10-2638) ; 29 Aug 94

 ;;3.0; CONTROLLED SUBSTANCES ;;13 Feb 97

 I '$D(PSDSITE) D ^PSDSET Q:'$D(PSDSITE)

 S OK=$S($D(^XUSEC("PSJ RPHARM",DUZ)):1,$D(^XUSEC("PSJ PHARM TECH",DUZ)):1,1:0)

 I 'OK W $C(7),!!,?9,"** Please contact your Pharmacy Coordinator for access to",!,?12,"reprint Green Sheets.",!!,"PSJ RPHARM or PSJ PHARM TECH security key required.",! K OK Q

ASKD ;ask dispensing location

 S PSDS=$P(PSDSITE,U,3),PSDSN=$P(PSDSITE,U,4)

 I $P(PSDSITE,U,5) S PRT=+$P($G(^PSD(58.8,+PSDS,2)),"^",6),ASK=+$G(^(2.5)) G GS1

 W ! K DIC,DA S DIC=58.8,DIC(0)="QEAZ",DIC("S")="I $P(^(0),""^"",3)=+PSDSITE,$S($P(^(0),""^"",2)[""M"":1,$P(^(0),""^"",2)[""S"":1,1:0)",DIC("A")="Select Primary Dispensing Site: ",DIC("B")=$P(PSDSITE,U,4)

 D ^DIC K DIC G:Y<0 END

 S PSDS=+Y,PSDSN=$P(Y,"^",2),PRT=+$P($G(^PSD(58.8,+PSDS,2)),"^",6),ASK=+$G(^PSD(58.8,+PSDS,2.5)),$P(PSDSITE,U,3)=+Y,$P(PSDSITE,U,4)=PSDSN

GS1 ;ask gs # range

 W !!,"You may enter a Green Sheet # list and/or a Green Sheet # range.",!

 W "NOTE: This response must be a list or range, e.g., 1,3,5 or 2-4,8.",!

 K DA,DIR,DIRUT S DIR(0)="LOA^0:999999999",DIR("A")="Select Green Sheet #(s): "

 D ^DIR K DIR G:$D(DIRUT) END

 S PSD1="" F  S PSD1=$O(Y(PSD1)) Q:PSD1=""  S:$D(Y(PSD1)) PSD1(PSD1)=Y(PSD1) K Y(PSD1)

DEV ;ask device and queue info

 W $C(7),!!,"This report now prints on plain paper.",!,"Please check your printer before starting this report.",!!,"You may queue this report to print at a later time.",!!

 S PSDCPI=10

 S Y=$P($G(^PSD(58.8,+PSDS,2)),"^",8),C=$P(^DD(58.8,24,0),"^",2) D Y^DIQ S PSDEV=Y

 K %ZIS,IOP,IO("Q"),POP S %ZIS="Q",%ZIS("B")=PSDEV D ^%ZIS I POP W !,"NO DEVICE SELECTED OR REPORT PRINTED!" G END

 I $D(IO("Q")) K IO("Q"),ZTIO,ZTSAVE,ZTDTH,ZTSK S ZTRTN="START^PSDRPGS2",ZTDESC="Reprint Green Sheets (VA FORM 10-2638)" D SAVE D ^%ZTLOAD,HOME^%ZIS K ZTSK G END

 U IO G START^PSDRPGS2

END K %ZIS,ANS,ASK,C,CNT,D,DA,DIC,DIE,DIR,DIROUT,DIRUT,DR,DTOUT,DUOUT,EXP,EXPD,LINE,LOT,NAOU,NAOUN,NODE,NODE1,PSDW

 K OK,ORD,ORDN,POP,PRT,PSD,PSD1,PSDA,PSDBY,PSDBYN,PSDCNT,PSDDT,PSDEV,PSDOUT,PSDCPI,PSDPN,PSDR,PSDRN,PSDS,PSDSN,PSDT,PSDTR,PSDTRN,REPRINT,QTY,SITE,STAT,TRANS,Y,ZTDESC,ZTDTH,ZTRTN,ZTSAVE,ZTSK

 D ^%ZISC S:$D(ZTQUEUED) ZTREQ="@"

 Q

SAVE ;save var

 S (ZTSAVE("ASK"),ZTSAVE("PSDS"),ZTSAVE("PSDSN"),ZTSAVE("PSDCPI"))="" S:$D(REPRINT) ZTSAVE("REPRINT")=""

 S ZTSAVE("PSD1(")=""

 Q

PSDRPGS   ;BIR/JPW-Reprint Green Sheet (VA FORM 10-2638) ; 29 Aug 94

 +1       ;;3.0; CONTROLLED SUBSTANCES ;;13 Feb 97

 +2        IF '$DATA(PSDSITE)

               DO ^PSDSET

               IF '$DATA(PSDSITE)

                   QUIT 

 +3        SET OK=$SELECT($DATA(^XUSEC("PSJ RPHARM",DUZ)):1,$DATA(^XUSEC("PSJ PHARM TECH",DUZ)):1,1:0)

 +4        IF 'OK

               WRITE $CHAR(7),!!,?9,"** Please contact your Pharmacy Coordinator for access to",!,?12,"reprint Green Sheets.",!!,"PSJ RPHARM or PSJ PHARM TECH security key required.",!

               KILL OK

               QUIT 

ASKD      ;ask dispensing location

 +1        SET PSDS=$PIECE(PSDSITE,U,3)

           SET PSDSN=$PIECE(PSDSITE,U,4)

 +2        IF $PIECE(PSDSITE,U,5)

               SET PRT=+$PIECE($GET(^PSD(58.8,+PSDS,2)),"^",6)

               SET ASK=+$GET(^(2.5))

               GOTO GS1

 +3        WRITE !

           KILL DIC,DA

           SET DIC=58.8

           SET DIC(0)="QEAZ"

           SET DIC("S")="I $P(^(0),""^"",3)=+PSDSITE,$S($P(^(0),""^"",2)[""M"":1,$P(^(0),""^"",2)[""S"":1,1:0)"

           SET DIC("A")="Select Primary Dispensing Site: "

           SET DIC("B")=$PIECE(PSDSITE,U,4)

 +4        DO ^DIC

           KILL DIC

           IF Y<0

               GOTO END

 +5        SET PSDS=+Y

           SET PSDSN=$PIECE(Y,"^",2)

           SET PRT=+$PIECE($GET(^PSD(58.8,+PSDS,2)),"^",6)

           SET ASK=+$GET(^PSD(58.8,+PSDS,2.5))

           SET $PIECE(PSDSITE,U,3)=+Y

           SET $PIECE(PSDSITE,U,4)=PSDSN

GS1       ;ask gs # range

 +1        WRITE !!,"You may enter a Green Sheet # list and/or a Green Sheet # range.",!

 +2        WRITE "NOTE: This response must be a list or range, e.g., 1,3,5 or 2-4,8.",!

 +3        KILL DA,DIR,DIRUT

           SET DIR(0)="LOA^0:999999999"

           SET DIR("A")="Select Green Sheet #(s): "

 +4        DO ^DIR

           KILL DIR

           IF $DATA(DIRUT)

               GOTO END

 +5        SET PSD1=""

           FOR 

               SET PSD1=$ORDER(Y(PSD1))

               IF PSD1=""

                   QUIT 

               IF $DATA(Y(PSD1))

                   SET PSD1(PSD1)=Y(PSD1)

               KILL Y(PSD1)

DEV       ;ask device and queue info

 +1        WRITE $CHAR(7),!!,"This report now prints on plain paper.",!,"Please check your printer before starting this report.",!!,"You may queue this report to print at a later time.",!!

 +2        SET PSDCPI=10

 +3        SET Y=$PIECE($GET(^PSD(58.8,+PSDS,2)),"^",8)

           SET C=$PIECE(^DD(58.8,24,0),"^",2)

           DO Y^DIQ

           SET PSDEV=Y

 +4        KILL %ZIS,IOP,IO("Q"),POP

           SET %ZIS="Q"

           SET %ZIS("B")=PSDEV

           DO ^%ZIS

           IF POP

               WRITE !,"NO DEVICE SELECTED OR REPORT PRINTED!"

               GOTO END

 +5        IF $DATA(IO("Q"))

               KILL IO("Q"),ZTIO,ZTSAVE,ZTDTH,ZTSK

               SET ZTRTN="START^PSDRPGS2"

               SET ZTDESC="Reprint Green Sheets (VA FORM 10-2638)"

               DO SAVE

               DO ^%ZTLOAD

               DO HOME^%ZIS

               KILL ZTSK

               GOTO END

 +6        USE IO

           GOTO START^PSDRPGS2

END        KILL %ZIS,ANS,ASK,C,CNT,D,DA,DIC,DIE,DIR,DIROUT,DIRUT,DR,DTOUT,DUOUT,EXP,EXPD,LINE,LOT,NAOU,NAOUN,NODE,NODE1,PSDW

 +1        KILL OK,ORD,ORDN,POP,PRT,PSD,PSD1,PSDA,PSDBY,PSDBYN,PSDCNT,PSDDT,PSDEV,PSDOUT,PSDCPI,PSDPN,PSDR,PSDRN,PSDS,PSDSN,PSDT,PSDTR,PSDTRN,REPRINT,QTY,SITE,STAT,TRANS,Y,ZTDESC,ZTDTH,ZTRTN,ZTSAVE,ZTSK

 +2        DO ^%ZISC

           IF $DATA(ZTQUEUED)

               SET ZTREQ="@"

 +3        QUIT 

SAVE      ;save var

 +1        SET (ZTSAVE("ASK"),ZTSAVE("PSDS"),ZTSAVE("PSDSN"),ZTSAVE("PSDCPI"))=""

           IF $DATA(REPRINT)

               SET ZTSAVE("REPRINT")=""

 +2        SET ZTSAVE("PSD1(")=""

 +3        QUIT