Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: PSGOE82

PSGOE82.m

Go to the documentation of this file. 
  1. PSGOE82 ;BIR/CML3-NON-VERIFIED ORDER EDIT (CONT.) ;27 Jan 98 / 9:32 AM
  1.  ;;5.0; INPATIENT MEDICATIONS ;**2,35,50,67,58,81,127,168**;16 DEC 97
  1.  ;
  1.  ; Reference to ^DD(53.1 is supported by DBIA #2256.
  1.  ; Reference to ^VA(200 is supported by DBIA #10060.
  1.  ; Reference to ^DIE is supported by DBIA #10018.
  1.  ; Reference to ^DIC is supported by DBIA #10006.
  1.  ; Reference to ^DICN is supported by DBIA #10009.
  1.  ;
  1. 1 ; provider
  1.  S MSG=0,PSGF2=1 S:PSGOEEF(PSGF2) BACK="1^PSGOE82"
  1. A1 I $G(PSGORD)["P",$G(PSGP) I $$LASTREN^PSJLMPRI(PSGP,PSGORD) D  Q
  1.  . W !?5,"This order has been renewed. Provider may not be edited at this point. " D PAUSE^VALM1
  1.  W !,"PROVIDER: ",$S(PSGPR:PSGPRN_"// ",1:"") R X:DTIME I X="^"!'$T W:'$T $C(7) S PSGOEE=0 G DONE
  1.  I $S(X="":'PSGPR,1:X="@") W $C(7),"  (Required)" S X="?" D ENHLP^PSGOEM(53.1,1) G A1
  1.  I X="",PSGPR S X=PSGPRN I PSGPR'=PSGPRN,$D(^VA(200,PSGPR,"PS")) W:0 "    "_$P(^("PS"),"^",2)_"    "_$P(^("PS"),"^",3) G DONE
  1.  I X?1."?" D ENHLP^PSGOEM(53.1,1)
  1.  I $E(X)="^" D ENFF G:Y>0 @Y G A1
  1.  K DIC S DIC="^VA(200,",DIC(0)="EMQZ",DIC("S")="I $D(^(""PS"")),^(""PS""),$S('$P(^(""PS""),""^"",4):1,1:$P(^(""PS""),""^"",4)>DT)" D ^DIC K DIC I Y'>0 G A1
  1.  S PSGPR=+Y,PSGPRN=Y(0,0) G DONE
  1.  ;
  1. 5 ; self med
  1.  S MSG=0,PSGF2=5 S:PSGOEEF(PSGF2) BACK="5^PSGOE82" K PSGOEEF(6) S:PSGSM PSGOEEF(6)=1
  1. A5 W !,"SELF MED: " W $P("NO^YES","^",PSGSM+1),"// " R X:DTIME I X="^"!'$T W:'$T $C(7) S PSGOEE=0 G DONE
  1.  ;I "01"[X,$L(X)<2 S:PSGSM=""&(X]"") PSGSM=X W:PSGSM]"" "  (",$P("NO^YES","^",PSGSM+1),")" G:'PSGSM DONE S PSGOEEF(6)=1 G 6
  1.  I "01"[X,$L(X)<2 S:X]"" PSGSM=+X W:PSGSM]"" "  (",$P("NO^YES","^",PSGSM+1),")" G:'PSGSM DONE S PSGOEEF(6)=1 G 6
  1.  I X="@" W $C(7),"  (Required)" G A5
  1.  I X?1"^".E D ENFF G:Y>0 @Y G A5
  1.  I X?1."?" D ENHLP^PSGOEM(53.1,5) G A5
  1.  D YN I  S PSGSM=$E(X)="Y" K PSGOEEF(6) G:'PSGSM DONE S PSGOEEF(6)=1 G 6
  1.  W $C(7) D ENHLP^PSGOEM(53.1,5) G A5
  1.  ;
  1. 6 ; hospital supplied self med
  1.  S MSG=0,PSGF2=6 S:PSGOEEF(PSGF2) BACK="6^PSGOE82"
  1. A6 W !,"HOSPITAL SUPPLIED SELF MED: " W:PSGHSM]"" $P("NO^YES","^",PSGHSM+1),"// " R X:DTIME I X="^"!'$T W:'$T $C(7) S PSGOEE=0 G DONE
  1.  I "01"[X,$L(X)=1 S:X]"" PSGHSM=+X W "  (",$P("NO^YES","^",PSGHSM+1),")" S MSG=0,PSGF2=5 G DONE
  1.  I X="@" W $C(7),"  (Required)" G A6
  1.  I X?1"^".E D ENFF G:Y>0 @Y G A6
  1.  I X?1."?" D ENHLP^PSGOEM(53.1,6) G A6
  1.  D YN I  S PSGHSM=$E(X)="Y" S MSG=0,PSGF2=5 G DONE
  1.  W $C(7) D ENHLP^PSGOEM(53.1,6) G A6
  1.  ;
  1. 2 ; dispense drug multiple
  1.  S MSG=0,PSGF2=2,BACK="2^PSGOE82" K PSGOEEND
  1.  N PSGX,PSGXX F PSGXX=0:0 S PSGX=PSGXX,PSGXX=$O(^PS(53.45,PSJSYSP,2,PSGXX)) Q:'PSGXX
  1.  N PSJPNDRN I $G(PSGORD) I $E(PSGORD,$L(PSGORD))="P",$P($G(^PS(53.1,+PSGORD,0)),"^",24)="R" S PSJPNDRN=1 D
  1.  .S $P(PSJPNDRN,"^",2)="Dispense drugs for renewal orders cannot be deleted, but can be given an INACTIVE DATE.  "
  1.  N DA,DIC,DIE,DR,DIR S DIE="^PS(53.45,",DA=PSJSYSP,DR=2,DR(2,53.4502)=".01;.02"_$S($G(PSJPNDRN):";.03",1:"") D ^DIE
  1.  I '$O(^PS(53.45,PSJSYSP,2,0)) W $C(7),!!,"WARNING: This order must have at least one dispense drug before pharmacy can",!?9,"verify it!",! S MSG=1
  1.  D DDOC(PSGX)
  1.  NEW PSJDOSE
  1.  D DOSECHK^PSJDOSE
  1.  I +$G(PSJDSFLG) D DSPWARN^PSJDOSE S PSGOEEF(109)=1
  1.  G DONE
  1.  ;
  1. 40 ; comments
  1.  S MSG=0,PSGF2=40,BACK="40^PSGOE82",DA=PSJSYSP,DR=1,DIE="^PS(53.45," D ^DIE W ! G DONE
  1.  ;
  1. 66 ; provider comments
  1.  ;S MSG=0,PSGF2=66,BACK="66^PSGOE82",DA=PSJSYSP,DR=4,DIE="^PS(53.45," D ^DIE W ! G DONE
  1.  ;
  1. DONE ;
  1.  I PSGOEE G:'PSGOEEF(PSGF2) @BACK S PSGOEE=PSGOEEF(PSGF2)
  1.  K F,F0,PSGF2,F3,PSG,SDT Q
  1.  ;
  1. ENFF ; up-arrow to another field
  1.  S Y=-1 I '$D(PSGOEEF)!(X?1"^"1.9N) W $C(7),"  ??" Q
  1.  S X=$E(X,2,99) I X=+X S Y=$S($D(PSGOEEF(X)):X,1:-1) W "  " W:Y>0 $$CODES2^PSIVUTL(53.1,X) W:Y'>0 $C(7),"??" Q
  1.  K DIC S DIC="^DD(53.1,",DIC(0)="QEM",DIC("S")="I $D(PSGOEEF(+Y))" D ^DIC K DIC S Y=+Y S:Y>0 Y=$P($T(@("F"_Y)),";",3) Q
  1.  ;
  1. DEL ; delete entry
  1.  W !?3,"SURE YOU WANT TO DELETE" S %=0 D YN^DICN I %'=1 W $C(7),"  <NOTHING DELETED>"
  1.  Q
  1.  ;
  1. YN ; yes/no as a set of codes
  1.  I X'?.U F Y=1:1:$L(X) I $E(X,Y)?1L S X=$E(X,1,Y-1)_$C($A(X,Y)-32)_$E(X,Y+1,$L(X))
  1.  F Y="NO","YES" I $P(Y,X)="" W $P(Y,X,2) Q
  1.  Q
  1. DDOC(PSGX) ; Order check on additional dispens drug for allergy and adv. reactions.
  1.  N PSGY,PSGND1,PSGND3 S PSGY=0 F  S PSGX=$O(^PS(53.45,PSJSYSP,2,PSGX)) Q:'PSGX  S PSGY=$P($G(^PS(53.45,PSJSYSP,2,PSGX,0)),"^") Q:PSGY=""  D
  1.  . N INTERVEN,PSJDDI,PSJIREQ,PSJRXREQ,PSJDD,PSGORQF,PSJPDRG S PSJDD=PSGY
  1.  . S Y=1,(PSJIREQ,PSJRXREQ,INTERVEN,X)=""
  1.  . D IVSOL^PSGSICHK
  1.  . I ($D(PSGORQF)) D
  1.  .. K ^PS(53.45,PSJSYSP,2,PSGX),^PS(53.45,PSJSYSP,2,"B",PSGY)
  1.  Q
  1.  ;
  1. F101 ;;101^PSGOE8
  1. F109 ;;109^PSGOE8
  1. F3 ;;3^PSGOE8
  1. F7 ;;7^PSGOE8
  1. PSGF26 ;;26^PSGOE8
  1. F39 ;;39^PSGOE81
  1. F8 ;;8^PSGOE81
  1. F10 ;;10^PSGOE81
  1. PSGF25 ;;25^PSGOE81
  1. F1 ;;1^PSGOE82
  1. F5 ;;5^PSGOE82
  1. PSGF2 ;;2^PSGOE82