Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: PSOBAI

PSOBAI.m

Go to the documentation of this file. 
  1. PSOBAI ;BIR/EJW - BAD ADDRESS PROCESSING ;02/02/2006
  1.  ;;7.0;OUTPATIENT PHARMACY;**233,258,268,264**;DEC 1997;Build 19
  1.  ;
  1.  ;External reference EN^DGREGAED supported by DBIA 4198
  1.  ;External reference UPDATE^DGADDUTL supported by DBIA 4886
  1.  ;External reference ^DPT( supported by DBIA 5031
  1.  ;
  1. CHKADDR(PSODFN,WARN,UPDATE) ; CHECK ADDRESS BY PATIENT
  1.  ;Input: PSODFN - PATIENT file (#2) IEN
  1.  ;       WARN - Display warning (optional)
  1.  ;       UPDATE - If bad address flagged, prompt to update patient address (optional)
  1.  ;If calling from patient selection, if bad, even if there is an active temporary address, prompt to update the address
  1.  N PSOBADR,PSOTEMP
  1.  I PSODFN="" Q
  1.  S PSOBADR=$$BADADR^DGUTL3(PSODFN)
  1.  I PSOBADR D
  1.  .S PSOTEMP=$$CHKTEMP(PSODFN)
  1.  .I $G(WARN) D
  1.  ..D WARN1
  1.  ..I $G(UPDATE) D UPDATE Q
  1.  ..D PAUSE
  1.  Q
  1.  ;
  1. CHKRX(PSORX) ;CHECK ADDRESS BY RX
  1.  ;Input: PSORX - PRESCRIPTION file (#52) IEN
  1.  ;Output: PSOBADR - Bad Address Indicator_"^"_temporary address or not
  1.  N PSOBADR,PSODFN,PSOTEMP
  1.  S PSOBADR=""
  1.  I PSORX="" Q 0
  1.  S PSODFN=$P($G(^PSRX(PSORX,0)),"^",2) I PSODFN="" Q 0
  1.  S PSOBADR=$$BADADR^DGUTL3(PSODFN)
  1.  I PSOBADR S PSOTEMP=$$CHKTEMP(PSODFN)
  1.  S PSOBADR=PSOBADR_"^"_$G(PSOTEMP)
  1.  Q PSOBADR
  1.  ;
  1. WARN1 ;
  1.  W !!,?8,"WARNING: The patient address is indicated as a bad"
  1.  W !,?17,"address (",$S(PSOBADR=1:"UNDELIVERABLE",PSOBADR=2:"HOMELESS",1:"OTHER"),")."
  1.  I $G(PSOTEMP) W !,?17,"* Temporary address is active *" Q
  1.  W !,?17,"Medication will not be mailed to"
  1.  W !,?17,"the patient until the address has been"
  1.  W !,?17,"corrected.",!
  1.  Q
  1. CHKTEMP(PSODFN) ; see if active temporary address
  1.  ;Input: PSODFN - PATIENT file (#2) IEN
  1.  N DFN,VAPA
  1.  S DFN=PSODFN,PSOTEMP=0
  1.  D 6^VADPT I +VAPA(9) S PSOTEMP=1
  1.  Q PSOTEMP
  1.  ;
  1. UPDATE ;
  1.  N PSOSEL,DA
  1.  I '$D(PSOPAR) D ^PSOLSET
  1.  I '$P($G(PSOPAR),"^",22),'$D(^XUSEC("PSO ADDRESS UPDATE",+$G(DUZ))) D PAUSE Q
  1.  K DIR S DIR(0)="Y",DIR("B")="N",DIR("A")="Do you want to update the address/phone"
  1.  D ^DIR K DIR
  1.  I Y'=1 Q
  1.  L +^DPT(PSODFN):$S(+$G(^DD("DILOCKTM"))>0:+^DD("DILOCKTM"),1:3) I '$T D MSG,PAUSE Q
  1.  K DIR S DIR(0)="SAO^P:PERMANENT;T:TEMPORARY;B:BOTH"
  1.  S DIR("A")=" Update (P)ermanent address, (T)emporary, or (B)oth: "
  1.  S DIR("B")="BOTH" D ^DIR
  1.  I $D(DIRUT) G ULK
  1.  S PSOSEL=Y
  1.  I PSOSEL="P"!(PSOSEL="B") D
  1.  .;D UPDATE^DGADDUTL(PSODFN,"PERM") - THIS CALL CLEARS BAI FLAG INAPPROPRIATELY SO USE FOLLOWING TO UPDATE PERMANENT ADDRESS/PHONE INSTEAD 5/29/06
  1.  .N PSOFLG
  1.  .S PSOFLG(1)=1 D EN^DGREGAED(PSODFN,.PSOFLG) W !
  1.  S DA=PSODFN,DIE="^DPT(",DR=".134" D ^DIE W !
  1.  I PSOSEL="P" D ULK Q
  1.  I PSOSEL="B"!(PSOSEL="T") D UPDATE^DGADDUTL(PSODFN,"TEMP"),ULK,PAUSE
  1.  Q
  1. ULK ;
  1.  L -^DPT(PSODFN)
  1.  Q
  1.  ;
  1. PAUSE ;
  1.  W ! K DIR S DIR(0)="E",DIR("A")="Press Return to continue" D ^DIR K DIR
  1.  Q
  1.  ;
  1. MSG ;
  1.  S VALMSG="Patient Data is being edited by another user!"
  1.  Q
  1.  ;