Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: PSODRG

PSODRG.m

Go to the documentation of this file. 
  1. PSODRG ;IHS/DSD/JCM-ORDER ENTRY DRUG SELECTION ;28-Mar-2016 12:57;DU
  1.  ;;7.0;OUTPATIENT PHARMACY;**20,23,36,53,54,46,112,139,1005,1013,207,148,243,268,1015,1016,1021**;DEC 1997;Build 14
  1.  ;Reference ^PSDRUG supported by DBIA 221
  1.  ;Reference ^PS(50.7 supported by DBIA 2223
  1.  ;Reference to PSSDIN supported by DBIA 3166
  1.  ;Reference to $$NDCFMT^PSSNDCUT supported by IA 4707
  1.  ; Modified IHS/CIA/PLS - 12/30/03 - Line SET+15 and POST+11
  1.  ;          IHS/MSC/PLS - 01/05/07 - Line SET+9
  1.  ;          IHS/MSC/MGH - 10/05/11 - Line START+7
  1.  ;          IHS/MSC/MGH - 02/08/12 - Line SELECT+11
  1.  ;          IHS/MSC/MGH - 12/21/12 - Line POST+16 and POST+21
  1.  ;          IHS/MSC/MGH - 04/04/13 - Line POST+7
  1.  ;          IHS/MSC/PLS - 0/28/2016 - Line SELECT+19
  1.  ;----------------------------------------------------------
  1. START ;
  1.  S (PSONEW("DFLG"),PSONEW("FIELD"),PSODRG("QFLG"))=0
  1.  D @($S(+$G(PSOEDIT)=1&('$D(DA)):"SELECT^PSODRGN",1:"SELECT"))
  1.  G:$G(PSORXED("DFLG")) END ; Select Drug
  1.  I $G(PSORX("EDIT")),$G(PSOY),$G(PSODRUG("IEN"))=+PSOY D  G:$G(PSORXED("DFLG")) END
  1.  . N NDC D NDC(+$G(PSORXED("IRXN")),0,+PSOY,.NDC) I $G(NDC)="^" S PSORXED("DFLG")=1 Q
  1.  . I $G(NDC)'="" S (PSODRUG("NDC"),PSORXED("FLD",27))=NDC
  1.  ;
  1.  I $G(PSORX("EDIT"))]"",'PSONEW("FIELD") D TRADE
  1.  G:PSONEW("DFLG")!(PSODRG("QFLG"))!($G(PSORXED("DFLG"))) END
  1.  D SET ; Set various drug information
  1.  D NFI ; Display dispense drug/orderable item text
  1.  ;IHS/MSC/MGH Add text for REM medication Patch 1013
  1.  D REMMSG^APSPFUNC(PSODRUG("IEN"))
  1.  D:'$G(PSOEDIT) POST I $G(PSORX("DFLG")) S PSONEW("DFLG")=1 K:'$G(PSORX("EDIT")) PSORX("DFLG") ; Do any post selection action
  1. END ;D EOJ
  1.  Q
  1.  ;------------------------------------------------------------
  1.  ;
  1. SELECT ;
  1.  K:'$G(PSORXED) CLOZPAT
  1.  K DIC,X,Y,PSODRUG("TRADE NAME"),PSODRUG("NDC"),PSODRUG("DAW") S:$G(POERR)&($P($G(OR0),"^",9)) Y=$P(^PSDRUG($P(OR0,"^",9),0),"^")
  1.  I $G(PSODRUG("IEN"))]"" S Y=PSODRUG("NAME"),PSONEW("OLD VAL")=PSODRUG("IEN")
  1.  W !,"DRUG: "_$S($G(Y)]"":Y_"// ",1:"") R X:$S($D(DTIME):DTIME,1:300) I '$T S DTOUT=1
  1.  I X="",$G(Y)]"" S:Y X=Y S:'X X=$G(PSODRUG("IEN")) S:X X="`"_X
  1.  G:X="" SELECT
  1.  I X?1."?" W !!,"Answer with DRUG NUMBER, or GENERIC NAME, or VA PRODUCT NAME, or",!,"NATIONAL DRUG CLASS, or SYNONYM" G SELECT
  1.  I $G(PSORXED),X["^" S PSORXED("DFLG")=1 G SELECTX
  1.  I X="^"!(X["^^")!($D(DTOUT)) S PSONEW("DFLG")=1 G SELECTX
  1.  I '$G(POERR),X[U,$L(X)>1 S PSODIR("FLD")=PSONEW("FLD") D JUMP^PSODIR1 S:$G(PSODIR("FIELD")) PSONEW("FIELD")=PSODIR("FIELD") K PSODIR S PSODRG("QFLG")=1 G SELECTX
  1.  ;IHS/MSC/MGH changed for mixed case lookup, uses new cross-reference
  1.  ;S DIC=50,DIC(0)="EMQZVT",DIC("T")="",D="B^C^VAPN^VAC"
  1.  S DIC=50,DIC(0)="EMQZVT",DIC("T")="",D="BCAP^C^VAPN^VAC"
  1.  S DIC("S")="I $S('$D(^PSDRUG(+Y,""I"")):1,'^(""I""):1,DT'>^(""I""):1,1:0),$S($P($G(^PSDRUG(+Y,2)),""^"",3)'[""O"":0,1:1),$D(^PSDRUG(""ASP"",+$G(^(2)),+Y))"
  1.  D MIX^DIC1 K DIC,D
  1.  I $D(DTOUT) S PSONEW("DFLG")=1 G SELECTX
  1.  I $D(DUOUT) K DUOUT G SELECT
  1.  I Y<0 G SELECT
  1.  ;IHS/MSC/PLS - 03/28/2016 - CR5951
  1.  I $$ERXONLY^APSPFNC6(+Y) D  S Y=-1 G SELECT
  1.  .W !,"Drug is marked as ERX Only",*7,!
  1.  S:$G(PSONEW("OLD VAL"))=+Y&('$G(PSOEDIT)) PSODRG("QFLG")=1
  1.  K PSOY S PSOY=Y,PSOY(0)=Y(0)
  1.  I $P(PSOY(0),"^")="OTHER DRUG"!($P(PSOY(0),"^")="OUTSIDE DRUG") D TRADE
  1. SELECTX K X,Y,DTOUT,DUOUT,PSONEW("OLD VAL")
  1.  Q
  1.  ;
  1. NDC(RX,RFL,DRG,NDC) ; Editing NDC for ECME Released Rx's
  1.  S NDC=$S($G(NDC)'="":$G(NDC),1:$$GETNDC^PSONDCUT(RX,.RFL))
  1.  I $$STATUS^PSOBPSUT(RX,RFL)="" Q
  1.  I '$$RXRLDT^PSOBPSUT(RX,RFL) Q
  1.  ;
  1.  S NDC=$S($G(NDC)'="":$G(NDC),1:$$GETNDC^PSONDCUT(RX,.RFL))
  1.  D NDCEDT^PSONDCUT(RX,.RFL,$G(DRG),$G(PSOSITE),.NDC)
  1.  Q
  1.  ;
  1. TRADE ;
  1.  K DIR,DIC,DA,X,Y
  1.  S DIR(0)="52,6.5" S:$G(PSOTRN)]"" DIR("B")=$G(PSOTRN) D ^DIR K DIR,DIC
  1.  I X="@" S Y=X K DIRUT
  1.  I $D(DIRUT) S:$D(DUOUT)!$D(DTOUT)&('$D(PSORX("EDIT"))) PSONEW("DFLG")=1 G TRADEX
  1.  S PSODRUG("TRADE NAME")=Y
  1. TRADEX I $G(PSORXED("DFLG")),$D(DIRUT) S PSORXED("DFLG")=1
  1.  K DIRUT,DTOUT,DUOUT,X,Y,DA,DR,DIE
  1.  Q
  1. SET ;
  1.  N STAT S PSODRUG("IEN")=+PSOY,PSODRUG("VA CLASS")=$P(PSOY(0),"^",2)
  1.  S PSODRUG("NAME")=$P(PSOY(0),"^")
  1.  S:+$G(^PSDRUG(+PSOY,2)) PSODRUG("OI")=+$G(^(2)),PSODRUG("OIN")=$P(^PS(50.7,+$G(^(2)),0),"^")
  1.  S PSODRUG("NDF")=$S($G(^PSDRUG(+PSOY,"ND"))]"":+^("ND")_"A"_$P(^("ND"),"^",3),1:0)
  1.  S PSODRUG("MAXDOSE")=$P(PSOY(0),"^",4),PSODRUG("DEA")=$P(PSOY(0),"^",3)
  1.  S PSODRUG("CLN")=$S($D(^PSDRUG(+PSOY,"ND")):+$P(^("ND"),"^",6),1:0)
  1.  S PSODRUG("SIG")=$P(PSOY(0),"^",5)
  1.  I $G(PSODRUG("NDC"))="" S PSODRUG("NDC")=$$GETNDC^PSSNDCUT(+PSOY,$G(PSOSITE))
  1.  S:$D(PSONEW("NDC")) PSONEW("NDC")=PSODRUG("NDC")  ;IHS/MSC/PLS
  1.  S PSODRUG("DAW")=+$$GET1^DIQ(50,+PSOY,81)
  1.  S PSODRUG("STKLVL")=$G(^PSDRUG(+PSOY,660.1))
  1.  G:$G(^PSDRUG(+PSOY,660))']"" SETX
  1.  S PSOX1=$G(^PSDRUG(+PSOY,660))
  1.  S PSODRUG("COST")=$P($G(PSOX1),"^",6)
  1.  S PSODRUG("UNIT")=$P($G(PSOX1),"^",8)
  1.  S PSODRUG("EXPIRATION DATE")=$P($G(PSOX1),"^",9)
  1.  ; IHS/CIA/PLS - 12/29/03 - Added IHS specific fields
  1.  S PSODRUG("AWP")=+$P($G(^PSDRUG(+PSOY,999999931)),U,2)  ; AWP Price
  1.  S PSODRUG("MANUFACTURER")=$$GET1^DIQ(50,+PSOY,9999999.24,"E")
  1.  S PSODRUG("LOT #")=$$GET1^DIQ(50,+PSOY,9999999.25)
  1.  ;IHS/MSC/MGH Added check if manufacturers expiration date shows up
  1.  N APSPMAN S APSPMAN=$P($G(^APSPCTRL(PSOSITE,1)),U)
  1.  I APSPMAN<3 S PSODRUG("EXPIRATION DATE")=$$GET1^DIQ(50,+PSOY,9999999.26,"I")
  1.  S:($P(%APSITE,"^",11)]"")&((PSODRUG("EXPIRATION DATE")="")!(PSODRUG("EXPIRATION DATE")'>DT)) PSODRUG("EXPIRATION DATE")=$$FMADD^XLFDT(DT,$P(%APSITE,"^",11))
  1. SETX K PSOX1,PSOY
  1.  Q
  1. NFI ;display restriction/guidelines
  1.  D EN^PSSDIN(PSODRUG("OI"),PSODRUG("IEN")) S NFI=$$PROMPT^PSSDIN
  1.  I NFI]"","ODY"[NFI D TD^PSONFI
  1.  K NFI Q
  1. POST ;order checks
  1.  K PSORX("INTERVENE") N STAT,SIG,PTR,NDF,VAP S PSORX("DFLG")=0
  1.  N CMP,CMPDR,PTR
  1.  D ^PSOBUILD
  1.  D @$S($G(COPY):"^PSOCPDUP",1:"^PSODRDUP") ; Set PSORX("DFLG")=1 if process to stop
  1.  Q:$G(PSORX("DFLG"))
  1.  W:$G(PSOFIN)']"" !,"Now doing drug interaction and allergy checks.  Please wait...",!
  1.  ;IHS/MSC/MGH Check for compound med
  1.  S CMP=$P($G(^PSDRUG(PSODRUG("IEN"),999999935)),U,1)
  1.  I CMP D CMP(.PSODRUG)
  1.  E  D ^PSODGDGI
  1.  I $G(PSORX("INTERVENE"))]"" D FULL^VALM1,^PSORXI S VALMBCK="R"
  1.  G:PSORX("DFLG") POSTX
  1.  D:$P($G(^PSDRUG(PSODRUG("IEN"),"CLOZ1")),"^")]"" CLOZ G:PSORX("DFLG") POSTX
  1.  K PSORX("INTERVENE")
  1.  S X="APSQLAB" X ^%ZOSF("TEST") I $T D PRINT^APSQLAB   ; IHS/CIA/PLS - 01/18/04 - Output lab information
  1.  S PSONOAL="" D ALLERGY^PSOORUT2 D:PSONOAL'="" NOALRGY K PSONOAL
  1.  G:PSORX("DFLG") POSTX
  1.  I $D(PSODRUG("NDF")) S NDF=$P(PSODRUG("NDF"),"A"),VAP=$P(PSODRUG("NDF"),"A",2),PTR=NDF_"."_VAP
  1.  I $G(NDF) D CHK^PSODGAL(PSODFN,"DR",PTR) K NDF,VAP,PTR
  1.  I $P($G(PSODRUG("NDF")),"A")=0 D CHK1^PSODGAL(PSODFN)
  1.  I $D(PSODRUG("VA CLASS")) D CLASS^PSODGAL(PSODFN)
  1.  Q
  1. CMP(PSODRUG) ;IHS/MSC/MGH Check for compound med
  1.  N SAVE,CDRG
  1.  S CMPDR=0
  1.  S SAVE("VA CLASS")=PSODRUG("VA CLASS")
  1.  S SAVE("NDF")=PSODRUG("NDF")
  1.  F  S CMPDR=$O(^PSDRUG(PSODRUG("IEN"),999999936,CMPDR)) Q:'+CMPDR  D
  1.  .S CDRG=$P($G(^PSDRUG(PSODRUG("IEN"),999999936,CMPDR,0)),U,1)
  1.  .S PSODRUG("NDF")=$S($G(^PSDRUG(CDRG,"ND"))]"":+^("ND")_"A"_$P(^("ND"),"^",3),1:0)
  1.  .;do allergy checks
  1.  .S PTR=$$GET1^DIQ(50,CDRG,20,"I")_"."_$$GET1^DIQ(50,CDRG,22,"I")
  1.  .D CHK^PSODGAL(PSODFN,"DR",PTR)  K PTR
  1.  .S PSODRUG("VA CLASS")=$$GET1^DIQ(50,CDRG,2)
  1.  .I $D(PSODRUG("VA CLASS")) D CLASS^PSODGAL(PSODFN)
  1.  .;Do interventions
  1.  .D ^PSODGDGI
  1.  S PSODRUG("VA CLASS")=SAVE("VA CLASS")
  1.  S PSODRUG("NDF")=SAVE("NDF")
  1.  ;END MOD
  1. POSTX ;
  1.  K ^TMP($J,"DI"_PSODFN),^TMP($J,"DI")
  1.  K PSORX("INTERVENE"),DA
  1.  Q
  1.  ;
  1. EOJ ;
  1.  K PSODRG
  1.  Q
  1.  ;
  1. CLOZ ;
  1.  S ANQRTN=$P(^PSDRUG(PSODRUG("IEN"),"CLOZ1"),"^"),ANQX=0
  1.  S P(5)=PSODRUG("IEN"),DFN=PSODFN,X=ANQRTN
  1.  X ^%ZOSF("TEST") I  D @("^"_ANQRTN) S:$G(ANQX) PSORX("DFLG")=1
  1.  K P(5),ANQRTN,ANQX,X
  1.  Q
  1.  ;
  1. EN(DRG) ;returns lab test identified for clozapine order checking
  1.  K LAB I $P($G(^PSDRUG(DRG,"CLOZ1")),"^")'="PSOCLO1" S LAB("NOT")=0 Q
  1.  I $P($G(^PSDRUG(DRG,"CLOZ1")),"^")="PSOCLO1" D
  1.  .S (CNT,I)=0 F  S I=$O(^PSDRUG(DRG,"CLOZ2",I)) Q:'I  S CNT=$G(CNT)+1
  1.  .I CNT'=2 S LAB("BAD TEST")=0 K CNT Q
  1.  .K CNT F I=0:0 S I=$O(^PSDRUG(DRG,"CLOZ2",I)) Q:'I  D
  1.  ..S LABT=$S($P(^PSDRUG(DRG,"CLOZ2",I,0),"^",4)=1:"WBC",1:"ANC"),LAB(LABT)=$P(^PSDRUG(DRG,"CLOZ2",I,0),"^")_"^"_$P(^(0),"^",3)_"^"_$P(^(0),"^",4)
  1.  K LABT,I
  1.  Q
  1. NOALRGY ;
  1.  W $C(7),!,"There is no allergy assessment on file for this patient."
  1.  W !,"You will be prompted to intervene if you continue with this prescription"
  1.  K DIR
  1.  S DIR(0)="SA^1:YES;0:NO",DIR("A")="Do you want to Continue?: ",DIR("B")="N" D ^DIR
  1.  I 'Y S PSORX("DFLG")=1 Q
  1.  D ^PSORXI
  1.  Q