Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: PSOHLNE2

PSOHLNE2.m

Go to the documentation of this file. 
  1. PSOHLNE2 ;BIR/RTR-Parsing out more OERR segments ;8/13/08 2:43pm
  1.  ;;7.0;OUTPATIENT PHARMACY;**1,7,59,46,225,305**;DEC 1997;Build 8
  1.  ;External reference to DG(40.8 supported by DBIA 728
  1.  ;External reference to PS(50.606 supported by DBIA 2174
  1.  ;External reference to PS(50.7 supported by DBIA 2223
  1.  ;External reference to PSDRUG( supported by DBIA 221
  1.  ;External reference to PS(55 supported by DBIA 2228
  1.  ;External reference to SC( supported by DBIA 2675
  1.  ;External reference to EN^ORERR supported by DBIA 2187
  1.  ;
  1. EN ;RXO segment on new orders with multiple subscripts
  1.  S (POVAR,POVAR1)="",(NNN,NNNN)=0,PSOIII=1,MSG(ZZ,0)=$E(MSG(ZZ),5,$L(MSG(ZZ)))
  1.  S AAA="" F  S AAA=$O(MSG(ZZ,AAA)) Q:AAA=""  S NNN=0 F OOO=1:1:$L(MSG(ZZ,AAA)) S NNN=NNN+1 D  D:$G(POVAR1)="|" PARSE
  1.  .I $E(MSG(ZZ,AAA),OOO)="|" S NNNN=NNNN+1
  1.  .S POVAR1=$E(MSG(ZZ,AAA),OOO)
  1.  .S POLIM=POVAR
  1.  .S POVAR=$S(POVAR="":POVAR1,1:POVAR_POVAR1)
  1.  I $G(POVAR)'="" I NNNN=13!(NNNN=12) S PSOREFIL=POVAR
  1.  K MSG(ZZ,0)
  1.  Q
  1. PARSE ;
  1.  I NNNN=1 S PSORDITE=$P(POLIM,"^",4) G SET
  1.  I NNNN=10 S PSODDRUG=$P(POLIM,"^",4) I $G(PSODDRUG),('$D(^PSDRUG(PSODDRUG,0))) S PSODDRUG="" G SET
  1.  I NNNN=10 G SET
  1.  I NNNN=11 S PSOXQTY=POLIM G SET
  1.  I NNNN=13 S PSOREFIL=POLIM G SET
  1.  I NNNN=17 S PSODYSPL=POLIM
  1. SET S (POVAR,POLIM)="" Q
  1.  ;
  1. OBXX ;Parse out OBX segments
  1.  S OCOUNT=OCOUNT+1
  1.  S (POVAR,POVAR)="",(NNCK,NNN,NNNN)=0,PSOIII=1,MSG(ZZ,0)=$E(MSG(ZZ),5,$L(MSG(ZZ)))
  1.  S AAA="" F  S AAA=$O(MSG(ZZ,AAA)) Q:AAA=""  S NNN=0 F OOO=1:1:$L(MSG(ZZ,AAA)) S NNN=NNN+1 D  D:$G(POVAR1)="&"&(NNNN=4) OPARSE D:$G(POVAR1)="|" OPARSE
  1.  .I $E(MSG(ZZ,AAA),OOO)="|" S NNNN=NNNN+1
  1.  .S POVAR1=$E(MSG(ZZ,AAA),OOO)
  1.  .S POLIM=POVAR
  1.  .S POVAR=$S(POVAR="":POVAR1,1:POVAR_POVAR1)
  1.  I $G(POVAR)'="" I NNNN=4!(NNNN=5) S NNCK=NNCK+1 S OBXAR(OCOUNT,NNCK)=POVAR
  1.  K MSG(ZZ,0)
  1.  F OOO=2:1 Q:'$D(OBXAR(OCOUNT,OOO))  S OBXAR(OCOUNT,1)=OBXAR(OCOUNT,1)_"&"_OBXAR(OCOUNT,OOO) K OBXAR(OCOUNT,OOO)
  1.  Q
  1. OPARSE ;
  1.  I NNNN=4,$G(POVAR1)="&" S NNCK=NNCK+1,OBXAR(OCOUNT,NNCK)=$G(POLIM) G OSET
  1.  I NNNN=5 S NNCK=NNCK+1 S OBXAR(OCOUNT,NNCK)=$G(POLIM)
  1. OSET S (POVAR,POLIM)="" Q
  1.  ;
  1. PURGE ;Purge order initiated by CPRS
  1.  N DA,PREER,PRG,PPG,PND,PRGFLAG,PURGCOMM,PEER,PURGPV1,PURGPID,PURGORC,PURGRX,PURGPLC,PRGSTAT,PSCC,PSARC,PSCA,PSACOUNT,PURGEXRX,PLAST,PURGLTH,PURGNODE
  1.  S PSOMSORR=1
  1.  S PRGFLAG=0
  1.  I $G(PSOFILNM),$G(PSOFILNM)'["S" S PURGRX=PSOFILNM G PRX
  1.  S PND=+$G(PSOFILNM) I PND D  G PDNO
  1.  .I '$D(^PS(52.41,PND,0)) Q
  1.  .I $G(PDFN),$G(PDFN)'=$P($G(^PS(52.41,PND,0)),"^",2) S PURGCOMM="Patient does not match" D PDERR Q
  1.  .S PRGSTAT=$P($G(^PS(52.41,PND,0)),"^",3) I PRGSTAT="NW"!(PRGSTAT="RNW")!(PRGSTAT="HD") S PRGFLAG=1 Q
  1.  .K DIK S DA=PND,DIK="^PS(52.41," D ^DIK K DIK Q
  1.  S PURGCOMM="Order was not located by Pharmacy."
  1.  D PDERR G PDNO
  1. PDERR D EN^ORERR(PURGCOMM,.MSG)
  1.  Q
  1. PDNO F PEER=0:0 S PEER=$O(MSG(PEER)) Q:'PEER  S:$P(MSG(PEER),"|")="PV1" PURGPV1=MSG(PEER) S:$P(MSG(PEER),"|")="PID" PURGPID=MSG(PEER) S:$P(MSG(PEER),"|")="ORC"&($G(PURGORC)="") PURGORC=MSG(PEER)
  1.  N MSG,PSOHINST D INIT^PSOHLSN S MSG(2)=$G(PURGPID),MSG(3)=$G(PURGPV1),MSG(4)="ORC|"_$S($G(PRGFLAG):"ZU",1:"ZR")_"|"_$G(OR("PLACE"))_$S($G(PLACERXX):";"_PLACERXX,1:"")_"^OR"_"|"_$S($P($G(PURGORC),"|",4)'="":$P(PURGORC,"|",4),1:"")
  1.  F PREER=11,13 I $P($G(PURGORC),"|",PREER)'="" S $P(MSG(4),"|",PREER)=$P($G(PURGORC),"|",PREER)
  1.  S $P(MSG(4),"|",17)="^^^^"_$S($G(PRGFLAG):"Unable to Purge order.",1:"OK to Purge order.")_"^"
  1.  D SEND^PSOHLSN
  1. PURGEX K PSOMSORR Q
  1. PRX ;Purge from PSRX here
  1.  I '$D(^PSRX(PURGRX,0)) G PDNO
  1.  I $G(PDFN),$G(PDFN)'=$P($G(^PSRX(PURGRX,0)),"^",2) S PURGCOMM="Patient does not match" D PDERR G PDNO
  1.  I '$P($G(^PSRX(PURGRX,"ARC")),"^") S PRGFLAG=1 G PDNO
  1.  ;purge from PSRX
  1.  S PURGEXRX=$P(^PSRX(PURGRX,0),"^")
  1.  S PSOSUSPA=1 K DIK S DA=PURGRX,PSCC=$P($G(^PSRX(PURGRX,0)),"^",2),DIK="^PSRX(" D ^DIK K DIK,PSOSUSPA
  1.  I $D(^PS(55,+$G(PSCC),0)) S DA(1)=PSCC,DIK="^PS(55,"_DA(1)_",""P""," F PSCA=0:0 S PSCA=$O(^PS(55,+$G(PSCC),"P",PSCA)) Q:'PSCA  I ^PS(55,+$G(PSCC),"P",PSCA,0)=PURGRX S DA=PSCA D ^DIK K DA,DIK
  1.  I $D(^PS(52.4,PURGRX,0)) S DA=PURGRX,DIK="^PS(52.4," D ^DIK K DA,DIK
  1.  S DA=$O(^PS(52.5,"B",PURGRX,"")) I DA S DIK="^PS(52.5," D ^DIK K DIK,DA
  1.  I '$G(DT) S DT=$$DT^XLFDT
  1.  I '$G(PSCC) G PUQUIT
  1.  I '$D(^PS(55,PSCC,"ARC",DT)) S DA=PSCC,DIE=55,DR="101///"_DT,DR(2,55.13)="1///"_$G(PURGEXRX) D ^DIE K DIE G PUQUIT
  1.  S PLAST=0 F PSARC=0:0 S PSARC=$O(^PS(55,PSCC,"ARC",DT,1,PSARC)) Q:'PSARC  S PLAST=PSARC
  1.  I $G(PLAST),$D(^PS(55,PSCC,"ARC",DT,1,PLAST,0)) S PURGNODE=^PS(55,PSCC,"ARC",DT,1,PLAST,0) S PURGLTH=$L(PURGNODE) I $G(PURGLTH),PURGLTH<220 S ^PS(55,PSCC,"ARC",DT,1,PLAST,0)=PURGNODE_$S($E(PURGNODE,PURGLTH)'="*":"*",1:"")_PURGEXRX G PUQUIT
  1.  S DA=PSCC,DIE=55,DR="101///"_DT,DR(2,55.13)="1///"_$G(PURGEXRX) D ^DIE K DIE
  1. PUQUIT G PDNO
  1.  ;
  1. REF ;  Refill request from CPRS
  1.  N PSORXFL,PSORFX,REFXXX,REFCOM,REFCOMXX,REFEER,REFPV1,REFPID,REFORC,RREER,RFLOOP,REFSEG,RFTYPE,REFILLER,REFVR,PSOERR,PSODUZ,PSOAUTOF
  1.  I $G(PSOFILNM),$G(PSOFILNM)'["S" S PSORXFL=PSOFILNM G REFRX
  1.  I $G(PSOFILNM) S PSORFX=+$G(PSOFILNM) D  S REFXXX=1 G REFSND
  1.  .I '$D(^PS(52.41,PSORFX,0)) S (REFCOMXX,REFCOM)="Order was not located by Pharmacy." D REFERR Q
  1.  .I $G(PDFN),$G(PDFN)'=$P($G(^PS(52.41,PSORFX,0)),"^",2) S (REFCOMXX,REFCOM)="Patient does not match." D REFERR Q
  1.  .I $P($G(^PS(52.41,PSORFX,0)),"^",3)="RF" S REFCOM="Refill has already been requested." Q
  1.  .S REFCOM="Refill request not allowed on Pending order."
  1.  S (REFCOMXX,REFCOM)="Order was not located by Pharmacy." D REFERR S REFXXX=1 G REFSND
  1. REFERR D EN^ORERR(REFCOMXX,.MSG)
  1.  Q
  1. REFSND ;  Add code here if response message is ever required
  1.  Q
  1. REFRX ;
  1.  I $O(^PS(52.41,"ARF",PSORXFL,0)) S REFXXX=1,REFCOM="Refill request already exists." G REFSND
  1.  I '$D(^PSRX(PSORXFL,0)) S (REFCOMXX,REFCOM)="Order was not located by Pharmacy." D REFERR S REFXXX=1 G REFSND
  1.  I $G(PDFN),$G(PDFN)'=$P($G(^PSRX(PSORXFL,0)),"^",2) S (REFCOMXX,REFCOM)="Patient does not match." D REFERR S REFXXX=1 G REFSND
  1.  F RFLOOP=0:0 S RFLOOP=$O(MSG(RFLOOP)) Q:'RFLOOP  S REFSEG=$G(MSG(RFLOOP)),RFTYPE=$P(REFSEG,"|")_"Z" S REFSEG=$E(REFSEG,5,$L(REFSEG)) I RFTYPE="PIDZ"!(RFTYPE="PV1Z")!(RFTYPE="ORCZ")!(RFTYPE="ZRXZ") D @RFTYPE
  1.  I '$G(PLACER) S REFXXX=1,REFCOM="Unable to process refill request." G REFSND
  1.  I $G(REFILLER),$G(REFILLER)'=$G(PSORXFL) S REFCOMXX="Filler number mismatch" D REFERR S REFXXX=1,REFCOM="Unable to process refill request." G REFSND
  1.  ;
  1.  ;  Auto Refill, file to Prescription file #52, if key exists and at
  1.  ;   least one key holder and if CPRS Automated refill flag is on.
  1.  S PSOAUTOF=0
  1.  I $D(^XUSEC("PSOAUTRF")),$O(^XUSEC("PSOAUTRF",0)),$$GET1^DIQ(59.7,1,40.16,"I") D
  1.  . S PSOERR=""
  1.  . D REF^PSOATRFC(PSOFILNM,.PSOERR)
  1.  . D:$D(PSOERR)>1 MAILMSG^PSOATRFC($G(PDFN),PSOFILNM,.PSOERR)
  1.  . ;  If no error msg array, then refill was filed in the Prescription
  1.  . ;   file #52 so quit, Else file refill to Pending file #52.41
  1.  . S:$D(PSOERR)<2 PSOAUTOF=1
  1.  Q:PSOAUTOF
  1.  ;
  1.  ;  Manual Refill, file to Pending Outpatient Orders file #52.41
  1.  K DD,DO S DIC="^PS(52.41,",DIC(0)="L",X=PLACER,DIC("DR")="1////"_$G(DFN)_";2////"_"RF"_";4////"_$G(ENTERED)_";5////"_$G(PROV) D FILE^DICN K DIC,DR I Y<0 S REFXXX=1,REFCOM="Unable to process refill request." G REFSND
  1.  S PENDING=+Y S $P(^PS(52.41,PENDING,0),"^",13)=$G(LOCATION),$P(^(0),"^",17)=$S($G(ROUTING)'="":$G(ROUTING),1:"W"),$P(^(0),"^",19)=$G(PSORXFL),$P(^(0),"^",20)="F",$P(^(0),"^",14)="R"
  1.  S $P(^PS(52.41,PENDING,0),"^",8)=$P($G(^PSRX(PSORXFL,"OR1")),"^"),$P(^PS(52.41,PENDING,0),"^",9)=$P($G(^PSRX(PSORXFL,0)),"^",6)
  1.  S $P(^PS(52.41,PENDING,"INI"),"^")=$G(PSINPTR) D NOW^%DTC S $P(^PS(52.41,PENDING,0),"^",12)=% K %
  1.  K DIK S DA=PENDING,DIK="^PS(52.41," D IX1^DIK K DIK
  1.  G REFSND
  1. PIDZ ;
  1.  S DFN=+$P(REFSEG,"|",3)
  1.  Q
  1. PV1Z ;
  1.  S LOCATION=+$P(+$P(REFSEG,"|",3),"^")
  1.  S:'$D(^SC(LOCATION,0)) LOCATION=""
  1.  S INPTRX=0 I $G(LOCATION) S PSINPTR=$P($G(^SC(LOCATION,0)),"^",4) I PSINPTR Q
  1.  I $G(LOCATION) S INPTRX=$P($G(^SC(LOCATION,0)),"^",15)
  1.  I '$G(INPTRX) S INPTRX=$O(^DG(40.8,0))
  1.  I '$G(DT) S DT=$$DT^XLFDT
  1.  S PSINPTR=+$$SITE^VASITE(DT,INPTRX)
  1.  Q
  1. ORCZ ;
  1.  S PLACER=+$P(REFSEG,"|",2),REFILLER=+$P(REFSEG,"|",3),ENTERED=+$P(REFSEG,"|",10),PROV=+$P(REFSEG,"|",12)
  1.  Q
  1. ZRXZ ;
  1.  S ROUTING=$P(REFSEG,"|",4)
  1.  Q
  1. STUFF ;
  1.  S PSOVRBD=$P($G(^PS(50.7,+$G(PSORDITE),0)),"^",2)
  1.  I '$G(PSOVRBD) K PSOVRBD Q
  1.  S PSOVRB=$P($G(^PS(50.606,PSOVRBD,"MISC")),"^")
  1.  F EE=0:0 S EE=$O(^PS(52.41,PENDING,1,EE)) Q:'EE  S $P(^PS(52.41,PENDING,1,EE,1),"^",10)=$$UNESC^ORHLESC($G(PSOVRB))
  1.  K PSOVRBD,PSONUNN,PSONUN,PSOVRB
  1.  Q