Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: PSON52

PSON52.m

Go to the documentation of this file. 
  1. PSON52 ;BIR/DSD - files new entries in prescription file ;06-Dec-2013 08:18;DU
  1.  ;;7.0;OUTPATIENT PHARMACY;**1,16,23,27,32,46,71,111,124,117,131,139,157,1005,1006,1007,1008,1011,1013,1014,143,219,148,239,201,268,260,225,303,1015,1016,1017**;DEC 1997;Build 40
  1.  ;External reference ^PS(55 supported by DBIA 2228
  1.  ;External reference to PSOUL^PSSLOCK supported by DBIA 2789
  1.  ;External reference to ^XUSEC supported by DBIA 10076
  1.  ;External reference SWSTAT^IBBAPI supported by DBIA 4663
  1.  ;External reference SAVNDC^PSSNDCUT supported by DBIA 4707
  1.  ; Modified - IHS/CIA/PLS - 12/30/03 - Starting at line DD+37
  1.  ;            IHS/MSC/PLS - 09/17/07 - Added CLININD and CLININD2 to $T region
  1.  ;            IHS/MSC/PLS - 12/08/08 - Added CASH DUE set
  1.  ;                          07/30/10 - Line IBQ+1
  1.  ;                          04/15/11 - Added PRV* and DEA* fields
  1.  ;                          09/27/11 - Added APSPPRIO references
  1.  ;                          10/13/11 - Line INIT+5,INIT+9
  1.  ;                          05/22/12 - Line DT+2
  1.  ;                          11/20/12 - Line DT+15
  1.  ;                          03/06/13 - Line DD-2
  1.  ;                          06/04/13 - Added DSCMED reference
  1.  ;            IHS/MSC/MGH   08/05/13 - Line DT+16
  1. EN(PSOX) ;Entry Point
  1. START ;
  1.  D:$D(XRTL) T0^%ZOSV ; Start RT Monitor
  1.  D INIT G:PSON52("QFLG") END D NFILE Q:$G(PSONEW("DFLG"))  D PS55,DIK
  1.  S:$D(XRT0) XRTN=$T(+0) D:$D(XRT0) T1^%ZOSV ; Stop RT Monitor
  1.  D FINISH
  1.  I $P(^PSRX(PSOX("IRXN"),0),"^",11)="W",$G(^("IB")) S ^PSRX("ACP",$P(^PSRX(PSOX("IRXN"),0),"^",2),$P(^(2),"^",2),0,PSOX("IRXN"))=""
  1. END D EOJ
  1.  Q
  1. INIT ;
  1.  K X,%DT S:$G(PSOID) PSOX("ISSUE DATE")=PSOID
  1.  S PSOX("CS")=0
  1.  F DEA=1:1 Q:$E(PSODRUG("DEA"),DEA)=""  I $E(+PSODRUG("DEA"),DEA)>1,$E(+PSODRUG("DEA"),DEA)<6 S $P(PSOX("CS"),"^")=1 S:$E(+PSODRUG("DEA"),DEA)=2 $P(PSOX("CS"),"^",2)=1
  1.  S PSON52("QFLG")=0,X1=PSOX("ISSUE DATE"),X2=PSOX("DAYS SUPPLY")*(PSOX("# OF REFILLS")+1)\1
  1.  ;IHS/MSC/PLS - 10/13/2011
  1.  ;I $D(CLOZPAT) S X2=$S(X2=14:14,X2=7:7,1:X2) G DT
  1.  I $D(CLOZPAT) S X2=$S(X2=28:28,X2=21:21,X2=14:14,X2=7:7,1:X2) G DT
  1.  ;S X2=$S(PSOX("DAYS SUPPLY")=X2:X2,+$G(PSOX("CS")):184,+$G(DEA("CS")):184,1:366)
  1.  S X2=$S(PSOX("DAYS SUPPLY")=X2:X2,+$P($G(PSOX("CS")),U,2):184,+$G(PSOX("CS")):184,+$G(DEA("CS")):184,1:366)
  1.  ;
  1.  ;IHS/MSC/PLS - 10/13/2011 - Next three lines commented out
  1.  ;I X2<30 D
  1.  ;. N % S %=$P($G(PSORX("PATIENT STATUS")),"^"),X2=30
  1.  ;. S:%?.N %=$P($G(^PS(53,+%,0)),"^") I %["AUTH ABS" S X2=5
  1. DT ;IHS/MSC/PLS - 02/13/2012
  1.  ;S X2=$S(+$G(PSODIR("CS")):184,1:366)
  1.  ;IHS/MSC/PLS - 05/22/2012
  1.  S X2=$S(+PSOX("CS"):184,1:366)
  1.  ;IHS/MSC/PLS - 04/21/2011 - Added next three lines
  1.  N EXTEXP
  1.  S EXTEXP=$$GET1^DIQ(50,PSODRUG("IEN"),9999999.08)
  1.  S X2=$S(EXTEXP:EXTEXP,1:X2)
  1.  D C^%DTC S PSOX("STOP DATE")=$P(X,".") K X
  1.  I PSOX("# OF REFILLS")>0 S X1=PSOX("FILL DATE"),X2=$S((PSOX("DAYS SUPPLY")-10\1)<1:1,1:PSOX("DAYS SUPPLY")-10\1) D C^%DTC S PSOX("NEXT POSSIBLE REFILL")=$P(X,".") K X
  1.  S PSOX("TYPE OF RX")=0,PSOX("DISPENSED DATE")=PSOX("FILL DATE") D NOW^%DTC S PSOX("LOGIN DATE")=$S($P($G(OR0),"^",12):$P($G(OR0),"^",12),1:%) K %,X
  1.  S PSOX("STATUS")=$S($G(PSOX("STATUS"))]"":PSOX("STATUS"),$D(PSORX("VERIFY")):1,1:0)
  1.  S PSOX("COPIES")=$S($G(PSOX("COPIES"))]"":PSOX("COPIES"),1:1)
  1.  I $G(PSORX("PHARM"))]"" S PSOX("PHARMACIST")=PSORX("PHARM") K PSORX("PHARM")
  1.  S:$L($G(APSPPRIO)) PSOX("APSPPRIO")=APSPPRIO  ;IHS/MSC/PLS - 09/27/11
  1.  ;S PSOX("RXNORM")=$$RXNORM^APSPFNC1($G(PSOX("NDC")))  ;IHS/MSC/PLS - 11/20/2012
  1.  ;IHS/MSC/MGH Patch 1017 changed depending on pickup location
  1.  I $G(PSOX("PICKUP"))'="" S PSOX("NDC")=$$GETNDC^APSPFNC1($G(PSODRUG("IEN")),$G(PSOX("PICKUP")))
  1.  S PSOX("RXNORM")=$$RXNORM^APSPFNC1($G(PSOX("NDC")))  ;IHS/MSC/MGH - 10/25/2013
  1.  D INITPRV
  1. INITX Q
  1.  ;
  1. INITPRV ;EP -
  1.  N PRV
  1.  S PRV=PSOX("PROVIDER")
  1.  S PSOX("PRV STR ADD1")=$$GET1^DIQ(200,PRV,.111)
  1.  S PSOX("PRV STR ADD2")=$$GET1^DIQ(200,PRV,.112)
  1.  S PSOX("PRV STR ADD3")=$$GET1^DIQ(200,PRV,.113)
  1.  S PSOX("PRV CITY")=$$GET1^DIQ(200,PRV,.114)
  1.  S PSOX("PRV STATE")=$$GET1^DIQ(200,PRV,.115)
  1.  S PSOX("PRV ZIP")=$$GET1^DIQ(200,PRV,.116)
  1.  S PSOX("DEA_VA_USPHS")=$S($$ISSCH^APSPFNC2(PSODRUG("IEN"),"2345"):$$DEAVAUS^APSPFUNC(PRV),1:"")
  1.  Q
  1.  ;
  1. NFILE I $G(OR0) D  Q:$G(PSONEW("DFLG"))
  1.  .D NOOR^PSONEW Q:$G(PSONEW("DFLG"))
  1.  .I $G(PSOSIGFL)!($G(PSODRUG("OI"))'=$P(OR0,"^",8)) S PSONEW("CLERK CODE")=DUZ,PSONEW("REMARKS")=$G(PSONEW("REMARKS"))_" CPRS Order #"_$P(OR0,"^")_" Edited."
  1.  S DIC="^PSRX(",DLAYGO=52,DIC(0)="L",X=PSOX("RX #") K DD,DO D FILE^DICN S PSOX("IRXN")=+Y K DLAYGO,X,Y,DIC,DD,DO D:+$G(DGI) TECH^PSODGDGI
  1.  F PSOX1=0:1 S PSON52=$P($T(DD+PSOX1),";;",2,4) Q:PSON52=""  K PSOY S PSOY=$P(PSON52,";;") I $G(@PSOY)]"" S $P(PSON52(PSOX("IRXN"),$P(PSON52,";;",2)),"^",$P(PSON52,";;",3))=@PSOY
  1.  F I=1:1:PSOX("ENT") S ^PSRX(PSOX("IRXN"),6,I,0)=PSOX("DOSE",I)_"^"_$G(PSOX("DOSE ORDERED",I))_"^"_$G(PSOX("UNITS",I))_"^"_$G(PSOX("NOUN",I))_"^" D
  1.  .S ^PSRX(PSOX("IRXN"),6,I,0)=^PSRX(PSOX("IRXN"),6,I,0)_$G(PSOX("DURATION",I))_"^"_$G(PSOX("CONJUNCTION",I))_"^"_$G(PSOX("ROUTE",I))_"^"_$G(PSOX("SCHEDULE",I))_"^"_$G(PSOX("VERB",I))
  1.  .I $G(PSOX("ODOSE",I))]"" S ^PSRX(PSOX("IRXN"),6,I,1)=PSOX("ODOSE",I)
  1.  S ^PSRX(PSOX("IRXN"),6,0)="^52.0113^"_PSOX("ENT")_"^"_PSOX("ENT")
  1.  K PSOX1,PSOY
  1.  S PSOX1="" F  S PSOX1=$O(PSON52(PSOX("IRXN"),PSOX1)) Q:PSOX1=""  S ^PSRX(PSOX("IRXN"),PSOX1)=$G(PSON52(PSOX("IRXN"),PSOX1))
  1.  I $O(PSOX("SIG",0)) D
  1.  .S D=0 F  S D=$O(PSOX("SIG",D)) Q:'D  S ^PSRX(PSOX("IRXN"),"INS1",D,0)=PSOX("SIG",D),TP=$G(TP)+1
  1.  .S ^PSRX(PSOX("IRXN"),"INS1",0)="^52.0115^"_TP_"^"_TP_"^"_DT_"^^" K TP,D
  1.  I $G(PSOX("SINS"))]"" S ^PSRX(PSOX("IRXN"),"INSS")=PSOX("SINS")
  1.  I $G(SIGOK) D
  1.  .S $P(^PSRX(PSOX("IRXN"),"SIG"),"^",2)=1,^PSRX(PSOX("IRXN"),"SIG1",0)="^52.04A^^"
  1.  .S D=0 F  S D=$O(SIG(D)) Q:'D  S ^PSRX(PSOX("IRXN"),"SIG1",D,0)=SIG(D),$P(^PSRX(PSOX("IRXN"),"SIG1",0),"^",3)=+$P(^PSRX(PSOX("IRXN"),"SIG1",0),"^",3)+1,$P(^(0),"^",4)=+$P(^(0),"^",4)+1 Q:'$O(SIG(D))
  1.  .K SIG
  1.  I $D(PSOINSFL) S ^PSRX(PSOX("IRXN"),"A",0)="^52.3DA^1^1",^PSRX(PSOX("IRXN"),"A",1,0)=DT_"^G^^0^Patient Instructions "_$S(PSOINSFL=1:"",1:"Not ")_"Sent By Provider."
  1.  I $G(OR0) S:$P(OR0,"^",24) ^PSRX(PSOX("IRXN"),"PKI")=1
  1.  K PSOX1,PSOFINFL,HLDSIG,D,PSOINSFL,D
  1.  D:$G(^TMP("PSODAI",$J,0))
  1.  .S $P(^PSRX(PSOX("IRXN"),3),"^",6)=1
  1.  .I $O(^TMP("PSODAI",$J,0)) S DAI=0 F  S DAI=$O(^TMP("PSODAI",$J,DAI)) Q:'DAI  D
  1.  ..S:'$D(^PSRX(PSOX("IRXN"),"DAI",0)) ^PSRX(PSOX("IRXN"),"DAI",0)="^52.03^^" S ^PSRX(PSOX("IRXN"),"DAI",DAI,0)=^TMP("PSODAI",$J,DAI,0)
  1.  ..S $P(^PSRX(PSOX("IRXN"),"DAI",0),"^",3)=+$P(^PSRX(PSOX("IRXN"),"DAI",0),"^",3)+1,$P(^(0),"^",4)=+$P(^(0),"^",4)+1
  1.  .K ^TMP("PSODAI",$J),DAI
  1.  I $G(PSOX("CHCS NUMBER"))'="" S $P(^PSRX(PSOX("IRXN"),"EXT"),"^")=$G(PSOX("CHCS NUMBER"))
  1.  I $G(PSOX("EXTERNAL SYSTEM"))'="" S $P(^PSRX(PSOX("IRXN"),"EXT"),"^",2)=$G(PSOX("EXTERNAL SYSTEM"))
  1.  I $G(PSOX("NEWCOPAY")) S ^PSRX(PSOX("IRXN"),"IB")=$G(PSOX("NEWCOPAY"))
  1.  ;Next line, set SC question based on Copay status?
  1. IBQ ;I $G(PSOBILL)=2 S ^PSRX(PSOX("IRXN"),"IBQ")=$S($G(PSOX("NEWCOPAY")):0,1:1)
  1.  S PSOSCP=""  ;IHS/MSC/PLS - 07/30/10 - Prevent undefined during autofinish
  1.  N PSOSCFLD S PSOSCFLD=$S(PSOSCP'="":$G(PSOANSQ("SC")),1:"")_"^"_$G(PSOANSQ("MST"))_"^"_$G(PSOANSQ("VEH"))_"^"_$G(PSOANSQ("RAD"))_"^"_$G(PSOANSQ("PGW"))_"^"_$G(PSOANSQ("HNC"))_"^"_$G(PSOANSQ("CV"))_"^"_$G(PSOANSQ("SHAD"))
  1.  I PSOSCP<50&($TR(PSOSCFLD,"^")'="")&($P($G(^PS(53,+$G(PSONEW("PATIENT STATUS")),0)),"^",7)'=1) D
  1.  . S ^PSRX(PSOX("IRXN"),"IBQ")=PSOSCFLD K PSOSCFLD  ;don't set if SC % is null or 0, just set it in ICD node
  1.  D ICD^PSODIAG
  1.  ;D:$$SWSTAT^IBBAPI() GACT^PSOPFSU0(PSOX("IRXN"),0)  ;IHS/MSC/PLS - 03/15/10
  1.  K PSOANSQ,PSOANSQD,PSOX("NEWCOPAY")
  1.  L -^PSRX("B",PSOX("IRXN"))
  1.  Q
  1.  ;
  1. PS55 ;
  1.  L +^PS(55,PSODFN,"P"):$S(+$G(^DD("DILOCKTM"))>0:+^DD("DILOCKTM"),1:3)
  1.  S:'$D(^PS(55,PSODFN,"P",0)) ^(0)="^55.03PA^^"
  1.  F PSOX1=$P(^PS(55,PSODFN,"P",0),"^",3):1 Q:'$D(^PS(55,PSODFN,"P",PSOX1))
  1.  S PSOX("55 IEN")=PSOX1
  1.  S ^PS(55,PSODFN,"P",PSOX1,0)=PSOX("IRXN"),$P(^PS(55,PSODFN,"P",0),"^",3,4)=PSOX1_"^"_($P(^PS(55,PSODFN,"P",0),"^",4)+1)
  1.  S ^PS(55,PSODFN,"P","A",PSONEW("STOP DATE"),PSOX("IRXN"))=""
  1. PS55X L -^PS(55,PSODFN,"P")
  1.  K PSOX1
  1.  Q
  1. DIK ;
  1.  I $D(^XUSEC("PSORPH",DUZ)) S DA=PSOX("IRXN"),DIE=52,DR="41////"_PSOCOU_";S:'X Y=""@1"";42////"_PSOCOUU_";@1" D ^DIE K DIE,DR
  1.  K DIK,DA S DIK="^PSRX(",DA=PSOX("IRXN") D IX1^DIK K DIK
  1.  S DA=PSOX("IRXN") D ORC^PSORN52C
  1.  Q
  1. FINISH ;
  1. ANQ I $G(ANQDATA)]"" D NOW^%DTC G:$D(^PS(52.52,"B",%)) ANQ D
  1.  .K DD,DO S DIC="^PS(52.52,",DIC(0)="L",DLAYGO=52.52,X=% D FILE^DICN K DIC,DLAYGO,DD,DO
  1.  .S ^PS(52.52,+Y,0)=$P(Y,"^",2)_"^"_PSOX("IRXN")_"^"_ANQDATA,^PS(52.52,"A",PSOX("IRXN"),+Y)="" K ANQDATA,X,Y,%,ANQREM
  1.  G:PSOX("STATUS")=4 FINISHP
  1.  I $D(PSORX("VERIFY")) D  G FINISHX
  1.  .K DIC,DLAYGO,DINUM,DIADD,X,DD,DO S DIC="^PS(52.4,",DLAYGO=52.4,DINUM=PSOX("IRXN"),DIC(0)="ML",X=PSOX("IRXN")
  1.  .D FILE^DICN K DD,DO,DIC,DLAYGO,DINUM S ^PS(52.4,PSOX("IRXN"),0)=PSOX("IRXN")_"^"_PSODFN_"^"_DUZ_"^"_"^"_$E(PSOX("LOGIN DATE"),1,7)_"^"_PSOX("IRXN")_"^"_PSOX("STOP DATE")
  1.  .K DIK,DA S DIK="^PS(52.4,",DA=PSOX("IRXN") D IX^DIK K DIK,DA
  1.  ;
  1.  I PSOX("FILL DATE")>DT,$P(PSOPAR,"^",6) S DA=PSOX("IRXN"),RXFL(PSOX("IRXN"))=0 D SUS^PSORXL K DA G FINISHX
  1.  ;
  1.  ; - Calling ECME for claims generation and transmission / REJECT handling
  1.  N ACTION,PSOERX
  1.  S PSOERX=PSOX("IRXN")
  1.  I $$SUBMIT^PSOBPSUT(PSOERX,0) D  I ACTION="Q"!(ACTION="^") Q
  1.  . S ACTION="" D ECMESND^PSOBPSU1(PSOERX,0,PSOX("FILL DATE"),"OF")
  1.  . I $$FIND^PSOREJUT(PSOERX,0) D
  1.  . . S ACTION=$$HDLG^PSOREJU1(PSOERX,0,"79,88","OF","IOQ","Q")
  1.  . I $$STATUS^PSOBPSUT(PSOERX,0)="E PAYABLE" D
  1.  . . D SAVNDC^PSSNDCUT(+$$GET1^DIQ(52,PSOERX,6,"I"),$G(PSOSITE),$$GETNDC^PSONDCUT(PSOERX,0))
  1.  ;
  1. FINISHP ;
  1.  I $G(PSORX("PSOL",1))']"" S PSORX("PSOL",1)=PSOX("IRXN")_",",RXFL(PSOX("IRXN"))=0 G FINISHX
  1.  F PSOX1=0:0 S PSOX1=$O(PSORX("PSOL",PSOX1)) Q:'PSOX1  S PSOX2=PSOX1
  1.  I $L(PSORX("PSOL",PSOX2))+$L(PSOX("IRXN"))<220 S PSORX("PSOL",PSOX2)=PSORX("PSOL",PSOX2)_PSOX("IRXN")_","
  1.  E  S PSORX("PSOL",PSOX2+1)=PSOX("IRXN")_","
  1.  S RXFL(PSOX("IRXN"))=0
  1. FINISHX ;call to build Rx array for bingo board
  1.  I $G(PSORX("MAIL/WINDOW"))["W" S BINGCRT=1,BINGRTE="W",BBFLG=1 D BBRX^PSORN52C
  1.  K PSOX1,PSOX2
  1.  Q
  1. EOJ ;
  1.  ;B xref locked in routine PSONRXN
  1.  L -^PSRX("B",PSOX("IRXN")) K OTHDOS,DA,PSON52,PSOPRC,RTE,SCH,PSOX("INS"),PSONEW("INS"),PSORXED("INS"),PSONEW("ENT"),PSORXED("ENT"),OLENT
  1.  D PSOUL^PSSLOCK(PSOX("IRXN"))
  1.  Q
  1.  ;
  1.  ;;PSODRUG("DAW");;EPH;;1
  1.  ;;PSOX("SIG");;SIG;;1
  1. DD ;;PSOX("RX #");;0;;1
  1.  ;;PSOX("ISSUE DATE");;0;;13
  1.  ;;PSODFN;;0;;2
  1.  ;;PSOX("PATIENT STATUS");;0;;3
  1.  ;;PSOX("PROVIDER");;0;;4
  1.  ;;PSOX("CLINIC");;0;;5
  1.  ;;PSODRUG("IEN");;0;;6
  1.  ;;PSODRUG("TRADE NAME");;TN;;1
  1.  ;;PSOX("QTY");;0;;7
  1.  ;;PSOX("DAYS SUPPLY");;0;;8
  1.  ;;PSOX("# OF REFILLS");;0;;9
  1.  ;;PSOX("COPIES");;0;;18
  1.  ;;PSOX("MAIL/WINDOW");;0;;11
  1.  ;;PSOX("REMARKS");;3;;7
  1.  ;;PSOX("CLERK CODE");;0;;16
  1.  ;;PSODRUG("COST");;0;;17
  1.  ;;PSOSITE;;2;;9
  1.  ;;PSOX("LOGIN DATE");;2;;1
  1.  ;;PSOX("FILL DATE");;2;;2
  1.  ;;PSOX("PHARMACIST");;2;;3
  1.  ;;PSOX("LOT #");;2;;4
  1.  ;;PSOX("DISPENSED DATE");;2;;5
  1.  ;;PSOX("STOP DATE");;2;;6
  1.  ;;PSODRUG("NDC");;2;;7
  1.  ;;PSODRUG("MANUFACTURER");;2;;8
  1.  ;;PSOX("EXPIRATION DATE");;2;;11
  1.  ;;PSOX("GENERIC PROVIDER");;2;;12
  1.  ;;PSOX("RELEASED DATE/TIME");;2;;13
  1.  ;;PSOX("METHOD OF PICK-UP");;MP;;1
  1.  ;;PSOX("STATUS");;STA;;1
  1.  ;;PSOX("LAST DISPENSED DATE");;3;;1
  1.  ;;PSOX("NEXT POSSIBLE REFILL");;3;;2
  1.  ;;PSOX("COSIGNING PROVIDER");;3;;3
  1.  ;;PSOX("TYPE OF RX");;TYPE;;1
  1.  ;;PSOX("SAND");;SAND;;1
  1.  ;;PSOX("POE");;POE;;1
  1.  ;;PSOX("INS");;INS;;1
  1.  ;;PSOX("CM");;9999999;;2
  1.  ;;PSOX("CLININD");;999999921;;1
  1.  ;;PSOX("CLININD2");;999999921;;2
  1.  ;;PSOX("AUTOFIN");;999999921;;3
  1.  ;;PSOX("ELECTRONIC PHARMACY");;999999921;;4
  1.  ;;PSOX("CASH DUE");;999999921;;6
  1.  ;;PSOX("RXNORM");;999999921;;7
  1.  ;;PSOX("DAW");;999999921;;5
  1.  ;;PSOX("COST");;0;;17
  1.  ;;PSOX("NDC");;2;;7
  1.  ;;PSODRUG("AWP");;9999999;;6
  1.  ;;PSOX("AWP");;9999999;;6
  1.  ;;PSOX("BST");;9999999;;7
  1.  ;;PSOX("INSURER");;9999999;;12
  1.  ;;PSOX("DUR");;9999999;;13
  1.  ;;PSOX("TRIP");;9999999;;14
  1.  ;;PSOX("MANUFACTURER");;2;;8
  1.  ;;PSOX("PRV STR ADD1");;999999931;;1
  1.  ;;PSOX("PRV STR ADD2");;999999931;;2
  1.  ;;PSOX("PRV STR ADD3");;999999931;;3
  1.  ;;PSOX("PRV CITY");;999999931;;4
  1.  ;;PSOX("PRV STATE");;999999931;;5
  1.  ;;PSOX("PRV ZIP");;999999931;;6
  1.  ;;PSOX("DEA_VA_USPHS");;999999931;;7
  1.  ;;PSOX("APSPPRIO");;999999931;;8
  1.  ;;PSOX("DSCMED");;999999921;;8