Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: PXRHS06

PXRHS06.m

Go to the documentation of this file. 
  1. PXRHS06 ;ISL/SBW - PCE Visit Treatment data extract ;12/10/96
  1.  ;;1.0;PCE PATIENT CARE ENCOUNTER;**13**;Aug 12, 1996
  1. TREAT(DFN,ENDDT,BEGDT,OCCLIM,CATCODE) ; Control branching
  1.  ;INPUT  : DFN      - Pointer to PATIENT file (#2)
  1.  ;         ENDDT    - Ending date/time in internal FileMan format
  1.  ;                  - Defaults to today's date at 11:59 pm
  1.  ;         BEGDT    - Beginning date/time in internal FileMan format
  1.  ;                  - Defaults to one year prior to today's date
  1.  ;         OCCLIM   - Maximum number of days for which data is returned
  1.  ;                    (If multiple visits on a given day, all data for
  1.  ;                    these visit will be returned) or an "R" for
  1.  ;                    only the most recent occurrence of each topic
  1.  ;                    Note: If event date is used, it may appear that too
  1.  ;                          many occurrences are retrieved but it is
  1.  ;                          it is based on visit date not event date.
  1.  ;                    returned (Can include multiple codes)
  1.  ;         CATCODE  - Pattern Match which controls visit data that is
  1.  ;               A = AMBULATORY
  1.  ;               H = HOSPITALIZATION
  1.  ;               I = IN HOSPITAL
  1.  ;               C = CHART REVIEW
  1.  ;               T = TELECOMMUNICATIONS
  1.  ;               N = NOT FOUND
  1.  ;               S = DAY SURGERY
  1.  ;               O = OBSERVATION
  1.  ;               E = EVENT (HISTORICAL)
  1.  ;               R = NURSING HOME
  1.  ;               D = DAILY HOSPITALIZATION DATA
  1.  ;               X = ANCILLARY PACKAGE DAILY DATA
  1.  ;
  1.  ;OUTPUT : 
  1.  ;  Data from V TREATMENT (9000010.15) file
  1.  ;  ^TMP("PXT,$J,InvDt,TREAT,IFN,0) = TREATMENT [E;.01]
  1.  ;     ^ EVENT DATE/TIME or VISIT/ADMIT DATE&TIME [I;1201 or .03] 
  1.  ;     ^ HOW MANY [I;.04] ^ ORDERING PROVIDER [E;1202] 
  1.  ;     ^ ENCOUNTER PROVIDER [E;1204]
  1.  ;  ^TMP("PXT",$J,InvDt,TREAT,IFN,1) = HOSPITAL LOCATION [E;9000010;.22] 
  1.  ;     ^ HOSP. LOC. ABBREVIATION [E;44;1]
  1.  ;     ^ LOC OF ENCOUNTER [E;9000010;.06] ^ OUTSIDE LOC [E;9000010;2101]
  1.  ;  ^TMP("PXT",$J,InvDt,TREAT,IFN,"S") = DATA SOURCE [E;80102]
  1.  ;  ^TMP("PXT",$J,InvDt,TREAT,IFN,"P") = PROVIDER NARRATIVE [E;.06]
  1.  ;  ^TMP("PXT",$J,InvDt,TREAT,IFN,"PNC") = PROVIDER NARR. CATEGORY [E;80201]
  1.  ;
  1.  ;   [] = [I(nternal)/E(xternal); Optional file #; Record #]
  1.  ;   Subscripts:
  1.  ;     InvDt - Inverse FileMan date of DATE OF event or visit minus time
  1.  ;     TREAT - TREATMENT PROVIDED
  1.  ;     IFN   - Internal Record #
  1.  ;
  1.  Q:$G(DFN)']""!'$D(^AUPNVTRT("AA",DFN))
  1.  N PXIVD,PXIFN,CNT,PDT,IBEGDT,IENDDT
  1.  S:+$G(OCCLIM)'>0 OCCLIM=999
  1.  S:+$G(BEGDT)'>0 BEGDT=DT-10000
  1.  S:+$G(ENDDT)'>0 ENDDT=DT_".235959"
  1.  ; Chg regular dt/time to inverted dt/time
  1.  S IBEGDT=9999999-ENDDT,IENDDT=9999999-BEGDT
  1.  K ^TMP("PXT",$J)
  1.  S PXIVD=IBEGDT,CNT=0
  1.  F  S PXIVD=$O(^AUPNVTRT("AA",DFN,PXIVD)) Q:PXIVD'>0!(PXIVD>IENDDT)  D  Q:CNT'<OCCLIM
  1.  . S PXIFN=0
  1.  . F  S PXIFN=$O(^AUPNVTRT("AA",DFN,PXIVD,PXIFN)) Q:PXIFN'>0  D
  1.  . . N DIC,DIQ,DR,DA,REC,VDATA,TREAT,TRDT,NUM,PNARR,PNARRC,COMMENT
  1.  . . N OPROV,EPROV,HLOC,HLOCABB,SOURCE,IDT
  1.  . . S DIC=9000010.15,DA=PXIFN,DIQ="REC(",DIQ(0)="IE"
  1.  . . S DR=".01;.03;.04;.06;1201;1202;1204;80102;80201;81101"
  1.  . . D EN^DIQ1
  1.  . . Q:'$D(REC)
  1.  . . S VDATA=$$GETVDATA^PXRHS03(+REC(9000010.15,DA,.03,"I"))
  1.  . . Q:$G(CATCODE)'[$P(VDATA,U,3)  ;Only get data with passed serv. cat.
  1.  . . S TREAT=REC(9000010.15,DA,.01,"E")
  1.  . . S TRDT=REC(9000010.15,DA,1201,"I")
  1.  . . S:TRDT']"" TRDT=$P(VDATA,U)
  1.  . . S IDT=9999999-TRDT
  1.  . . I IDT<IBEGDT!(IDT>IENDDT) Q  ;Only get data within date range
  1.  . . S NUM=REC(9000010.15,DA,.04,"I")
  1.  . . S OPROV=REC(9000010.15,DA,1202,"E")
  1.  . . S EPROV=REC(9000010.15,DA,1204,"E")
  1.  . . S HLOC=$P(VDATA,U,5)
  1.  . . S HLOCABB=$P(VDATA,U,6)
  1.  . . S SOURCE=REC(9000010.15,DA,80102,"E")
  1.  . . S COMMENT=REC(9000010.15,DA,81101,"E")
  1.  . . S PNARR=REC(9000010.15,DA,.06,"E")
  1.  . . S PNARRC=REC(9000010.15,DA,80201,"E")
  1.  . . S IDT=$P(IDT,".") ;Index with only date and no time
  1.  . . S ^TMP("PXT",$J,IDT,TREAT,DA,0)=TREAT_U_TRDT_U_NUM_U_OPROV_U_EPROV
  1.  . . S ^TMP("PXT",$J,IDT,TREAT,DA,1)=HLOC_U_HLOCABB_U_$P(VDATA,U,2)_U_$P(VDATA,U,4)
  1.  . . S ^TMP("PXT",$J,IDT,TREAT,DA,"S")=SOURCE
  1.  . . S ^TMP("PXT",$J,IDT,TREAT,DA,"P")=PNARR
  1.  . . S ^TMP("PXT",$J,IDT,TREAT,DA,"PNC")=PNARRC
  1.  . . S ^TMP("PXT",$J,IDT,TREAT,DA,"COM")=COMMENT
  1.  . . ; Counter by date not by visit. There may be multiple visits with
  1.  . . ; multiple treatments for any given day
  1.  . . I PXIVD'=$G(PDT) S CNT=CNT+1,PDT=PXIVD
  1.  Q