Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: PXRMIMM

PXRMIMM.m

Go to the documentation of this file.
  1. PXRMIMM ; SLC/PKR - Handle immunization findings. ;29-Feb-2012 09:25;DU
  1. ;;2.0;CLINICAL REMINDERS;**1001**;Feb 04, 2005;Build 21
  1. ;IHS/MSC/MGH Patch 1001 wrap lookup with $G
  1. ;
  1. ;=======================================================
  1. EVALFI(DFN,DEFARR,ENODE,FIEVAL) ;Evaluate immunization findings.
  1. D EVALFI^PXRMINDX(DFN,.DEFARR,ENODE,.FIEVAL)
  1. Q
  1. ;
  1. ;=======================================================
  1. EVALPL(FINDPA,ENODE,TERMARR,PLIST) ;Evaluate immunization term findings
  1. ;for patient lists.
  1. D EVALPL^PXRMINDL(.FINDPA,ENODE,.TERMARR,PLIST)
  1. Q
  1. ;
  1. ;=======================================================
  1. EVALTERM(DFN,FINDPA,ENODE,TERMARR,TFIEVAL) ;Evaluate immunization terms.
  1. D EVALTERM^PXRMINDX(DFN,.FINDPA,ENODE,.TERMARR,.TFIEVAL)
  1. Q
  1. ;
  1. ;=======================================================
  1. GETDATA(DAS,FIEVT) ;Return data, for a specified V Immunization entry.
  1. ;DBIA #4250
  1. D VIMM^PXPXRM(DAS,.FIEVT)
  1. Q
  1. ;
  1. ;=======================================================
  1. MHVOUT(INDENT,IFIEVAL,NLINES,TEXT) ;Produce the clinical
  1. ;maintenance output.
  1. N EM,FIEN,IND,JND,NAME,NOUT,PNAME,REACTION,SERIES,TEMP,TEXTOUT,VDATE
  1. S FIEN=$P(IFIEVAL("FINDING"),";",1)
  1. ;IHS/MSC/MGH Patch 1001 wrap with $G
  1. S PNAME=$P($G(^AUTTIMM(FIEN,0)),U,1)
  1. S NAME="Immunization: "_PNAME_" = "
  1. S IND=0
  1. F S IND=+$O(IFIEVAL(IND)) Q:IND=0 D
  1. . S SERIES=$G(IFIEVAL(IND,"SERIES"))
  1. . I SERIES'="" S SERIES=$$EXTERNAL^DILFD(9000010.11,.04,"",SERIES,.EM)
  1. . I $G(IFIEVAL(IND,"CONTRAINDICATED")) S SERIES=SERIES_"; - CONTRAINDICATED"
  1. . S VDATE=IFIEVAL(IND,"DATE")
  1. . S TEMP=NAME_SERIES_" ("_$$EDATE^PXRMDATE(VDATE)_")"
  1. . D FORMATS^PXRMTEXT(INDENT+2,PXRMRM,TEMP,.NOUT,.TEXTOUT)
  1. . F JND=1:1:NOUT S NLINES=NLINES+1,TEXT(NLINES)=TEXTOUT(JND)
  1. S NLINES=NLINES+1,TEXT(NLINES)=""
  1. Q
  1. ;
  1. ;=======================================================
  1. OUTPUT(INDENT,IFIEVAL,NLINES,TEXT) ;Produce the clinical
  1. ;maintenance output.
  1. N EM,FIEN,IND,JND,NOUT,PNAME,REACTION,SERIES,TEMP,TEXTOUT,VDATE
  1. S FIEN=$P(IFIEVAL("FINDING"),";",1)
  1. ;IHS/MSC/MGH Patch 1001 Wrap with $G
  1. S PNAME=$P($G(^AUTTIMM(FIEN,0)),U,1)
  1. S NLINES=NLINES+1
  1. S TEXT(NLINES)=$$INSCHR^PXRMEXLC(INDENT," ")_"Immunization: "_PNAME
  1. S IND=0
  1. F S IND=+$O(IFIEVAL(IND)) Q:IND=0 D
  1. . S VDATE=IFIEVAL(IND,"DATE")
  1. . S TEMP=$$EDATE^PXRMDATE(VDATE)
  1. . S REACTION=$G(IFIEVAL(IND,"REACTION"))
  1. . S SERIES=$G(IFIEVAL(IND,"SERIES"))
  1. . I SERIES'="" D
  1. .. S TEMP=TEMP_" series - "
  1. .. S TEMP=TEMP_$$EXTERNAL^DILFD(9000010.11,.04,"",SERIES,.EM)
  1. . I REACTION'="" D
  1. .. S TEMP=TEMP_" reaction - "
  1. .. S TEMP=TEMP_$$EXTERNAL^DILFD(9000010.11,.06,"",REACTION,.EM)
  1. . I $G(IFIEVAL(IND,"CONTRAINDICATED")) S TEMP=TEMP_"; - CONTRAINDICATED"
  1. . D FORMATS^PXRMTEXT(INDENT+2,PXRMRM,TEMP,.NOUT,.TEXTOUT)
  1. . F JND=1:1:NOUT S NLINES=NLINES+1,TEXT(NLINES)=TEXTOUT(JND)
  1. . I IFIEVAL(IND,"COMMENTS")'="" D
  1. .. S TEMP="Comments: "_IFIEVAL(IND,"COMMENTS")
  1. .. D FORMATS^PXRMTEXT(INDENT+3,PXRMRM,TEMP,.NOUT,.TEXTOUT)
  1. .. F JND=1:1:NOUT S NLINES=NLINES+1,TEXT(NLINES)=TEXTOUT(JND)
  1. S NLINES=NLINES+1,TEXT(NLINES)=""
  1. Q
  1. ;