Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: PXRMLDR

PXRMLDR.m

Go to the documentation of this file. 
  1. PXRMLDR ;SLC/PKR - Load Definitions and terms for evaluation. ;09/04/2012
  1.  ;;2.0;CLINICAL REMINDERS;**18,26**;Feb 04, 2005;Build 404
  1.  ;
  1.  ;===================================
  1. DEF(DEFIEN,DEFARR) ;Load those portions of the definition needed for
  1.  ;evaluation.
  1.  K DEFARR
  1.  S DEFARR("IEN")=DEFIEN
  1.  I '$D(^PXD(811.9,DEFIEN)) S DEFARR("DNE")="" Q
  1.  N FTYPE,IND,JND,STL
  1.  S STL=0
  1.  S DEFARR(0)=^PXD(811.9,DEFIEN,0)
  1.  ;Baseline
  1.  S IND=0
  1.  F  S IND=+$O(^PXD(811.9,DEFIEN,7,IND)) Q:IND=0  D
  1.  . S DEFARR(7,IND,0)=^PXD(811.9,DEFIEN,7,IND,0)
  1.  . S DEFARR(7,IND,3)=^PXD(811.9,DEFIEN,7,IND,3)
  1.  ;Load the findings multiple.
  1.  S IND=0
  1.  F  S IND=+$O(^PXD(811.9,DEFIEN,20,IND)) Q:IND=0  D
  1.  . S DEFARR(20,IND,0)=^PXD(811.9,DEFIEN,20,IND,0)
  1.  . S DEFARR(20,IND,3)=$G(^PXD(811.9,DEFIEN,20,IND,3))
  1.  . S DEFARR(20,IND,6)=$G(^PXD(811.9,DEFIEN,20,IND,6))
  1.  . S DEFARR(20,IND,10)=$G(^PXD(811.9,DEFIEN,20,IND,10))
  1.  . S DEFARR(20,IND,11)=$G(^PXD(811.9,DEFIEN,20,IND,11))
  1.  . S DEFARR(20,IND,15)=$G(^PXD(811.9,DEFIEN,20,IND,15))
  1.  . S JND=0
  1.  . F  S JND=+$O(^PXD(811.9,DEFIEN,20,IND,5,JND)) Q:JND=0  D
  1.  .. S DEFARR(20,IND,5,JND)=^PXD(811.9,DEFIEN,20,IND,5,JND,0)
  1.  M DEFARR("E")=^PXD(811.9,DEFIEN,20,"E")
  1.  M DEFARR("EDEP")=^PXD(811.9,DEFIEN,20,"EDEP")
  1.  ;Load the function findings.
  1.  S IND=0
  1.  F  S IND=+$O(^PXD(811.9,DEFIEN,25,IND)) Q:IND=0  D
  1.  . M DEFARR(25,"FF"_IND)=^PXD(811.9,DEFIEN,25,IND)
  1.  ;Load the logic fields.
  1.  S DEFARR(31)=$G(^PXD(811.9,DEFIEN,31))
  1.  S DEFARR(32)=$G(^PXD(811.9,DEFIEN,32))
  1.  S DEFARR(35)=$G(^PXD(811.9,DEFIEN,35))
  1.  S DEFARR(36)=$G(^PXD(811.9,DEFIEN,36))
  1.  S DEFARR(40)=$G(^PXD(811.9,DEFIEN,40))
  1.  S DEFARR(42)=$G(^PXD(811.9,DEFIEN,42))
  1.  ;Load the custom date due fields.
  1.  S DEFARR(45)=$G(^PXD(811.9,DEFIEN,45))
  1.  I $L(DEFARR(45))>0 D
  1.  . M DEFARR(46)=^PXD(811.9,DEFIEN,46)
  1.  . M DEFARR(47)=^PXD(811.9,DEFIEN,47)
  1.  . K DEFARR(47,0),DEFARR(47,"B")
  1.  ;Load the logic found/not found text fields.
  1.  S DEFARR(62)=$G(^PXD(811.9,DEFIEN,62))
  1.  S DEFARR(67)=$G(^PXD(811.9,DEFIEN,67))
  1.  S DEFARR(72)=$G(^PXD(811.9,DEFIEN,72))
  1.  S DEFARR(77)=$G(^PXD(811.9,DEFIEN,77))
  1.  ;Check for finding list strings too long.
  1.  I DEFARR(32)=-1 S STL=1,FTYPE="cohort"
  1.  I DEFARR(36)=-1 S STL=1,FTYPE="resolution"
  1.  I DEFARR(40)=-1 S STL=1,FTYPE="age"
  1.  I DEFARR(42)=-1 S STL=1,FTYPE="information"
  1.  I STL S $P(DEFARR(0),U,6,7)=1_U_$$NOW^XLFDT D ERRMSG^PXRMLOGX(FTYPE)
  1.  Q
  1.  ;
  1.  ;===================================
  1. EDITFM0(FINDING,FIELD,VALUE,FARR) ;For finding number FINDING set the
  1.  ;field named field to the value VALUE in FARR.
  1.  N NTP,PIECE
  1.  S NTP("MINIMUM AGE")=2,NTP("MAXIMUM AGE")=3,NTP("REMINDER FREQUENCY")=4
  1.  S NTP("RANK FREQUENCY")=5,NTP("USE IN RESOLUTION LOGIC")=6
  1.  S NTP("USE IN PATIENT COHORT LOGIC")=7,NTP("BEGINNING DATE/TIME")=8
  1.  S NTP("USE INACTIVE PROBLEMS")=9,NTP("WITHIN CATEGORY RANK")=10
  1.  S NTP("ENDING DATE/TIME")=11,NTP("MH SCALE")=12
  1.  S NTP("RX TYPE")=13,NTP("OCCURRENCE COUNT")=14
  1.  S PIECE=NTP(FIELD)
  1.  S $P(FARR(20,FINDING,0),U,PIECE)=VALUE
  1.  Q
  1.  ;
  1.  ;===================================
  1. TAX(TAXIEN,TAXARR) ;Load a taxonomy into TAXARR for evaluation.
  1.  S TAXARR("IEN")=TAXIEN
  1.  M TAXARR("AE")=^PXD(811.2,TAXIEN,20,"AE")
  1.  M TAXARR("APDS")=^PXD(811.2,TAXIEN,"APDS")
  1.  S TAXARR(0)=^PXD(811.2,TAXIEN,0)
  1.  S TAXARR(15)=$G(^PXD(811.2,TAXIEN,15))
  1.  Q
  1.  ;
  1.  ;===================================
  1. TERM(TERMIEN,TERMARR) ;Load those portions of the term needed for
  1.  ;evaluation.
  1.  I '$D(^PXRMD(811.5,TERMIEN)) Q
  1.  K TERMARR
  1.  N IND,JND
  1.  S TERMARR(0)=^PXRMD(811.5,TERMIEN,0)
  1.  ;Load the findings multiple.
  1.  S IND=0
  1.  F  S IND=+$O(^PXRMD(811.5,TERMIEN,20,IND)) Q:IND=0  D
  1.  . S TERMARR(20,IND,0)=^PXRMD(811.5,TERMIEN,20,IND,0)
  1.  . S TERMARR(20,IND,3)=$G(^PXRMD(811.5,TERMIEN,20,IND,3))
  1.  . S TERMARR(20,IND,10)=$G(^PXRMD(811.5,TERMIEN,20,IND,10))
  1.  . S TERMARR(20,IND,11)=$G(^PXRMD(811.5,TERMIEN,20,IND,11))
  1.  . S TERMARR(20,IND,15)=$G(^PXRMD(811.5,TERMIEN,20,IND,15))
  1.  . S JND=0
  1.  . F  S JND=+$O(^PXRMD(811.5,TERMIEN,20,IND,5,JND)) Q:JND=0  D
  1.  .. S TERMARR(20,IND,5,JND)=^PXRMD(811.5,TERMIEN,20,IND,5,JND,0)
  1.  M TERMARR("E")=^PXRMD(811.5,TERMIEN,20,"E")
  1.  S TERMARR("IEN")=TERMIEN
  1.  Q
  1.  ;