Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: PXRMMH

PXRMMH.m

Go to the documentation of this file. 
  1. PXRMMH ; SLC/PKR - Handle mental health findings. ;11/23/2007
  1.  ;;2.0;CLINICAL REMINDERS;**4,6**;Feb 04, 2005;Build 123
  1.  ;
  1.  ;=======================================================
  1. EVALFI(DFN,DEFARR,ENODE,FIEVAL) ;Evaluate mental health findings.
  1.  D EVALFI^PXRMINDX(DFN,.DEFARR,ENODE,.FIEVAL)
  1.  Q
  1.  ;
  1.  ;=======================================================
  1. EVALPL(FINDPA,ENODE,TERMARR,PLIST) ;Evaluate mental health term findings
  1.  ;for patient lists.
  1.  D EVALPL^PXRMINDL(.FINDPA,ENODE,.TERMARR,PLIST)
  1.  Q
  1.  ;
  1.  ;=======================================================
  1. EVALTERM(DFN,FINDPA,ENODE,TERMARR,TFIEVAL) ;Evaluate mental
  1.  ;health instrument terms.
  1.  D EVALTERM^PXRMINDX(DFN,.FINDPA,ENODE,.TERMARR,.TFIEVAL)
  1.  Q
  1.  ;
  1.  ;=======================================================
  1. GETDATA(DASP,FIEVT) ;Return the data for a MH Administrations entry.
  1.  ;Some tests require the YSP key in order to get a score.
  1.  N DAS,DATA,IND,SCALE
  1.  S DAS=$P(DASP,"S",1)
  1.  S SCALE=+$P(DASP,"S",2)
  1.  ;DBIA #5043
  1.  D ENDAS71^YTQPXRM6(.DATA,DAS)
  1.  I $G(DATA(1))="[ERROR]" Q
  1.  I SCALE=0 S SCALE=+$O(DATA("SI",""))
  1.  S FIEVT("MH TEST")=$P(DATA(2),U,3)
  1.  S IND=0
  1.  F  S IND=$O(DATA("SI",IND)) Q:IND=""  S FIEVT("S",IND)=$P(DATA("SI",IND),U,3,4)
  1.  S IND=0
  1.  F  S IND=$O(DATA("R",IND)) Q:IND=""  S FIEVT("R",IND)=$P(DATA("R",IND),U,6)
  1.  I $D(DATA("SI",SCALE)) S FIEVT("VALUE")=FIEVT("S",SCALE),FIEVT("SCALE NAME")=$P(DATA("SI",SCALE),U,2)
  1.  Q
  1.  ;
  1.  ;=======================================================
  1. MHVOUT(INDENT,IFIEVAL,NLINES,TEXT) ;Produce the MHV output.
  1.  N DATE,IND,JND,MHTEST,NOUT,SCALE,SNAME,SCORE,TEXTOUT
  1.  S MHTEST="Mental Health Test: "_IFIEVAL("MH TEST")_" = "
  1.  S IND=0
  1.  F  S IND=+$O(IFIEVAL(IND)) Q:IND=0  D
  1.  . S DATE="("_$$EDATE^PXRMDATE(IFIEVAL(IND,"DATE"))_")"
  1.  . S TEMP=MHTEST_DATE
  1.  . S SNAME=$G(IFIEVAL(IND,"SCALE NAME"))
  1.  . I SNAME'="" S TEMP=TEMP_" scale: "_SNAME_" -"
  1.  . S SCORE=$G(IFIEVAL(IND,"VALUE"))
  1.  . I SCORE'="" S TEMP=TEMP_"  raw score: "_$P(SCORE,U,1)_", transformed score: "_$P(SCORE,U,2)
  1.  . D FORMATS^PXRMTEXT(INDENT+2,PXRMRM,TEMP,.NOUT,.TEXTOUT)
  1.  . F JND=1:1:NOUT S NLINES=NLINES+1,TEXT(NLINES)=TEXTOUT(JND)
  1.  S NLINES=NLINES+1,TEXT(NLINES)=""
  1.  Q
  1.  ;
  1.  ;=======================================================
  1. OUTPUT(INDENT,IFIEVAL,NLINES,TEXT) ;Produce the clinical
  1.  ;maintenance output.
  1.  N IND,JND,MHTEST,NOUT,SCALE,SNAME,SCORE,TEXTOUT
  1.  S MHTEST=IFIEVAL("MH TEST")
  1.  S NLINES=NLINES+1
  1.  S TEXT(NLINES)=$$INSCHR^PXRMEXLC(INDENT," ")_"Mental Health Test: "_MHTEST
  1.  S IND=0
  1.  F  S IND=+$O(IFIEVAL(IND)) Q:IND=0  D
  1.  . S TEMP=$$EDATE^PXRMDATE(IFIEVAL(IND,"DATE"))
  1.  . S SNAME=$G(IFIEVAL(IND,"SCALE NAME"))
  1.  . I SNAME'="" S TEMP=TEMP_" scale: "_SNAME_" -"
  1.  . S SCORE=$G(IFIEVAL(IND,"VALUE"))
  1.  . I SCORE'="" S TEMP=TEMP_"  raw score: "_$P(SCORE,U,1)_", transformed score: "_$P(SCORE,U,2)
  1.  . D FORMATS^PXRMTEXT(INDENT+2,PXRMRM,TEMP,.NOUT,.TEXTOUT)
  1.  . F JND=1:1:NOUT S NLINES=NLINES+1,TEXT(NLINES)=TEXTOUT(JND)
  1.  S NLINES=NLINES+1,TEXT(NLINES)=""
  1.  Q
  1.  ;
  1.  ;=======================================================
  1. SCHELP(MHIEN) ;Xecutable help for MH SCALE
  1.  N DATA,IND,JND,NUM,SCALE,SNUM
  1.  I MHIEN=0 D  Q
  1.  . S SCALE(1)="This is not a valid Mental Health finding, selecting an MH scale does"
  1.  . S SCALE(2)="not make sense"
  1.  . D EN^DDIOL(.SCALE)
  1.  ;DBIA #5053
  1.  D SCALES^YTQPXRM5(.DATA,MHIEN)
  1.  I DATA(1)="ERROR" D  Q
  1.  . S SCALE(1)="There are no scales for this test."
  1.  . D EN^DDIOL(.SCALE)
  1.  S SCALE(1)="Valid scales are:"
  1.  S SCALE(2)="SCALE NUMBER  SCALE NAME"
  1.  S SCALE(3)="------------------------"
  1.  S IND=0,JND=3
  1.  F  S IND=$O(DATA("S",IND)) Q:IND=""  D
  1.  . S JND=JND+1
  1.  . S NUM=6-$L(IND)
  1.  . S SCALE(JND)=$$INSCHR^PXRMEXLC(NUM," ")_(IND)_"        "_$P(DATA("S",IND),U,1)
  1.  D EN^DDIOL(.SCALE)
  1.  Q
  1.  ;
  1.  ;=======================================================
  1. SCHELPD(DA) ;Xecutable help for MH SCALE in Result Group file 801.41
  1.  N MHIEN
  1.  S MHIEN=+$P($G(^PXRMD(801.41,DA,50)),U)
  1.  D SCHELP^PXRMMH(MHIEN)
  1.  Q
  1.  ;=======================================================
  1. SCHELPF ;Xecutable help for MH SCALE in 811.9 findings.
  1.  N FIND0,MHIEN
  1.  S FIND0=^PXD(811.9,DA(1),20,DA,0)
  1.  I FIND0["YTT(601.71" S MHIEN=$P(FIND0,";",1)
  1.  E  S MHIEN=0
  1.  D SCHELP(MHIEN)
  1.  Q
  1.  ;
  1.  ;=======================================================
  1. SCHELPT ;Xecutable help for MH SCALE in 811.5 findings.
  1.  N MHIEN,TFIND0
  1.  S TFIND0=^PXRMD(811.5,DA(1),20,DA,0)
  1.  I TFIND0["YTT(601.71" S MHIEN=$P(TFIND0,";",1)
  1.  E  S MHIEN=0
  1.  D SCHELP(MHIEN)
  1.  Q
  1.  ;
  1.  ;=======================================================
  1. SCNAME(TEST,SCNUM) ;Given the test ien and scale number return the
  1.  ;scale name.
  1.  N DATA,SCNAME
  1.  D SCALES^YTQPXRM5(.DATA,TEST)
  1.  Q $G(DATA("S",SCNUM))
  1.  ;
  1.  ;=======================================================
  1. SEVALFI(DFN,ITEM,NGET,SDIR,BDT,EDT,NFOUND,FLIST) ;
  1.  N FIEV,FINDING,IND,YS,DATA
  1.  S YS("CODE")=ITEM,YS("DFN")=DFN
  1.  S YS("BEGIN")=BDT,YS("END")=EDT
  1.  ;PTTEST^YTQPXRM2 does not understand "*" for a limit so use 99.
  1.  I NGET="*" S NGET=99
  1.  S YS("LIMIT")=$S(SDIR=-1:NGET,1:-NGET)
  1.  ;DBIA #5035
  1.  D PTTEST^YTQPXRM2(.DATA,.YS)
  1.  S NFOUND=$P(DATA(1),U,2)
  1.  I NFOUND=0 Q
  1.  F IND=1:1:NFOUND S FLIST(IND)=DATA(IND+1)
  1.  Q
  1.  ;
  1.  ;=======================================================
  1. SEVALPL(ITEM,NOCC,BDT,EDT,PLIST) ;Use MH API to get patient list. Called
  1.  ;from PXRMINDL.
  1.  N YS
  1.  ;YTAPI10A does not understand "*" for a limit so use 99.
  1.  ;OCCUR^YTQPXRM1 does not understand "*" for a limit so use 99.
  1.  I NOCC="*" S NOCC=99
  1.  S YS("CODE")=ITEM,YS("BEGIN")=BDT,YS("END")=EDT,YS("LIMIT")=NOCC
  1.  ;DBIA #5034
  1.  D OCCUR^YTQPXRM1(PLIST,.YS)
  1.  Q
  1.  ;
  1.  ;=======================================================
  1. VSCALE(X,FIND0) ;Make sure that the mental health scale is valid.
  1.  ;Either the scale number or the scale name can be used.
  1.  N DATA,IND,MHIEN,MHTEST,SCALE,VALID
  1.  S MHTEST=$P(FIND0,U,1)
  1.  S MHIEN=$P(MHTEST,";",1)
  1.  D SCALES^YTQPXRM5(.DATA,MHIEN)
  1.  I +X>0 S VALID=$S($D(DATA("S",X)):1,1:0)
  1.  E  D
  1.  . S IND=1,VALID=0
  1.  . F  S IND=$O(DATA("S",IND)) Q:(VALID)!(IND="")  D
  1.  .. I X=$P(DATA("S",IND),U,1) S VALID=1 Q
  1.  I 'VALID D EN^DDIOL(X_" is not a valid scale for this test!")
  1.  I $O(DATA(""),-1)>20 H 1
  1.  Q VALID
  1.  ;
  1.  ;=======================================================
  1. VSCALED(X,DA) ;Make sure that the mental health scale is valid for a result
  1.  ;group.
  1.  I X="" Q 1
  1.  ;Do not execute as part of a verify fields.
  1.  I $G(DIUTIL)="VERIFY FIELDS" Q 1
  1.  ;Do not execute as part of exchange.
  1.  I $G(PXRMEXCH) Q 1
  1.  N MHTEST
  1.  S MHTEST=$P($G(^PXRMD(801.41,DA,50)),U)
  1.  Q $$VSCALE(X,MHTEST)
  1.  ;
  1.  ;=======================================================
  1. VSCALEF(X) ;Make sure that the mental health scale is valid for a finding.
  1.  I X="" Q 1
  1.  ;Do not execute as part of a verify fields.
  1.  I $G(DIUTIL)="VERIFY FIELDS" Q 1
  1.  ;Do not execute as part of exchange.
  1.  I $G(PXRMEXCH) Q 1
  1.  N FIND0
  1.  S FIND0=^PXD(811.9,DA(1),20,DA,0)
  1.  Q $$VSCALE(X,FIND0)
  1.  ;
  1.  ;=======================================================
  1. VSCALET(X) ;Make sure that the mental health scale is valid for a 
  1.  ;term finding.
  1.  I X="" Q 1
  1.  ;Do not execute as part of a verify fields.
  1.  I $G(DIUTIL)="VERIFY FIELDS" Q 1
  1.  ;Do not execute as part of exchange.
  1.  I $G(PXRMEXCH) Q 1
  1.  N TFIND0
  1.  S TFIND0=^PXRMD(811.5,DA(1),20,DA,0)
  1.  Q $$VSCALE(X,TFIND0)
  1.  ;
  1.  ;=======================================================
  1. WARN ;Warn the user that they must select a scale if they intend to use
  1.  ;a condition.
  1.  W !,"Remember that the score is returned as raw score^transformed score,"
  1.  W !,"so if your Condition uses the raw score use +V or $P(V,U,1) and if"
  1.  W !,"it uses the transformed score use $P(V,U,2)."
  1.  Q
  1.  ;