Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: PXRMVITL

PXRMVITL.m

Go to the documentation of this file. 
  1. PXRMVITL ;SLC/PKR - Handle vitals findings. ;08/19/2010
  1.  ;;2.0;CLINICAL REMINDERS;**6,12,17,18**;Feb 04, 2005;Build 152
  1.  ;
  1.  ;===========================================================
  1. EVALFI(DFN,DEFARR,ENODE,FIEVAL) ;Evaluate vital measurement findings.
  1.  D EVALFI^PXRMINDX(DFN,.DEFARR,ENODE,.FIEVAL)
  1.  Q
  1.  ;
  1.  ;===========================================================
  1. EVALPL(FINDPA,ENODE,TERMARR,PLIST) ;Evaluate vital measurement
  1.  ;term findings for patient lists.
  1.  D EVALPL^PXRMINDL(.FINDPA,ENODE,.TERMARR,PLIST)
  1.  Q
  1.  ;
  1.  ;===========================================================
  1. EVALTERM(DFN,FINDPA,ENODE,TERMARR,TFIEVAL) ;Evaluate vital measurement
  1.  ;terms.
  1.  D EVALTERM^PXRMINDX(DFN,.FINDPA,ENODE,.TERMARR,.TFIEVAL)
  1.  Q
  1.  ;
  1.  ;===========================================================
  1. GETDATA(DAS,FIEVT) ;Return data for a GMRV Vital Measurement entry.
  1.  N EM,IND,GMRVDATA,STOP,TEMP,TYPE
  1.  ;DBIA #3647
  1.  D EN^GMVPXRM(.GMRVDATA,DAS,"I")
  1.  I $P(GMRVDATA(1),U,1)=-1 D  Q
  1.  . S ^TMP("PXRMXMZ",$J,1,0)="Found GMRV entry "_DAS_" in the index, but it does not exist in ^GMR(120.5"
  1.  . D SEND^PXRMMSG("PXRMXMZ","Bad entry in Vitals index.","",DUZ)
  1.  S FIEVT("TYPE")=$$EXTERNAL^DILFD(120.5,.03,"",GMRVDATA(3),.EM)
  1.  ;DBIA #10040
  1.  S TEMP=$S(+GMRVDATA(5)'=0:^SC(GMRVDATA(5),0),1:"")
  1.  S FIEVT("HOSPITAL LOCATION")=$P(TEMP,U,1)
  1.  S FIEVT("LOCATION TYPE")=$P(TEMP,U,3)
  1.  S STOP=$P(TEMP,U,7)
  1.  S FIEVT("ENTERED BY")=$P(^VA(200,GMRVDATA(6),0),U,1)
  1.  S (FIEVT("RATE"),FIEVT("VALUE"))=$P(GMRVDATA(7),U,1)
  1.  I FIEVT("TYPE")="BLOOD PRESSURE",FIEVT("RATE")["/" D
  1.  . S FIEVT("SYSTOLIC")=$P(FIEVT("RATE"),"/",1)
  1.  . S FIEVT("DIASTOLIC")=$P(FIEVT("RATE"),"/",$L(FIEVT("RATE"),"/"))
  1.  S IND=0
  1.  ;Load the external form of the qualifiers.
  1.  F  S IND=$O(GMRVDATA(12,IND)) Q:IND=""  D
  1.  . S TEMP=$P(GMRVDATA(12,IND),U,1)
  1.  .;DBIA #4504
  1.  . I TEMP'="" S FIEVT("QUALIFIER",IND)=$P($G(^GMRD(120.52,+TEMP,0)),U,1)
  1.  ;DBIA #557
  1.  I STOP'="" S FIEVT("STOP CODE")=$P(^DIC(40.7,STOP,0),U,1,2)
  1.  E  S FIEVT("STOP CODE")=""
  1.  Q
  1.  ;
  1.  ;===========================================================
  1. MHVOUT(INDENT,IFIEVAL,NLINES,TEXT) ;Produce the MHV output.
  1.  N DATE,EM,IND,JND,NAME,NOUT,RATE,TEMP,TEXTOUT,TYPE
  1.  S TYPE=$$EXTERNAL^DILFD(120.5,.03,"",IFIEVAL("TYPE"),.EM)
  1.  S NAME="Vital Measurement: "_TYPE_" = "
  1.  S IND=0
  1.  F  S IND=+$O(IFIEVAL(IND)) Q:IND=0  D
  1.  . S RATE=$G(IFIEVAL(IND,"VALUE"))
  1.  . I RATE="" S RATE="MISSING"
  1.  . S DATE=IFIEVAL(IND,"DATE")
  1.  . S TEMP=NAME_RATE_" ("_$$EDATE^PXRMDATE(DATE)_")"
  1.  . D FORMATS^PXRMTEXT(INDENT+2,PXRMRM,TEMP,.NOUT,.TEXTOUT)
  1.  . F JND=1:1:NOUT S NLINES=NLINES+1,TEXT(NLINES)=TEXTOUT(JND)
  1.  S NLINES=NLINES+1,TEXT(NLINES)=""
  1.  Q
  1.  ;
  1.  ;===========================================================
  1. OUTPUT(INDENT,IFIEVAL,NLINES,TEXT) ;Produce the clinical
  1.  ;maintenance output.
  1.  N DATE,EM,IND,JND,NOUT,RATE,TEMP,TEXTOUT,TYPE
  1.  S NLINES=NLINES+1
  1.  S TEXT(NLINES)=$$INSCHR^PXRMEXLC(INDENT," ")_"Vital Measurement: "_IFIEVAL("TYPE")
  1.  S IND=0
  1.  F  S IND=+$O(IFIEVAL(IND)) Q:IND=0  D
  1.  . S DATE=IFIEVAL(IND,"DATE")
  1.  . S TEMP=$$EDATE^PXRMDATE(DATE)
  1.  . S RATE=$G(IFIEVAL(IND,"VALUE"))
  1.  . I RATE="" S RATE="MISSING"
  1.  . S TEMP=TEMP_"; rate - "_RATE
  1.  . D FORMATS^PXRMTEXT(INDENT+2,PXRMRM,TEMP,.NOUT,.TEXTOUT)
  1.  . F JND=1:1:NOUT S NLINES=NLINES+1,TEXT(NLINES)=TEXTOUT(JND)
  1.  .;If there are qualifiers display them.
  1.  . I $D(IFIEVAL(IND,"QUALIFIER")) D
  1.  .. S TEMP="Qualifiers:"
  1.  .. N QIND S QIND=0
  1.  .. S QIND=$O(IFIEVAL(IND,"QUALIFIER",QIND)) S TEMP=TEMP_" "_IFIEVAL(IND,"QUALIFIER",QIND)
  1.  .. F  S QIND=$O(IFIEVAL(IND,"QUALIFIER",QIND)) Q:QIND=""  S TEMP=TEMP_", "_IFIEVAL(IND,"QUALIFIER",QIND)
  1.  .. D FORMATS^PXRMTEXT(INDENT+3,PXRMRM,TEMP,.NOUT,.TEXTOUT)
  1.  .. F JND=1:1:NOUT S NLINES=NLINES+1,TEXT(NLINES)=TEXTOUT(JND)
  1.  S NLINES=NLINES+1,TEXT(NLINES)=""
  1.  Q
  1.  ;