Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: RADD2

RADD2.m

Go to the documentation of this file. 
  1. RADD2 ;HISC/GJC/CAH-Radiology Data Dictionary Utility Routine ;5/14/97  10:31
  1.  ;;5.0;Radiology/Nuclear Medicine;**84,47**;Mar 16, 1998;Build 21
  1.  ;
  1.  ;Integration Agreements
  1.  ;----------------------
  1.  ;EN^DDIOL(10142); FILE^DIE(2053);NOTE^ORX3(868);MES^XPDUTL(10141)
  1.  ;
  1. EN1(RAX,RAY) ; Input transform for the .01 field (Procedure) for the Rad/Nuc
  1.  ; Med Common Procedure file i.e, ^RAMIS(71.3
  1.  ; Procedure must not have an inactive date before today in file 71
  1.  ; Procedure in file 71 must have same imaging type as the one
  1.  ;   selected before editing this record in file 71.3
  1.  ; If 'Parent' type procedure, it must have at least 1 descendent
  1.  ; 'RAX' is the value of the .01 field in ^RAMIS(71.3,
  1.  ; 'RAY' are ien's of entries in ^RAMIS(71,
  1.  I '$G(RAIMGTYI) Q 0
  1.  I $S('$D(^("I")):1,'^("I"):1,DT'>^("I"):1,1:0),$S(RAIMGTYI=$P($G(^RAMIS(71,+RAY,0)),"^",12):1,1:0),$S($P(^RAMIS(71,+RAY,0),U,6)'="P":1,$O(^RAMIS(71,+RAY,4,0)):1,1:0)
  1.  Q $T
  1.  ;
  1. CH(RAY,RAX) ; This subroutine will fire off the 'Radiology Request Cancel
  1.  ; /Hold' notification as defined in the 'OE/RR NOTIFICATIONS' file.
  1.  ; Only if request is either cancelled or held.  Called from the set
  1.  ; logic of the 'ACHN' xref in ^DD(75.1,5) field definition.
  1.  ;
  1.  ; Input variables:
  1.  ; 'RAX'=Request status of the order, $S(X=1:'discontinued',X=3:'hold')
  1.  ; 'RAY'=ien of the order in the RAD/NUC MED ORDERS file.
  1.  ;
  1.  Q:(RAY'=+RAY)  Q:(RAX'=1)&(RAX'=3)
  1.  N %,C,D,D0,DA,DC,DDER,DE,DG,DH,DI,DIC,DIE,DIEDA,DIEL,DIFLD,DIP,DIW,DIWT
  1.  N DK,DL,DM,DN,DP,DQ,DR,DU,DV,DW,I,J,N,ORBPMSG,ORBXDATA,ORIFN,ORNOTE,ORVP
  1.  N RA751,RADFN,RANME,RAOIFN,RAOLP,RAOPTN,RAORDS,RAOREA,RAOSTS,RAPARENT
  1.  N RAPRC,RAXIT,X,Y
  1.  S RA751=$G(^RAO(75.1,RAY,0)) Q:RA751']""
  1.  S RAOIFN=RAY,RADFN=+$P(RA751,"^")
  1.  S RAPRC=$P($G(^RAMIS(71,+$P(RA751,"^",2),0)),"^"),ORVP=RADFN_";DPT("
  1.  S ORBPMSG=$S(RAX=1:"Discontinued - ",1:"On hold - ")_$E(RAPRC,1,17)
  1.  S ORBXDATA=RAOIFN_","_RADFN,ORIFN=+$P(RA751,"^",7),ORNOTE(26)=1
  1.  D NOTE^ORX3
  1.  Q
  1. INACOM(RAD0) ; Check inactive date on the Rad/Nuc Med Procedure file (71)
  1.  ; for the Common Procedure before setting our inactive procedure to
  1.  ; active.  Called from the 'RA COMMON PROCEDURE EDIT' input template.
  1.  ; Option: Common Procedure Enter/Edit (13^RAMAIN2)
  1.  ; Input : RAD0-ien of Rad/Nuc Med Common Procedure
  1.  ; Output: if Common cannot be re-activated, reset the 'Inactive' field
  1.  ;         to 'yes'.
  1.  N RAINA S RAINA=$P($G(^RAMIS(71,+$P($G(^RAMIS(71.3,RAD0,0)),"^"),"I")),"^")
  1.  Q:RAINA=""!(RAINA>DT) "@15" ; we can inactivate the common
  1.  N RAFDA,RAMSG
  1.  S RAFDA(71.3,RAD0_",",4)="Y" D FILE^DIE("","RAFDA","") S RAMSG(1)=$C(7)
  1.  S RAMSG(2)="You cannot add this procedure to the common procedure list"
  1.  S RAMSG(3)="because it is inactivated in the Rad/Nuc Med Procedures file."
  1.  S RAMSG(4)="You must first re-activate the procedure through the 'Procedure"
  1.  S RAMSG(5)="Enter/Edit' option.",RAMSG(6)="" D MES^XPDUTL(.RAMSG)
  1.  Q "@10" ; reset 'Inactive' to 'yes', re-edit field.
  1.  ;
  1. EN2() ; called from ^DD(74,0,"ID","WRITE")
  1.  ; display long case #'s in the same print set as current record
  1.  N RA1,RA2
  1.  S RA1=0,RA2=""
  1.  ; F  S RA1=$O(^RARPT(Y,1,"B",RA1)) Q:'RA1  S RA2=RA2_$S(RA2="":"-",1:",-")_$P(RA1,"-",2)
  1.  F  S RA1=$O(^RARPT(Y,1,"B",RA1)) Q:'RA1  S RA2=RA2_$S(RA2="":"-",1:",-")_$P(RA1,"-",$L(RA1,"-"))  ;P47 to accommodate possible SSAN format
  1.  Q RA2
  1. USUAL(RADA,RAX) ; To insure that the USUAL DOSE value falls between the
  1.  ; HIGH ADULT DOSE and the LOW ADULT DOSE.
  1.  ; Input Variables:
  1.  ;     RADA -> top level/sub-file level IEN's
  1.  ;      RAX -> value input by the user
  1.  ; Output Variable: $S(1: value is accepted, 0: value not accepted)
  1.  ;
  1.  Q:RAX="" 0 ; X does not exist
  1.  N RA7108,RAH,RAL S RA7108=$G(^RAMIS(71,RADA(1),"NUC",RADA,0))
  1.  S RAH=$P(RA7108,"^",5),RAL=$P(RA7108,"^",6)
  1.  S RAH=$S(RAH="":99999.9999,1:RAH),RAL=$S(RAL="":.0001,1:RAL)
  1.  I (+RAX<RAL)!(+RAX>RAH) D  Q 0 ; value is not accepted
  1.  . N RARRY S RARRY(1)="The 'USUAL DOSE' must fall within the range of: "
  1.  . S RARRY(1)=RARRY(1)_RAL_" - "_RAH_" "
  1.  . D EN^DDIOL(.RARRY)
  1.  . Q
  1.  E  Q 1 ; value accepted
  1.  ;
  1. RANGE(RADA) ; Determine the range in which the 'USUAL DOSE' must fall
  1.  ; Input Variables:
  1.  ;     RADA  -> top level/sub-file level IEN's
  1.  ; Output Variable:
  1.  ;     RANGE -> the range in which the 'USUAL DOSE' must fall
  1.  N RA7108,RAH,RAL
  1.  S RA7108=$G(^RAMIS(71,RADA(1),"NUC",RADA,0))
  1.  S RAH=$P(RA7108,"^",5),RAL=$P(RA7108,"^",6)
  1.  S RAH=$S(RAH="":99999.9999,1:RAH),RAL=$S(RAL="":.0001,1:RAL)
  1.  Q RAL_"-"_RAH
  1. MEDOSE(RAY,RADT) ; Determine if this individual (RAY) is authorized to
  1.  ; administer medications.  Called from ^DD(70.15,4,12.1)
  1.  ; Input : RAY (pnt to 200) - the individual being checked at the moment 
  1.  ;         RADT - Date of the examination
  1.  ; Output: '1' - user is authorized to administer medications, else '0'
  1.  ;
  1.  Q:$D(^VA(200,"ARC","R",RAY)) 1 ; Rad/Nuc Med Class: Resident
  1.  Q:$D(^VA(200,"ARC","S",RAY)) 1 ; Rad/Nuc Med Class: Staff
  1.  Q:$D(^VA(200,"ARC","T",RAY)) 1 ; Rad/Nuc Med Class: Technologist
  1.  Q:$D(^XUSEC("ORES",RAY)) 1 Q:$D(^XUSEC("ORELSE",RAY)) 1
  1.  N RAUTH S RAUTH=$G(^VA(200,RAY,"PS"))
  1.  ; If authorized to write med orders ($P(RAUTH,"^")=1) and inactivation
  1.  ; date null -OR- inactivation date greater than or equal to the exam
  1.  ; date individual is authorized.
  1.  Q:+$P(RAUTH,"^")&($S('$P(RAUTH,"^",4):1,$P(RAUTH,"^",4)'<RADT:1,1:0)) 1
  1.  Q 0
  1.  ;
  1. PRIDXIXK(DA,X) ;This subroutine executes the KILL logic for the 'new style' AD cross-
  1.  ;reference on the 'PRIMARY DIAGNOSTIC CODE' (data dictionary: 70.03; field: 13)
  1.  ;Input: DA - an array where DA(2)=RADFN, DA(1)=RADTI, & DA=RACNI
  1.  ;        X - the primary diagnostic code value (this field points to file 78.3)
  1.  N RACNI,RADFN,RADTI,RAFDA,RAIENS,RAX
  1.  S RADFN=DA(2),RADTI=DA(1),RACNI=DA,RAX=X ;save the variables just in case
  1.  S RAIENS=DA_","_DA(1)_","_DA(2)_",",RAFDA(70.03,RAIENS,20)="@"
  1.  D FILE^DIE(,"RAFDA") ;delete data in 'DIAGNOSTIC PRINT DATE' (DD: 70.03; field: 20)
  1.  K ^RADPT("AD",RAX,RADFN,RADTI,RACNI)
  1.  Q
  1.  ;