Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: RAHLRS

RAHLRS.m

Go to the documentation of this file. 
  1. RAHLRS ;HIRMFO/CRT/PDW - Resend HL7 messages for selected cases ;01/19/08 12:40
  1.  ;;5.0;Radiology/Nuclear Medicine;**25,54,60,71,82,95**;Mar 16, 1998;Build 7
  1.  ;
  1.  ; Utility to RESEND HL7 messages
  1.  ;
  1.  ;;02/14/2006 BAY/KAM RA*5*71 Add ability to update exam data to V/R
  1.  N RACNI,RADFN,RADTI,RARPT,X
  1.  ;
  1.  D SETVARS Q:$G(RAIMGTY)=""
  1.  ;
  1.  F  S X=$$RACNLU(.RADFN,.RADTI,.RACNI) Q:+X'>0  D  Q:QUIT<0
  1.  .D RESEND(RADFN,RADTI,RACNI,.QUIT)
  1.  Q
  1.  ;
  1. RACNLU(RADFN,RADTI,RACNI) ; Select Case Number
  1.  ;
  1.  N RANOSCRN S RANOSCRN="" ; Don't limit cases to current Imaging Type
  1.  S (RADFN,RADTI,RADFN)=""
  1.  D ^RACNLU
  1.  Q X
  1.  ;
  1. RESEND(RADFN,RADTI,RACNI,QUIT) ; re-send exam message(s) to HL7 subscribers
  1.  ;
  1.  N RAED,RASSSX,RARPST ;added RASSSX,RARPST, RA*5*95
  1.  ;
  1.  S QUIT=0
  1.  I '$D(DT) D ^%DT S DT=Y
  1.  ;
  1.  S RAED=$$RAED(RADFN,RADTI,RACNI)
  1.  S QUIT=$$OK(RADFN,RADTI,RACNI)
  1.  I QUIT>0 D
  1.  .I RAED[",REG," D
  1.  ..D EN^DDIOL("Re-sending 'EXAM REGISTERD' HL7 message...",,"!!,?6")
  1.  ..D REG^RAHLRPC
  1.  .I RAED[",CANCEL," D
  1.  ..D EN^DDIOL("Re-sending 'EXAM CANCELLED' HL7 message...",,"!,?6")
  1.  ..D CANCEL^RAHLRPC
  1.  .I RAED[",EXAM," D
  1.  ..S $P(^RADPT(RADFN,"DT",RADTI,"P",RACNI,0),"^",30)="" ;Reset sent flag
  1.  ..D EN^DDIOL("Re-sending 'EXAMINED' HL7 message...",,"!,?6")
  1.  ..N RAEXMDUN D 1^RAHLRPC ;*60 Newed RAEXMDUN to prevent variable leak
  1.  .I RAED[",RPT," D
  1.  ..D EN^DDIOL("Re-sending 'REPORT VERIFIED' HL7 message...",,"!,?6")
  1.  ..;If EF report, set up RASSSX() to exclude VR subscribers, RA*5*95
  1.  ..I $G(RARPST)="EF" D HLXMSG^RARTE5
  1.  ..D RPT^RAHLRPC
  1.  Q
  1.  ;
  1. RAED(RADFN,RADTI,RACNI) ; identify correct ^RAHLRPC entry point(s)
  1.  ;
  1.  ; removed RARPTST from new, RA*5*95
  1.  N RASTAT,RAIMTYP,RAORD,RETURN
  1.  S (RARPST,RASTAT)=""
  1.  ;
  1.  S RETURN=",REG,"
  1.  ;
  1.  S RASTAT=$$GET1^DIQ(70.03,RACNI_","_RADTI_","_RADFN,3,"I")
  1.  ;
  1.  S RAIMTYP=$$GET1^DIQ(72,+RASTAT,7)
  1.  S RAORD=$$GET1^DIQ(72,+RASTAT,3)
  1.  ;
  1.  S:RAORD=0 RETURN=RETURN_"CANCEL,"
  1.  ;
  1.  I $$GET1^DIQ(72,+RASTAT,8)="YES" D  ; Generate Examined HL7 Message
  1.  .S RETURN=RETURN_"EXAM,"
  1.  ;
  1.  I RETURN'[",EXAM," D
  1.  .; also check previous statuses for 'Generate Examined HL7 Message'
  1.  .F  S RAORD=$O(^RA(72,"AA",RAIMTYP,RAORD),-1) Q:+RAORD<1  D  Q:RETURN[",EXAM,"
  1.  ..S RASTAT=$O(^RA(72,"AA",RAIMTYP,RAORD,0))
  1.  ..I $$GET1^DIQ(72,+RASTAT,8)="YES" S RETURN=RETURN_"EXAM,"
  1.  ;
  1.  I RARPT]"" D  ; Check if Verified or Elect. Filed report exists
  1.  .S RARPST=$$GET1^DIQ(74,RARPT,5,"I")
  1.  .I "^V^EF^"[("^"_RARPST_"^") S RETURN=RETURN_"RPT," ;RA*5*95
  1.  ;
  1.  Q RETURN
  1.  ;
  1. OK(RADFN,RADTI,RACNI) ; Get User to confirm continue
  1.  ;
  1.  N X,RAEXST
  1.  ;
  1.  S RAEXST=$$GET1^DIQ(70.03,RACNI_","_RADTI_","_RADFN,3)
  1.  ;
  1.  S X="",$P(X,"=",70)=""
  1.  D EN^DDIOL(X,"","!?5")
  1.  S DIR("A")="Re-send all HL7 messages for this '"_RAEXST_"' case?"
  1.  S DIR(0)="Y",DIR("B")="YES" D ^DIR
  1.  I Y="^" Q -1
  1.  Q Y
  1.  ;
  1. SETVARS ; Setup key Rad/Nuc Med variables
  1.  ;
  1.  I $O(RACCESS(DUZ,""))="" D SETVARS^RAPSET1(0)
  1.  Q:'($D(RACCESS(DUZ))\10)  ; user does not have location access
  1.  I $G(RAIMGTY)="" D SETVARS^RAPSET1(1) K:$G(RAIMGTY)="" XQUIT
  1.  Q