Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: RAMAGU10

RAMAGU10.m

Go to the documentation of this file. 
  1. RAMAGU10 ;HCIOFO/SG - ORDERS/EXAMS API (RAMISC VALID. #74) ; 3/5/09 2:23pm
  1.  ;;5.0;Radiology/Nuclear Medicine;**90**;Mar 16, 1998;Build 20
  1.  ;
  1.  Q
  1.  ;
  1.  ;***** VALIDATES RAMISC PARAMETERS RELATED TO THE FILE #74
  1.  ;
  1.  ; RAIENS        IENS of the report (file #74)
  1.  ;
  1.  ; RACTION       Action (can be combined):
  1.  ;                 E  Examined (procedure has been performed)
  1.  ;                 C  Complete
  1.  ;
  1.  ; .RAMISC       Reference to a local array containing miscellaneous
  1.  ;               request parameters.
  1.  ;
  1.  ; .RAFDA(       Reference to a local array where field values will
  1.  ;               be prepared for storage (FileMan FDA array).
  1.  ;
  1.  ;   "RACNT")    This is an additional node that stores counter for
  1.  ;               the IENS placeholders. Do not forget to remove this
  1.  ;               node before passing the array into a FileMan API.
  1.  ;
  1.  ;   "RAIENS")   This is an additional node that stores IENS of the
  1.  ;               record being processed. Do not forget to remove this 
  1.  ;               node before passing the array into a FileMan API.
  1.  ;
  1.  ; [RAFDACNT]    New value for the placeholder counter for the RAFDA. 
  1.  ;               If this parameter is greater than zero, it replaces
  1.  ;               the value stored in the RAFDA("RACNT").
  1.  ;
  1.  ; Input variables:
  1.  ;   RAMSPSDEFS
  1.  ;
  1.  ; Return values:
  1.  ;       <0  Error code
  1.  ;        0  Ok
  1.  ;
  1. VAL74(RAIENS,RACTION,RAMISC,RAFDA,RAFDACNT) ;
  1.  N ERRCNT,RC,TMP
  1.  ;
  1.  ;--- Check required parameters and variables
  1.  S RC=$$CHKREQ^RAUTL22("RACTION,RAIENS")  Q:RC<0 RC
  1.  Q:$TR(RACTION,"EC")'="" $$IPVE^RAERR("RACTION")
  1.  ;
  1.  ;--- Initialize variables
  1.  S RAFDA("RAIENS")=RAIENS
  1.  S:$G(RAFDACNT)>0 RAFDA("RACNT")=+RAFDACNT
  1.  S (ERRCNT,RC)=0
  1.  ;
  1.  ;--- Validate parameters specific to the 'COMPLETE' status
  1.  I RACTION["C"  D  S:TMP<0 ERRCNT=ERRCNT+1
  1.  . S TMP=$$VCOMPLT(RAIENS,RACTION,.RAMISC,.RAFDA)
  1.  ;
  1.  ;--- Error handling and cleanup
  1.  Q $S(ERRCNT>0:-11,1:0)
  1.  ;
  1.  ;+++++ VALIDATES 'COMPLETE' PARAMETERS
  1. VCOMPLT(RAIENS,RACTION,RAMISC,RAFDA) ;
  1.  N ERRCNT,NAME,PNODE,RC,TMP
  1.  S ERRCNT=0
  1.  ;
  1.  ;=== Word-processing fields
  1.  S:$$VALPRM^RAMAGU09("ACLHIST",,RAIENS)<0 ERRCNT=ERRCNT+1
  1.  S:$$VALPRM^RAMAGU09("IMPRESSION",,RAIENS)<0 ERRCNT=ERRCNT+1
  1.  S:$$VALPRM^RAMAGU09("REPORT",,RAIENS,,"R")<0 ERRCNT=ERRCNT+1
  1.  ;
  1.  ;=== Problem statement
  1.  S RC=$$VALPRM^RAMAGU09("PROBSTAT",,RAIENS)
  1.  I RC>0  D
  1.  . K RAFDA(74,RAIENS,25)  ; Do not store directly
  1.  E  S:RC<0 ERRCNT=ERRCNT+1
  1.  ;
  1.  ;=== Report date
  1.  S NAME="RPTDTE"
  1.  S:$D(RAMISC(NAME))#10 RAMISC(NAME)=RAMISC(NAME)\1  ; Strip the time
  1.  S:$$VALPRM^RAMAGU09(NAME,,RAIENS,,"R")<0 ERRCNT=ERRCNT+1
  1.  ;
  1.  ;=== Transcriptionist
  1.  S:$$VALPRM^RAMAGU09("TRANSCRST",,RAIENS)<0 ERRCNT=ERRCNT+1
  1.  ;
  1.  ;=== Verification date
  1.  S:$$VALPRM^RAMAGU09("VERDTE",,RAIENS)<0 ERRCNT=ERRCNT+1
  1.  ;
  1.  ;=== Verifying physician
  1.  S:$$VALPRM^RAMAGU09("VERPHYS",,RAIENS)<0 ERRCNT=ERRCNT+1
  1.  ;
  1.  ;=== Report status
  1.  S PNODE=$NA(RAMISC("RPTSTATUS"))
  1.  S:'($D(@PNODE)#10) @PNODE="V"
  1.  I @PNODE'="V",@PNODE'="EF"  D:$P($G(RAMSPSDEFS("R")),U,12)
  1.  . D IPVE^RAERR(PNODE)  S ERRCNT=ERRCNT+1
  1.  ;
  1.  ;=== Error handling and cleanup
  1.  Q $S(ERRCNT>0:-11,1:0)