Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: SCAPMC6

SCAPMC6.m

Go to the documentation of this file. 
  1. SCAPMC6 ;ALB/REW - Team APIs:APPTTM ; 5 Jul 1995
  1.  ;;5.3;Scheduling;**41,1015**;AUG 13, 1993;Build 21
  1.  ;;1.0
  1. ACPTTM(DFN,SCTM,SCFIELDA,SCACT,SCERR) ;add a patient to a team (pt tm assgn - #404.42
  1.  ; input:
  1.  ;  DFN     = pointer to PATIENT file (#2)
  1.  ;  SCTM    = pointer to TEAM file (#404.51)
  1.  ;  SCFIELDA= array of additional fields to be added
  1.  ;  SCACT   = date to activate [default=DT]
  1.  ;  SCERR = array NAME to store error messages.
  1.  ;          [ex. ^TMP("ORXX",$J)]
  1.  ;
  1.  ; Output:
  1.  ;  Returned = ien of 404.42 - 0 if none after^new?^Message
  1.  ;  SCERR() = Array of DIALOG file messages(errors) .
  1.  ;             Foramt:
  1.  ;               Subscript: Sequential # from 1 to n
  1.  ;               Piece     Description
  1.  ;                 1       IEN of DIALOG file
  1.  N SCPTTM,SCESEQ,SCPARM,SCIEN,SC,SCFLD,SCNEWTM
  1.  G:'$$OKDATA APTTMQ ;check/setup variables
  1.  IF $S('$D(SCFIELDA):0,('($D(@SCFIELDA@(.08))#2)):0,($G(@SCFIELDA@(.08))=1):1,1:0) IF '$$OKPTTMPC^SCMCTMU2(DFN,SCTM,SCACT) D  G APTTMQ
  1.  .S SCMESS=4044200.001
  1.  S SCPTTM=$$PTTMACT(DFN,SCTM,SCACT,.SCERR)
  1.  IF SCPTTM G APTTMQ
  1.  ELSE  D
  1.  .IF $D(SCFIELDA) D
  1.  ..S SCFLD=0
  1.  ..F  S SCFLD=$O(@SCFIELDA@(SCFLD)) Q:'SCFLD  D
  1.  ...S SC($J,404.42,"+1,",SCFLD)=@SCFIELDA@(SCFLD)
  1.  .S SC($J,404.42,"+1,",.01)=DFN
  1.  .S SC($J,404.42,"+1,",.02)=SCACT
  1.  .S SC($J,404.42,"+1,",.03)=SCTM
  1.  .D UPDATE^DIE("","SC($J)","SCIEN","SCERR")
  1.  .IF $D(@SCERR) K SCIEN
  1.  .ELSE  D
  1.  ..S SCPTTM=$G(SCIEN(1))
  1.  ..S SCNEWTM=1
  1.  ..D AFTERTM^SCMCDD1(SCPTTM)
  1. APTTMQ Q +$G(SCPTTM)_U_+$G(SCNEWTM)
  1.  ;
  1. PTTMACT(DFN,SCTM,SCDT,SCERR) ;what is patient/team assignment on a given date-time into the future? Return 404.42 ien or 0
  1.  N SCTMLST,SCOK,SCPTTMDT
  1.  S SCOK=0
  1.  S SCPTTMDT("BEGIN")=SCDT,SCPTTMDT("END")=3990101,SCPTTMDT("INCL")=0
  1.  IF $$TMPT^SCAPMC3(DFN,"SCPTTMDT","","SCTMLST",.SCERR) S:$D(SCTMLST("SCTM",SCTM)) SCOK=$O(SCTMLST("SCTM",SCTM,0))
  1.  Q SCOK
  1.  ;
  1. ACPTATM(DFNA,SCTM,SCFIELDA,SCACT,SCERR,SCNEWTM,SCOLDTM,SCBADTM) ;list of patients assigned to a team (404.42)
  1.  ; input: as per ACPTTM (above with the following change:)
  1.  ;    DFNA    = is the literal value of a patient array (e.g. "scpt"
  1.  ;              there is at least one scpt(dfn)="" defined
  1.  ;    SCNEWTM = Subset of DFNA that was NEWLY assigned to Team [returned]
  1.  ;    SCOLDTM = Subset of DFNA that was already assigned -Team [returned]
  1.  ;    SCBADTP = Subset of DFNA that was NOT assigned to Team  [returned]
  1.  ;    Note: The above three arrays return data in a user determined array
  1.  ; output: Count of Patients: 
  1.  ;           1             2            3               4
  1.  ;    total assigned^newly assigned^assigned prior^not assigned
  1.  N DFN,SCNEWCNT,SCOLDCNT,SCBADCNT,SCX,SCNOMAIL
  1.  S SCNOMAIL=1
  1.  S (SCNEWCNT,SCOLDCNT,SCBADCNT)=0
  1.  S DFN=0 F  S DFN=$O(@DFNA@(DFN)) Q:'DFN  D
  1.  .S SCX=$$ACPTTM(.DFN,.SCTM,.SCFIELDA,.SCACT,.SCERR)
  1.  .;  SCX = ien of 404.42^new?
  1.  .IF $P(SCX,U,2) D  ;newly assigned
  1.  ..S SCNEWCNT=SCNEWCNT+1
  1.  ..S @SCNEWTM@(DFN)=+SCX   ;scnewtm
  1.  .IF $P(SCX,U,1)&('$P(SCX,U,2)) D  ;old
  1.  ..S SCOLDCNT=SCOLDCNT+1
  1.  ..S @SCOLDTM@(DFN)=+SCX
  1.  .IF 'SCX D
  1.  ..S @SCBADTM@(DFN)=$P(SCX,U,3)
  1.  ..S SCBADCNT=SCBADCNT+1
  1.  K SCNOMAIL
  1.  D MAILLST^SCMCTMM(SCTM,.SCADDFLD,DT,.SCNEWTM,.SCOLDTM,.SCBADTM)
  1.  Q (SCNEWCNT+SCOLDCNT)_U_SCNEWCNT_U_SCOLDCNT_U_SCBADCNT
  1.  ;
  1. OKDATA() ;setup/check variables
  1.  N SCOK
  1.  S SCOK=1
  1.  D INIT^SCAPMCU1(.SCOK)
  1.  IF '$D(^DPT(DFN,0))!('$D(^SCTM(404.51,SCTM,0))) D  S SCOK=0
  1.  . S SCPARM("PATIENT")=DFN
  1.  . S SCPARM("TEAM")=SCTM
  1.  . D ERR^SCAPMCU1(SCESEQ,4045101,.SCPARM,"",.SCERR)
  1.  S:'$G(SCACT) SCACT=DT
  1.  Q SCOK