Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: SCENIA1

SCENIA1.m

Go to the documentation of this file.
  1. SCENIA1 ;ALB/SCK - INCOMPLETE ENCOUNTER ERROR DISPLAY PROTOCOLS ; 09 Oct 98 3:03 PM
  1. ;;5.3;Scheduling;**66,154,323,378,1015**;AUG 13, 1993;Build 21
  1. ;
  1. VE ; View Expanded Error
  1. N SDHDR1,SDHDR2
  1. S SDHDR1=VALMHDR(1)
  1. S SDHDR2=VALMHDR(2)
  1. S VALMBCK=""
  1. D EN^SCENIB0
  1. S VALMBCK="R"
  1. Q
  1. ;
  1. CE ; Entry point for getting corrective action for error and executing it.
  1. ; Variables
  1. ; SCXER - Ptr to 409.76
  1. ; SCEN - Ptr to 409.75
  1. ; SDXMT - Ptr to 409.73
  1. ;
  1. N SCXER,SCEN
  1. ;;;; MOD
  1. K ^TMP("SCENI COR",$J)
  1. ;
  1. D SELERM("O")
  1. Q:'$D(SCXER)
  1. ;
  1. ;;;;; MOD
  1. ;F I=1:1 S SCTEXT=$P($T(HDR+I),";;",2) Q:SCTEXT["$$END" D
  1. ;. W !?2,SCTEXT
  1. ;
  1. S SCEN=0
  1. S SDXMT=$G(^TMP("SCENI XMT",$J,0)) Q:'SDXMT
  1. F S SCEN=$O(SCXER(SCEN)) Q:'SCEN D
  1. . Q:'$D(^SD(409.75,SCEN,0))
  1. . S SCCOR=$G(^SD(409.76,$P(^SD(409.75,SCEN,0),U,2),"COR"))
  1. . I SCCOR="" D ERMSG(1) Q
  1. .;;;;;; MOD
  1. . Q:$D(^TMP("SCENI COR",$J,$P(SCCOR,"(")))
  1. . W !!,$G(^SD(409.76,$P(^SD(409.75,SCEN,0),U,2),1))
  1. . X SCCOR
  1. . I 'RTN D ERMSG(2) ;;;Q
  1. .;;;;; MOD
  1. . S ^TMP("SCENI COR",$J,$P(SCCOR,"("))=""
  1. ;
  1. ; ** After correcting selected errors, fire off the validator and reflag
  1. ; transmission entry
  1. W !,"Performing Ambulatory Care Validation Checks..."
  1. S RTN=$$VALIDATE^SCMSVUT2(SDXMT)
  1. I RTN<0 D ERMSG(5) G CEQ
  1. S RTN=$$SETRFLG(SDXMT)
  1. I RTN<0 D ERMSG(3) G CEQ
  1. ;
  1. ;;;;; MOD
  1. K ^TMP("SCENI COR",$J)
  1. CEQ Q
  1. ;
  1. EDI() ; Entry point for ENCOUNTER INFORMATION corrective action
  1. S SDOK=0
  1. D EI^SCENIA2
  1. Q SDOK
  1. ;
  1. DEM1() ; Entry point for correction logic
  1. S SDOK=0
  1. D DEM
  1. Q SDOK
  1. ;
  1. DEM ; Entry point for the SCENI PATIENT DEMOGRAPHICS protocol
  1. N DFN,SDXMT,RTN
  1. ;
  1. S DFN=$G(^TMP("SCENI DFN",$J,0)) Q:'DFN
  1. S SDXMT=$G(^TMP("SCENI XMT",$J,0)) Q:'SDXMT
  1. D FULL^VALM1
  1. ;SD*5.3*323 add sensitive record warning if applicable
  1. ;reference to DGRPU1 allowed in Integration Agreement 413
  1. N DIC S DIC=2,DIC(0)="EM",X="`"_DFN D ^DIC I Y=-1 S SDOK=1 Q
  1. D QUES^DGRPU1(DFN,"ADD3")
  1. ;
  1. I '$D(SDOK) D
  1. . W !,"Performing Ambulatory Care Validation Checks..."
  1. . S RTN=$$VALIDATE^SCMSVUT2(SDXMT)
  1. . ;;; MOD
  1. . I RTN<0 D ERMSG(5) Q ;G DEMQ
  1. . S RTN=$$SETRFLG(SDXMT)
  1. . I RTN<0 D ERMSG(3) Q ;G DEMQ
  1. I $D(SDOK) S SDOK=1
  1. DEMQ Q
  1. ;
  1. INTV() ; Entry point for correction logic for checkout errors
  1. S SDOK=0
  1. D CO
  1. Q SDOK
  1. ;
  1. CO ; Entry point for SCENI CHECKOUT INTERVIEW
  1. N SDXMT,SCENFLG,SDOE,SDDT,SDOEND
  1. K SCINF
  1. ;SD*5.3*323 add sensitive record warning if applicable next 5 lines
  1. N DFN
  1. S DFN=$G(^TMP("SCENI DFN",$J,0)) Q:'DFN
  1. S SDXMT=$G(^TMP("SCENI XMT",$J,0)) Q:'SDXMT
  1. D FULL^VALM1
  1. N DIC S DIC=2,DIC(0)="EM",X="`"_DFN D ^DIC I Y=-1 S SDOK=1 Q
  1. S SCSTAT=$$OPENC^SCUTIE1(SDXMT,"SCINF")
  1. I SCSTAT D G COQ
  1. . D FULL^VALM1
  1. . W !!,$CHAR(7),"This is a deleted encounter. Checkout information cannot be changed!"
  1. . D PAUSE^VALM1
  1. ;
  1. S SDOE=$P(^SD(409.73,SDXMT,0),U,2)
  1. S SDOEND=$G(^SCE(+SDOE,0))
  1. S SDCOHDL="",SCENFLG=1,VALMBCK=""
  1. ;
  1. I $P(SDOEND,U,8)=2,$P(SDOEND,U,6)="" D ADDEDIT(SDOEND) I 1
  1. E D EN^SDCO6
  1. ;
  1. S VALMBCK="R"
  1. ;
  1. I '$D(SDOK) D
  1. . W !,"Performing Ambulatory Care Validation Checks..."
  1. . S RTN=$$VALIDATE^SCMSVUT2(SDXMT)
  1. . ;;; MOD
  1. . I RTN<0 D ERMSG(5) Q ;G COQ
  1. . S RTN=$$SETRFLG(SDXMT)
  1. . I RTN<0 D ERMSG(3) Q ;G COQ
  1. I $D(SDOK) S SDOK=1
  1. COQ ;
  1. Q
  1. ;
  1. ADDEDIT(SDOEND) ;this is to edit add/edits
  1. N VAR
  1. Q:'$P(SDOEND,U,5)
  1. S VAR=$$INTV^PXAPI("ADDEDIT","SD","PIMS",$P(SDOEND,U,5),"",$P(SDOEND,U,2))
  1. Q
  1. ;
  1. LEDT() ;
  1. S SDOK=0
  1. D LE
  1. Q SDOK
  1. ;
  1. LE ; Entry point patient load edit.
  1. N DFN,SDXMT
  1. ;
  1. S DFN=$G(^TMP("SCENI DFN",$J,0)) Q:'DFN
  1. S SDXMT=$G(^TMP("SCENI XMT",$J,0)) Q:'SDXMT
  1. S VALMBCK="",DGNEW=0
  1. D FULL^VALM1
  1. ;SD*5.3*323 add sensitive record warning if applicable
  1. N DIC S DIC=2,DIC(0)="EM",X="`"_DFN D ^DIC I Y=-1 S SDOK=1 Q
  1. D A1^DG10
  1. I '$D(SDOK) D
  1. . W !,"Performing Ambulatory Care Validation Checks."
  1. . S RTN=$$VALIDATE^SCMSVUT2(SDXMT)
  1. . ;;;;; MOD
  1. . I RTN<0 D ERMSG(5) Q ;G LEQ
  1. . S RTN=$$SETRFLG(SDXMT)
  1. . I RTN<0 D ERMSG(3) Q ;G LEQ
  1. I $D(SDOK) S SDOK=1
  1. LEQ ;
  1. Q
  1. ;
  1. REFLG() ; Entry point for reflag correction action
  1. ;;;; MOD
  1. ;S SDOK=0
  1. ;D FLG
  1. ;Q SDOK
  1. Q 1
  1. ;
  1. FLG ; Entry point for Reflag Transmission protocol
  1. N SDXMT
  1. ;
  1. S SDXMT=$G(^TMP("SCENI XMT",$J,0)) Q:'SDXMT
  1. W !,"Performing Ambulatory Care Validation Checks..."
  1. S RTN=$$VALIDATE^SCMSVUT2(SDXMT)
  1. I RTN<0 D ERMSG(5) G FLQ
  1. S RTN=$$SETRFLG(SDXMT)
  1. I RTN<0 D ERMSG(3) G FLQ
  1. ;;;; MOD
  1. ;I $D(SDOK) S SDOK=1
  1. FLQ Q
  1. ;
  1. SETRFLG(SDXMT) ;
  1. ; Input
  1. ; SDXMT - Pointer to Transmission File, #409.73
  1. ;
  1. ; Output
  1. ; -1 - There was a problem reflaging the transmission
  1. ; 0 - No errors occured
  1. ; 1 - The entry is already flagged for transmission
  1. ;
  1. S RESULT=-1
  1. S STATUS=$P($G(^SD(409.73,SDXMT,0)),U,4)
  1. I STATUS S RESULT=1
  1. E D
  1. . D XMITFLAG^SCDXFU01(SDXMT,0),STREEVNT^SCDXFU01(SDXMT,0)
  1. . S RESULT=0
  1. D INIT^SCENIA0
  1. D RE^VALM4
  1. Q RESULT
  1. ;
  1. MSG(SDTEXT,SDEXMT) ;
  1. W:SDTEXT]"" !!,SDTEXT,!
  1. S DIR(0)="FAO",DIR("A")="Press ENTER to continue " D ^DIR K DIR
  1. Q 1
  1. ;
  1. SELERM(FLG) ; Select Multiple entries
  1. N VALMY
  1. ;
  1. D FULL^VALM1
  1. I $G(FLG)']"" S FLG="O"
  1. D EN^VALM2(XQORNOD(0),FLG) S VALMI=0
  1. I '$D(VALMY) S VALMBCK="R" Q
  1. S SDN1=""
  1. F S SDN1=$O(VALMY(SDN1)) Q:'SDN1 D
  1. . S SCEPTR="",SCEPTR=$O(^TMP("SCENI ERR",$J,"DA",SDN1,SCEPTR))
  1. . I SCEPTR>0 S SCXER(SCEPTR)=""
  1. Q
  1. ;
  1. ERMSG(MSGN) ;
  1. D FULL^VALM1
  1. S SCTEXT=$P($T(@MSGN),";;",2)
  1. W $CHAR(7)
  1. W !!?5,SCTEXT,!
  1. S DIR(0)="FAO",DIR("A")="Press ENTER to continue " D ^DIR K DIR
  1. S VALMBCK="R"
  1. Q
  1. ;
  1. EXIT ;
  1. I $D(VALMBCK),VALMBCK="R" D REFRESH^VALM S VALMBCK=$P(VALMBCK,"R")_$P(VALMBCK,"R",2)
  1. Q
  1. ;
  1. HDR ;
  1. ;;Selecting a range of errors to correct may result in one or
  1. ;;more similar errors being removed from the display list after
  1. ;;correction of the initial error.
  1. ;;$$END
  1. ;
  1. 1 ;;No correction logic has been defined for this error.
  1. 2 ;;Unable to execute Correction Logic.
  1. 3 ;;There was a problem trying to flag this entry for retransmission.
  1. 4 ;;This transmission entry is already flagged for transmission.
  1. 5 ;;The validator encountered a problem with this transmission entry.