Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: SCMCHLA

SCMCHLA.m

Go to the documentation of this file. 
  1. SCMCHLA ;ALB/KCL - PCMM HL7 Transmission Log File API'S ;25-JAN-2000
  1.  ;;5.3;Scheduling;**210,272,1015**;AUG 13, 1993;Build 21
  1.  ;
  1. LOCK(SCTLIEN) ; Description: Used to lock a record in the PCMM HL7
  1.  ; TANSMISSION LOG file.
  1.  ;
  1.  ;  Input:
  1.  ;   SCTLIEN - ien of a record in the PCMM HL7 TRANSMISSION LOG file
  1.  ;
  1.  ; Output:
  1.  ;  Function Value: Returns 1 on success, 0 on faliure
  1.  ;
  1.  I $G(SCTLIEN) L +^SCPT(404.471,SCTLIEN):3
  1.  ;
  1.  Q $T
  1.  ;
  1.  ;
  1. UNLOCK(SCTLIEN) ; Description: Used to unlock a record in the PCMM HL7
  1.  ; TANSMISSION LOG file.
  1.  ;
  1.  ;  Input:
  1.  ;   SCTLIEN - ien of a record in the PCMM HL7 TRANSMISSION LOG file
  1.  ;
  1.  ; Output: None
  1.  ;
  1.  I $G(SCTLIEN) L -^SCPT(404.471,SCTLIEN)
  1.  Q
  1.  ;
  1.  ;
  1. GETLOG(SCTLIEN,SCECIEN,TLOG) ;
  1.  ; Description: Used to obtain a record in the PCMM HL7 TRANSMISSION LOG
  1.  ; file and a record in the Error Code subfile.  The field values will
  1.  ; be returned in the TLOG array.
  1.  ;
  1.  ;  Input:
  1.  ;   SCTLIEN - ien of a record in the PCMM HL7 TRANSMISSION LOG file
  1.  ;   SCECIEN - ien of record in the Error Code subfile
  1.  ;
  1.  ; Output:
  1.  ;  Function Value: Returns 1 on success, 0 on faliure
  1.  ;  TLOG - this is the name of a local array, it should be passed by
  1.  ;         reference.  If the function is successful the array will
  1.  ;         contain the PCMM HL7 TRANSMISSION LOG record and the
  1.  ;         Error Code subfile record.
  1.  ;
  1.  ;         subscript           field name
  1.  ;         ---------           ----------
  1.  ;         "MSGID"             Message Control ID
  1.  ;         "DFN"               Patient
  1.  ;         "TRANS"             Transmission Date/Time
  1.  ;         "STATUS"            Status
  1.  ;         "ACK DT/TM"         ACK Received Date/Time
  1.  ;
  1.  ;  Error Code subfile record:
  1.  ;         "ERR","CODE"        Error Code
  1.  ;         "ERR","SEG"         Segment
  1.  ;         "ERR","SEQ"         Sequence
  1.  ;         "ERR","ZPCID"       ZPC ID
  1.  ;         "ERR","EPS"         Error Processing Status
  1.  ;
  1.  N NODE
  1.  K TLOG S TLOG=""
  1.  Q:'$G(SCTLIEN) 0
  1.  ;
  1.  S NODE=$G(^SCPT(404.471,SCTLIEN,0))
  1.  Q:(NODE="") 0
  1.  S TLOG("MSGID")=$P(NODE,"^")
  1.  S TLOG("DFN")=$P(NODE,"^",2)
  1.  S TLOG("TRANS")=$P(NODE,"^",3)
  1.  S TLOG("STATUS")=$P(NODE,"^",4)
  1.  S TLOG("ACK DT/TM")=$P(NODE,"^",5)
  1.  S TLOG("WORK")=$P(NODE,"^",7)
  1.  ;
  1.  S TLOG("ERR")=""
  1.  I $G(SCECIEN) D
  1.  .S NODE=$G(^SCPT(404.471,SCTLIEN,"ERR",SCECIEN,0))
  1.  .S TLOG("ERR","CODE")=$P(NODE,"^")
  1.  .S TLOG("ERR","SEG")=$P(NODE,"^",2)
  1.  .S TLOG("ERR","SEQ")=$P(NODE,"^",3)
  1.  .S TLOG("ERR","ZPCID")=$P(NODE,"^",5)
  1.  .S TLOG("ERR","EPS")=$P(NODE,"^",6)
  1.  ;
  1.  Q 1
  1.  ;
  1.  ;
  1. STATUS(SCTLIEN) ;
  1.  ; Description: Used to get STATUS field for record in PCMM HL7
  1.  ; TRANSMISSION LOG file.
  1.  ;
  1.  ;  Input:
  1.  ;   SCTLIEN - IEN of PCM HL7 TRANSMISSION LOG file
  1.  ;
  1.  ; Output:
  1.  ;  Funtion Value: Returns STATUS field value, null otherwise.
  1.  ;
  1.  Q:'$G(SCTLIEN) ""
  1.  Q $P($G(^SCPT(404.471,SCTLIEN,0)),"^",4)
  1.  ;
  1.  ;
  1. UPDSTAT(SCTLIEN,STATUS,ERROR) ;
  1.  ; Description: Used to update the STATUS field of record in PCMM HL7
  1.  ; TRANSMISSION LOG file.
  1.  ;
  1.  ;  Input:
  1.  ;   SCTLIEN - IEN of PCM HL7 TRANSMISSION LOG file
  1.  ;    STATUS - T=Transmitted, A=Accepted, RJ=Rejected,
  1.  ;             M=Marked for re-transmission, RT=Re-transmitted
  1.  ;
  1.  ; Output:
  1.  ;  Funtion Value: Returns 1 on success, 0 on failure.
  1.  ;  ERROR - returns error message on failure, pass by reference 
  1.  ;
  1.  N SCERR,SCFDA,SCIENS
  1.  ;
  1.  S ERROR=""
  1.  ;
  1.  I '$G(SCTLIEN) S ERROR="NO RECORD SPECIFIED" Q 0
  1.  I '$$LOCK(SCTLIEN) S ERROR="UNABLE TO OBTAIN LOCK ON RECORD" Q 0
  1.  I ",T,A,RJ,M,RT,"'[(","_$G(STATUS)_",") S ERROR="INVALID STATUS" Q 0
  1.  ;
  1.  S SCIENS=SCTLIEN_","
  1.  S SCFDA(404.471,SCIENS,.04)=STATUS  ; Status
  1.  D FILE^DIE("","SCFDA","SCERR")
  1.  ;
  1.  D UNLOCK(SCTLIEN)
  1.  ;
  1.  ; if error returned from DBS call, unable to file data
  1.  I $G(SCERR) S ERROR="UNABLE TO UPDATE STATUS FIELD" Q 0
  1.  ;
  1.  Q 1
  1.  ;
  1.  ;
  1. INCLUDE(SCTLIEN) ;
  1.  ; Description: Used to get INCLUDED IN REJECT BULLETIN? field for
  1.  ; record in PCMM HL7 TRANSMISSION LOG file.
  1.  ;
  1.  ;  Input:
  1.  ;   SCTLIEN - IEN of PCM HL7 TRANSMISSION LOG file
  1.  ;
  1.  ; Output:
  1.  ;  Funtion Value: Returns INCLUDED IN REJECT BULLETIN? field value, null otherwise.
  1.  ;
  1.  Q:'$G(SCTLIEN) ""
  1.  Q $P($G(^SCPT(404.471,SCTLIEN,0)),"^",6)
  1.  ;
  1.  ;
  1. UPDINCL(SCTLIEN,SCINCL,ERROR) ;
  1.  ; Description: Used to update the INCLUDED IN REJECT BULLETIN? field of
  1.  ; record in the PCMM HL7 TRANSMISSION LOG file.
  1.  ;
  1.  ;  Input:
  1.  ;    SCTLIEN - IEN of record in PCMM HL7 TRANSMISSION LOG file
  1.  ;     SCINCL - 'Y'=YES
  1.  ;
  1.  ; Output:
  1.  ;  Funtion Value: Returns 1 on success, 0 on failure.
  1.  ;  ERROR - returns error message on failure, pass by reference 
  1.  ;
  1.  N SCERR,SCFDA,SCIENS
  1.  ;
  1.  S ERROR=""
  1.  ;
  1.  I '$G(SCTLIEN) S ERROR="NO RECORD SPECIFIED" Q 0
  1.  I $G(SCINCL)'="Y" S ERROR="INVALID FIELD VALUE" Q 0
  1.  I '$$LOCK(SCTLIEN) S ERROR="UNABLE TO OBTAIN LOCK ON RECORD" Q 0
  1.  ;
  1.  S SCIENS=SCTLIEN_","
  1.  S SCFDA(404.471,SCIENS,.06)=SCINCL  ; Included In Reject Bulletin?
  1.  D FILE^DIE("","SCFDA","SCERR")
  1.  ;
  1.  D UNLOCK(SCTLIEN)
  1.  ;
  1.  ; if error returned from DBS call, unable to file data
  1.  I $G(SCERR) S ERROR="UNABLE TO UPDATE 'INCLUDED IN REJECT BULLETIN?' FIELD" Q 0
  1.  ;
  1.  Q 1
  1.  ;
  1.  ;
  1. ACK(SCTLIEN) ;
  1.  ; Description: Used to get ACK RECEIVED DATE/TIME field for
  1.  ; record in PCMM HL7 TRANSMISSION LOG file.
  1.  ;
  1.  ;  Input:
  1.  ;   SCTLIEN - IEN of PCM HL7 TRANSMISSION LOG file
  1.  ;
  1.  ; Output:
  1.  ;  Funtion Value: Returns ACK RECEIVED DATE/TIME field value, 0 otherwise.
  1.  ;
  1.  Q:'$G(SCTLIEN) 0
  1.  Q $P($G(^SCPT(404.471,SCTLIEN,0)),"^",5)
  1.  ;
  1.  ;
  1. UPDEPS(SCTLIEN,SCERIEN,EPSTAT,ERROR) ;
  1.  ; Description: Used to update the ERROR PROCESSING STATUS field of
  1.  ; record in the Error Code (#404.47142) subfile.
  1.  ;
  1.  ;  Input:
  1.  ;    SCTLIEN - IEN of record in PCMM HL7 TRANSMISSION LOG file
  1.  ;    SCERIEN - IEN record in ERROR CODE (#404.47142) subfile
  1.  ;     EPSTAT - 1=NEW, 2=CHECKED
  1.  ;
  1.  ; Output:
  1.  ;  Funtion Value: Returns 1 on success, 0 on failure.
  1.  ;  ERROR - returns error message on failure, pass by reference 
  1.  ;
  1.  N SCERR,SCFDA,SCIENS,STATUS
  1.  ;
  1.  S ERROR=""
  1.  ;
  1.  I '$G(SCTLIEN) S ERROR="NO RECORD SPECIFIED" Q 0
  1.  I '$G(SCERIEN) S ERROR="NO SUB-RECORD SPECIFIED" Q 0
  1.  I '$G(EPSTAT) S ERROR="INVALID ERROR PROCESSING STATUS" Q 0
  1.  S STATUS=$$STATUS(SCTLIEN)
  1.  I (STATUS'="RJ")&(STATUS'="M") S ERROR="STATUS IS NOT 'REJECTED' OR 'MARKED FOR RE-TRANSMIT'" Q 0
  1.  I '$$LOCK(SCTLIEN) S ERROR="UNABLE TO OBTAIN LOCK ON RECORD" Q 0
  1.  ;
  1.  S SCIENS=SCERIEN_","_SCTLIEN_","
  1.  S SCFDA(404.47142,SCIENS,.06)=EPSTAT  ; Error Processing Status
  1.  D FILE^DIE("","SCFDA","SCERR")
  1.  ;
  1.  D UNLOCK(SCTLIEN)
  1.  ;
  1.  ; if error returned from DBS call, unable to file data
  1.  I $G(SCERR) S ERROR="UNABLE TO UPDATE STATUS FIELD" Q 0
  1.  ;
  1.  Q 1