Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: SCMSVROL

SCMSVROL.m

Go to the documentation of this file. 
  1. SCMSVROL ;BP/JRP - HL7 ROL Segment Validation;6-MAR-1998
  1.  ;;5.3;Scheduling;**142,245,1015**;Aug 13, 1993;Build 21
  1.  ;
  1.  ;
  1. EN(ROLARRY,HLQ,HLFS,HLECH,VALERR) ;Entry point to validate all HL7 ROL
  1.  ; (Role) segments built for message
  1.  ;
  1.  ;Input : ROLARRY - Array of ROL Segments
  1.  ;        HLQ - HL7 null designation
  1.  ;        HLFS - HL7 field separator
  1.  ;        HLECH - HL7 encouding characters
  1.  ;        VALERR - Array to return error list in (full global reference)
  1.  ;
  1.  ;Output:  1 - All ROL segments passed validity checks
  1.  ;        -1^Text - One/many/all ROL segments failed validity checks
  1.  ;        List of errors returned as follows:
  1.  ;          VALERR("ROL",x) = Error Code
  1.  ;Notes : Initialization of VALERR() is the reponsibility of the
  1.  ;        calling program
  1.  ;      : Existance/validity of input is assumed
  1.  ;
  1.  ;Declare variables
  1.  N LOOP1,CNT,MSG,PRIMECNT,TMP,SCMSVROL,PRIME
  1.  S MSG="-1^Element in ROL segment failed validity check"
  1.  S PRIMECNT=0
  1.  ;Loop through array of ROL segments
  1.  S LOOP1=0
  1.  F  S LOOP1=+$O(@ROLARRY@(LOOP1)) Q:('LOOP1)  D
  1.  .;Validate individual segment
  1.  .S TMP=$$EN1($NA(@ROLARRY@(LOOP1)),HLQ,HLFS,HLECH,VALERR,.PRIME)
  1.  .;Track total number of primary providers designated
  1.  .I PRIME S PRIMECNT=PRIMECNT+1
  1.  ;Make logic in D050 only allow the number 1
  1.  S SCMSVROL=1
  1.  ;Validate number of primary providers designated (must be 1)
  1.  S CNT=1+$O(@VALERR@("ROL",""),-1)
  1.  D VALIDATE^SCMSVUT0("ROL",PRIMECNT,"D050",VALERR,.CNT)
  1. ENQ Q $S($D(@VALERR@("ROL")):MSG,1:1)
  1.  ;
  1. EN1(ROLSEG,HLQ,HLFS,HLECH,VALERR,PRIME) ;Entry point to validate the HL7 ROL
  1.  ; (Role) segment
  1.  ;
  1.  ;Input : ROLSEG - Array containing ROL Segment (full global reference)
  1.  ;                 ROLSEG = First 245 characters
  1.  ;                 ROLSEG(x) = Continuation nodes
  1.  ;        HLQ - HL7 null designation
  1.  ;        HLFS - HL7 field separator
  1.  ;        HLECH - HL7 encoding characters
  1.  ;        VALERR - Array to return error list in (full global reference)
  1.  ;        PRIME - Output variable (pass by reference)
  1.  ;
  1.  ;Output:  1 - ROL segment passed validity checks
  1.  ;        -1^Text - ROL segment failed validity checks
  1.  ;        List of errors returned as follows:
  1.  ;          VALERR("ROL",x) = Error Code
  1.  ;        PRIME = 1 if primary encounter provider
  1.  ;        PRIME = 0 if not primary encounter provider
  1.  ;Notes : Initialization of VALERR() is the reponsibility of the
  1.  ;        calling program
  1.  ;      : Existance/validity of input is assumed
  1.  ;
  1.  ;Declare variables
  1.  N SEG,MSG,CNT,TMP,PARSEG,OLDCNT,CMPSEP,SCMSVROL,LOOP,CODE,CHECK
  1.  S MSG="-1^Element in ROL segment failed validity check"
  1.  S (OLDCNT,CNT)=1+$O(@VALERR@("ROL",""),-1)
  1.  S PRIME=0
  1.  ;Parse out fields
  1.  S TMP("FS")=HLFS,TMP("ECH")=HLECH,TMP("Q")=HLQ
  1.  D PARSEG^SCMSVUT4(ROLSEG,"PARSEG",.TMP,0,1)
  1.  I PARSEG(0)'="ROL" D VALIDATE^SCMSVUT0("ROL","","0370",VALERR,.CNT) G EN1Q
  1.  ;Remember component separator
  1.  S CMPSEP=$E(HLECH,1)
  1.  ;Primary care provider ?
  1.  S DATA=$G(PARSEG(3,1))
  1.  S:($P(DATA,CMPSEP,4)=1) PRIME=1
  1.  ;Make logic in D050 allow numbers 0 and 1
  1.  S SCMSVROL=0
  1.  ;Validate
  1.  S CODE=""
  1.  F LOOP=1:1 D  Q:CODE=""
  1.  .S DATA=$T(ERRORS+LOOP)
  1.  .S CODE=$P(DATA,";",3)
  1.  .Q:(CODE="")
  1.  .S CHECK=$P(DATA,";",1)
  1.  .S DATA=$G(PARSEG(+$E(CHECK,1,2),+$E(CHECK,3,4)))
  1.  .S DATA=$P(DATA,CMPSEP,+$E(CHECK,5,6),+$E(CHECK,7,8))
  1.  .D VALIDATE^SCMSVUT0("ROL",DATA,CODE,VALERR,.CNT)
  1. EN1Q Q $S(CNT'=OLDCNT:MSG,1:1)
  1.  ;
  1.  ;Line tag format is SSRRBCEC
  1.  ;  SS=sequence, RR=repetition
  1.  ;  BC=begining component, EC=ending component
  1. ERRORS ;Data elements validated
  1. 01010101  ;;D150;ROLE INSTANCE ID
  1. 03010101  ;;D000;PROVIDER TYPE CODE
  1. 03010404  ;;D050;PRIMARY ENCOUNTER PROVIDER DESIGNATION
  1. 04010101  ;;D070;INVALID PROVIDER ID
  1. 04010207        ;;D130;PROVIDER NAME
  1. 04020101        ;;D140;PROVIDER SSN
  1.  ;;
  1.  ;;