Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: SCRPI01A

SCRPI01A.m

Go to the documentation of this file.
  1. SCRPI01A ;ALB/SCK - IEMM REPORT OF INCOMPLETE ENCOUNTERS PRINT ; 6/24/97
  1. ;;5.3;Scheduling;**66,1015**;AUG 13, 1993;Build 21
  1. Q
  1. PRINT ; Begin printing report
  1. ; Variables
  1. ; PAGE - Page Number
  1. ; SDIV - Division Name
  1. ; SDCLN - Clinic Name
  1. ; SDNAME - Patient Name
  1. ; SDT - Encounter Date
  1. ; SCABORT - Abort report flag
  1. ;
  1. N DASH,DBLDASH,PAGE,SDIV,SDCLN,SDNAME,SDT,SCABORT,NONAME
  1. ;
  1. S $P(DASH,"-",IOM-1)="",$P(DBLDASH,"=",IOM-1)=""
  1. S PAGE=0,SDIV=""
  1. ;
  1. I '$D(^TMP("SCRPI ERR",$J)) D HDR1 Q
  1. ;
  1. F S SDIV=$O(^TMP("SCRPI ERR",$J,SDIV)) Q:SDIV']"" D Q:$G(SCABORT)
  1. . S SDCLN=""
  1. . F S SDCLN=$O(^TMP("SCRPI ERR",$J,SDIV,SDCLN)) Q:SDCLN']"" D Q:$G(SCABORT)
  1. .. D HDR(SDIV,SDCLN)
  1. .. Q:$G(SCABORT)
  1. .. S SDNAME=""
  1. .. F S SDNAME=$O(^TMP("SCRPI ERR",$J,SDIV,SDCLN,SDNAME)) Q:SDNAME']"" D Q:$G(SCABORT)
  1. ... S SDT="",NONAME=0
  1. ... F S SDT=$O(^TMP("SCRPI ERR",$J,SDIV,SDCLN,SDNAME,SDT)) Q:'SDT D Q:$G(SCABORT)
  1. .... S SDER=""
  1. .... F S SDER=$O(^TMP("SCRPI ERR",$J,SDIV,SDCLN,SDNAME,SDT,SDER)) Q:'SDER D LINE(^TMP("SCRPI ERR",$J,SDIV,SDCLN,SDNAME,SDT,SDER,0)) Q:$G(SCABORT)
  1. ;
  1. D SELPAGE
  1. Q
  1. ;
  1. LINE(SDTMP) ; Print formatted line of the report. Check if task has been stopped by user.
  1. ; Set abort flag to quit if stopped.
  1. ; Input
  1. ; SDTMP - formatted line to print
  1. ;
  1. ; Output
  1. ; SCABORT - 1 if user aborts report printing
  1. ;
  1. ; Variables
  1. ; SCERR - Error Code form #409.76
  1. ; SCERR1 - Error Description from #409.76
  1. ;
  1. N X,X1,X2,SCERR,SCERR1,DFN
  1. ;
  1. ; ** if task has been stopped, set abort flag and quit.
  1. I $$S^%ZTLOAD D Q
  1. . S SCABORT=1
  1. . W !!,"Report stopped by user"
  1. ;
  1. I $Y>(IOSL-5) D HDR(SDIV,SDCLN)
  1. ;
  1. ; ** Check that error is still around and has not been corrected.
  1. Q:'$G(^SD(409.75,SDER,0))
  1. S SCERR=^SD(409.76,$P(^SD(409.75,SDER,0),U,2),0)
  1. S SCERR1=^SD(409.76,$P(^SD(409.75,SDER,0),U,2),1)
  1. ;
  1. S DFN=$P(SDTMP,U)
  1. D PID^VADPT6
  1. W !,$S('NONAME:$E(SDNAME,1,25),1:" "),?27,$S('NONAME:VA("BID"),1:" ")
  1. W ?33,$S($P(SDTMP,U,3)]"":$P(SDTMP,U,3),1:" ")," "
  1. W $$FMTE^XLFDT(SDT,"2FP"),?55,$S($P(SCERR,U,2)="V":"VISTA",$P(SCERR,U,2)="N":"NPCD ",1:"UNK "),?62,$P(SCERR,U)
  1. ;
  1. ; ** Parse out error description to fit report. If description length >50, then
  1. ; call parse procedure to break description into two lines.
  1. S X=$P(SCERR1,U)
  1. I $L(X)<50 D
  1. . W ?68,X
  1. E D
  1. . K X1,X2
  1. . D PARSE^SCRPIUT1(X,.X1,.X2,45,51)
  1. . W ?68,X1,!?68,X2
  1. S NONAME=1
  1. K VA
  1. Q
  1. ;
  1. HDR(SDIV,SDCLN) ; Print report header, if abort flag is set, then quit
  1. ; Input
  1. ; SDIV - Division Name
  1. ; SDCLN - Clinic Name
  1. ;
  1. ; Variables
  1. ; SDL - Print line
  1. ;
  1. N SDL,X
  1. ;
  1. I 'PAGE,IOST?1"C-".E W @IOF
  1. I PAGE,IOST?1"C-".E D Q:$G(SCABORT)
  1. . S DIR(0)="E" D ^DIR K DIR S SCABORT='+$G(Y)
  1. . W @IOF
  1. E D
  1. . I PAGE W @IOF
  1. ;
  1. S PAGE=PAGE+1
  1. W !?2,"Date: ",$$FDATE^VALM1($$DT^XLFDT),?((IOM/2)-22),"Incomplete Encounter Management Error Listing",?(IOM-13),"Page: ",PAGE
  1. ;
  1. S X="Division: "_$S($G(SDIV)]"":SDIV,1:" ---")
  1. D CTR^SCRPIUT1(.X,IOM)
  1. W !,X
  1. ;
  1. S X="Clinic: "_$S($G(SDCLN)]"":SDCLN,1:" ---")
  1. D CTR^SCRPIUT1(.X,IOM)
  1. W !,X
  1. ;
  1. S X="Date Range: "_$$FMTE^XLFDT($P(SDDT,U))_" to "_$$FMTE^XLFDT($P(SDDT,U,2))
  1. D CTR^SCRPIUT1(.X,IOM)
  1. W !,X
  1. ;
  1. S X="Selection Method by "_$$SELMTHD^SCRPI01(SDSEL1)_" then by "_$$SELMTHD^SCRPI01(SDSEL2)
  1. D CTR^SCRPIUT1(.X,IOM)
  1. W !,X
  1. ;
  1. W !!!,?35,"Encounter",?54,"Error",?62,"Error"
  1. W !,"Patient Name",?27,"SSN",?35,"Date/Time",?54,"Srce",?62,"Code",?68,"Description"
  1. W !,DBLDASH
  1. S X="[ '*' Indicates Deleted Outpatient Encounter for Transmission ]"
  1. D CTR^SCRPIUT1(.X,IOM)
  1. W !,X,!
  1. Q
  1. ;
  1. HDR1 ; Report header for no data found. Prints modified header.
  1. ;
  1. W !?2,"Date: ",$$FDATE^VALM1($$DT^XLFDT),?((IOM/2)-22),"Incomplete Encounter Management Error Listing"
  1. S X="Date Range: "_$$FMTE^XLFDT($P(SDDT,U))_" to "_$$FMTE^XLFDT($P(SDDT,U,2))
  1. D CTR^SCRPIUT1(.X,IOM)
  1. W !,X
  1. S X="Selection Method by "_$$SELMTHD^SCRPI01(SDSEL1)_" then by "_$$SELMTHD^SCRPI01(SDSEL2)
  1. D CTR^SCRPIUT1(.X,IOM)
  1. W !,X,!!
  1. W !?5,"No errors found"
  1. D NEXTLEV(SDSEL1)
  1. D NEXTLEV(SDSEL2)
  1. Q
  1. ;
  1. SELPAGE ; Print on last page the user parameters used for the report.
  1. N SDIV,SDCLN,SDERR,SDPAT,SDDSS
  1. ;
  1. I 'PAGE,IOST?1"C-".E W @IOF
  1. I PAGE,IOST?1"C-".E D Q:$G(SCABORT)
  1. . S DIR(0)="E" D ^DIR K DIR S SCABORT='+$G(Y)
  1. . W @IOF
  1. E D
  1. . I PAGE W @IOF
  1. ;
  1. S PAGE=PAGE+1
  1. W !?2,"Date: ",$$FDATE^VALM1($$DT^XLFDT),?((IOM/2)-22),"Incomplete Encounter Management Error Listing",?(IOM-13),"Page: ",PAGE
  1. S X="Report Selection Criteria"
  1. D CTR^SCRPIUT1(X,IOM)
  1. S X="Date Range: "_$$FMTE^XLFDT($P(SDDT,U))_" to "_$$FMTE^XLFDT($P(SDDT,U,2))
  1. D CTR^SCRPIUT1(X,IOM)
  1. ;
  1. W !!?10,"Divisions: ",$S(VAUTD:"All",1:"")
  1. I 'VAUTD S SDIV="" F S SDIV=$O(VAUTD(SDIV)) Q:'SDIV W !?15,VAUTD(SDIV)
  1. ;
  1. D NEXTLEV(SDSEL1)
  1. D NEXTLEV(SDSEL2)
  1. Q
  1. ;
  1. NEXTLEV(SRT) ; Print out any sublevels of the user selection parameters
  1. N SDITEM
  1. ;
  1. I SRT["CLN" D
  1. . W !!?10,"Clinics: ",$S(VAUTC:"All",1:"")
  1. . I 'VAUTC S SDITEM="" F S SDITEM=$O(VAUTC(SDITEM)) Q:'SDITEM W !?15,VAUTC(SDITEM)
  1. ;
  1. I SRT["PAT" D
  1. . W !!?10,"Patients: ",$S(VAUTN:"All",1:"")
  1. . I 'VAUTN S SDITEM="" F S SDITEM=$O(VAUTN(SDITEM)) Q:'SDITEM W !?15,VAUTN(SDITEM)
  1. ;
  1. I SRT["ERR" D
  1. . W !!?10,"Error Codes: ",$S(VAUER:"All",1:"")
  1. . I 'VAUER S SDITEM="" F S SDITEM=$O(VAUER(SDITEM)) Q:'SDITEM W !?15,VAUER(SDITEM)," ",$E($P(^SD(409.76,SDITEM,1),U),1,60)
  1. ;
  1. I SRT["DSS" D
  1. . W !!?10,"Clinic Stop Codes: ",$S(VAUDS:"All",1:"")
  1. . I 'VAUDS S SDITEM="" F S SDITEM=$O(VAUDS(SDITEM)) Q:'SDITEM W !?15,VAUDS(SDITEM)
  1. Q