Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: SCRPI01

SCRPI01.m

Go to the documentation of this file. 
  1. SCRPI01 ;ALB/SCK - IEMM REPORT OF INCOMPLETE ENCOUNTERS ; 2/2/97
  1.  ;;5.3;Scheduling;**66,338,1015**;AUG 13, 1993;Build 21
  1.  ;
  1. EN ;  Main entry point for report of incomplete encounters report
  1.  ;  Variables
  1.  ;      SDTXT        - String array for initial message display
  1.  ;      SDDT         - date Range, Begin^End
  1.  ;      SDSEL1,2     - Selection methods Line Tag
  1.  ;      SDOK         - Flag, 1 - Ok to continu, 0 - Quit
  1.  ;
  1.  N VAUTD,VAUTC,VAUDS,VAUTSTR,VAUTNI,SDTXT,SDDT,ZTSAVE,VAUTN,VAUER,SDSEL1,SDSEL2,SDOK,NDX,VAUTVB
  1.  ;
  1.  W !,$C(7)
  1.  F NDX=1:1 S SDTXT=$P($T(MSG+NDX),";;",2) Q:SDTXT="$$END"  D
  1.  . W !,SDTXT
  1.  W !!
  1.  S DIR(0)="E" D ^DIR K DIR Q:'$G(Y)
  1.  ; 
  1.  I $$DIV^SCRPIUT1<0 G ENQ
  1.  D MSG2
  1.  S SDSEL1=$$SELCT("","First") G:SDSEL1']"" ENQ
  1.  S SDSEL2=$$SELCT(SDSEL1,"Next") G:SDSEL2']"" ENQ
  1.  I '$$ASKDT^SCENI01(.SDDT) G ENQ
  1.  ;
  1.  D @SDSEL1 Q:$G(SDOK)<0
  1.  D @SDSEL2 Q:$G(SDOK)<0
  1.  ;
  1.  F X="SDDT","VAUTC","VAUTD","VAUDS","VAUDS(","VAUTC(","VAUTD(","SDSEL1","SDSEL2","VAUTN","VAUTN(","VAUER","VAUER(" D
  1.  . S ZTSAVE(X)=""
  1.  S IOP="Q"
  1.  W !!,"This report requires 132 columns and could take some time.",!,"Remember to QUEUE the report.",!
  1.  D EN^XUTMDEVQ("RPT^SCRPI01","IEMM Error Listing",.ZTSAVE)
  1.  D HOME^%ZIS
  1. ENQ Q
  1.  ;
  1. RPT ; Build report, then call print
  1.  K ^TMP("SCRPI ERR",$J)
  1.  D BLD
  1.  D PRINT^SCRPI01A
  1.  Q
  1.  ;
  1. EXIT ;
  1.  K ^TMP("SCRPI ERR",$J)
  1.  Q
  1.  ;
  1. SELCT(S1,SCT) ;  Set selection criteria
  1.  ;   Input
  1.  ;       S1    - Previous selection method
  1.  ;       SCT   - first or second selection method
  1.  ;
  1.  ;   Returns
  1.  ;       CLN - Clinic
  1.  ;       ERR - Error Code
  1.  ;       PAT - Patient
  1.  ;       DSS - Stop Code
  1.  ;
  1.  ;   Variables
  1.  ;       SCTEXT - Set up display list
  1.  ;
  1.  N X,CNT,SCTEXT
  1.  S X="SM^"
  1.  F CNT=1:1 S SCTEXT=$P($T(OPTIONS+CNT),";;",2) Q:SCTEXT="$$END"  D
  1.  . Q:S1[$P(SCTEXT,":")
  1.  . S X=X_SCTEXT
  1.  ;
  1.  S DIR(0)=X,DIR("A")="Set "_SCT_" Selection Criteria"
  1.  S DIR("?")="Pick a selection criteria from those listed below."
  1.  S DIR("??")="^D HLP^SCRPI01"
  1.  D ^DIR K DIR
  1.  Q $S(Y["C":"CLN",Y["P":"PAT",Y["E":"ERR",Y["D":"DSS",1:"")
  1.  ;
  1. CLN ; Clinic selection o/m/a
  1.  W !!,"Clinic Selection"
  1.  S VAUTNI=2
  1.  D CLINIC^VAUTOMA
  1.  W !
  1.  S SDOK=Y
  1.  Q
  1.  ;
  1. PAT ; Patient selection o/m/a
  1.  W !!,"Patient Selection"
  1.  S VAUTNI=2
  1.  D PATIENT^VAUTOMA
  1.  W !
  1.  S SDOK=Y
  1.  Q
  1.  ;
  1. ERR ; Error selection o/m/a
  1.  W !!,"Transmission Error Selection"
  1.  S DIC="^SD(409.76,",VAUTSTR="Error",VAUTVB="VAUER",VAUTNI=2
  1.  D FIRST^VAUTOMA
  1.  W !
  1.  S SDOK=Y
  1.  Q
  1.  ;
  1. DSS ; Clinic Stop code selection o/m/a
  1.  W !!,"Clinic Stop Code Selection"
  1.  S DIC="^DIC(40.7,",VAUTSTR="Stop Code",VAUTVB="VAUDS",VAUTNI=2
  1.  D FIRST^VAUTOMA
  1.  W !
  1.  S SDOK=1
  1.  Q
  1.  ;
  1. BLD ; Search for incomplete encounters and build TMP global
  1.  ;    Variables
  1.  ;        SDEND  - End date of date range
  1.  ;        SDOE   - Encounter IEN
  1.  ;        SDOEDT - Encounter date
  1.  ;        SDCNT  - Entry count
  1.  ;
  1.  N SDEND,SDOE,SDOEDT,SDCNT
  1.  ;
  1.  S SDOEDT=$P(SDDT,U)-.1,SDEND=$P(SDDT,U,2)+.9,SDCNT=0
  1.  F  S SDOEDT=$O(^SD(409.75,"AEDT",SDOEDT)) Q:'SDOEDT!(SDOEDT>SDEND)  D
  1.  . S SDXMT=0 F  S SDXMT=$O(^SD(409.75,"AEDT",SDOEDT,SDXMT)) Q:'SDXMT  D
  1.  .. S SDXER=0 F  S SDXER=$O(^SD(409.75,"AEDT",SDOEDT,SDXMT,SDXER)) Q:'SDXER  D BLD1(SDXER,SDXMT)
  1.  Q
  1.  ;
  1. BLD1(SDE,SDX) ;  If error passes checks, add to sorted TMP global
  1.  ;   Input
  1.  ;       SDE  - Pointer to #409.75
  1.  ;       SDX  - Pointer to #409.73
  1.  ;
  1.  ;   Variables
  1.  ;       SCEN   - Temporary array for encounter information
  1.  ;       SDDEL  - Deleted Encounter Marker "*"
  1.  ;       SDRSLT - -1:error, 1:Deleted Encounter, 0:Not deleted
  1.  ;       SDIV   - Division IEN
  1.  ;       SDCDE  - Stop code
  1.  ;
  1.  ;   Output
  1.  ;       ^TMP("SCRPI ERR",$J,Division Name,Clinic Name,Patient Name,Encounter Date,Error code IEN,0)=DFN^#409.73 Pointer^Deleted Flag
  1.  ;
  1.  N SCEN,SDDEL,SDRSLT,SDIV,SDCDE
  1.  ;
  1.  I '$D(ZTQUEUED) S SDCNT=SDCNT+1 W:(SDCNT#10)=0 "."
  1.  ;
  1.  S SDRSLT=$$OPENC^SCUTIE1(SDXMT,"SCEN")
  1.  Q:SDRSLT<0
  1.  S:SDRSLT SDDEL="*"
  1.  ;
  1.  I SDRSLT D
  1.  . S SDIV=$P(^SD(409.74,SCEN("DELIEN"),1),U,11)
  1.  . S SDCDE=$P(^SD(409.74,SCEN("DELIEN"),1),U,3)
  1.  E  D
  1.  . S SDIV=$P(^SCE(SCEN("SDOIEN"),0),U,11)
  1.  . S SDCDE=$P(^SCE(SCEN("SDOIEN"),0),U,3)
  1.  ;
  1.  I $S(VAUTD:0,$D(VAUTD(SDIV)):0,1:1) Q
  1.  ;
  1.  I SDSEL1="CLN",$S(VAUTC:0,$D(VAUTC(SCEN("CLINIC"))):0,1:1) Q
  1.  I SDSEL1="PAT",$S(VAUTN:0,$D(VAUTN(SCEN("DFN"))):0,1:1) Q
  1.  I SDSEL1="ERR" Q:'$D(^SD(409.75,SDE,0))  I $S(VAUER:0,$D(VAUER($P(^SD(409.75,SDE,0),U,2))):0,1:1) Q  ; SD*5.3*338
  1.  I SDSEL1="DSS",$S(VAUDS:0,$D(VAUDS(SDCDE)):0,1:1) Q
  1.  ;
  1.  I SDSEL2="CLN",$S(VAUTC:0,$D(VAUTC(SCEN("CLINIC"))):0,1:1) Q
  1.  I SDSEL2="PAT",$S(VAUTN:0,$D(VAUTN(SCEN("DFN"))):0,1:1) Q
  1.  I SDSEL2="ERR" Q:'$D(^SD(409.75,SDE,0))  I $S(VAUER:0,$D(VAUER($P(^SD(409.75,SDE,0),U,2))):0,1:1) Q  ; SD*5.3*338
  1.  I SDSEL2="DSS",$S(VAUDS:0,$D(VAUDS(SDCDE)):0,1:1) Q
  1.  ;
  1.  S ^TMP("SCRPI ERR",$J,$P(^DG(40.8,SDIV,0),U),$P(^SC(SCEN("CLINIC"),0),U),$P(^DPT(SCEN("DFN"),0),U),SCEN("ENCOUNTER"),SDE,0)=SCEN("DFN")_U_SDX_U_$G(SDDEL)
  1.  Q
  1.  ;
  1. SELMTHD(SEL) ;  Returns 'external' version of selection method
  1.  Q $S(SEL="CLN":"Clinic",SEL="PAT":"Patient",SEL="ERR":"Error Code",SEL="DSS":"Clinic Stop Code")
  1.  ;
  1. HLP ;  '??' help for the selection criteria.
  1.  ;
  1.  W !?2,"You may select any two of the following selection criteria, one at a time, for"
  1.  W !?2,"your report.  You will be asked for one/many/all selections for each criteria"
  1.  W !?2,"selected."
  1.  W !
  1.  W !?2,"Selection criteria are not sort criteria.  The sort criteria are  Division,"
  1.  W !?2,"Clinic, Patient, and Encounter.  Selection criteria limit what will be"
  1.  W !?2,"printed in the report."
  1.  Q
  1.  ;
  1. MSG2 ;
  1.  W !!!
  1.  W "The following are selection criteria which are used to specify a group of or"
  1.  W !,"particular clinic, patient, error code or clinic stop code to be printed."
  1.  W !,"You are asked to pick two, one at a time.  Type '??' for more details."
  1.  Q
  1.  ;
  1. MSG ;
  1.  ;;  This report requires 132 columns to print and will default to 
  1.  ;;  QUEUING required.  If you print this report to your terminal,
  1.  ;;  answer 'NO' to the 'Do you still want your output queued' prompt.
  1.  ;;$$END
  1.  ;
  1. OPTIONS ;  Selection methods
  1.  ;;C:Clinic;
  1.  ;;P:Patient;
  1.  ;;E:Error Code;
  1.  ;;D:Clinic Stop Code;
  1.  ;;$$END
  1.  ;