SROALMN.m

SROALMN ;BIR/ADM - LIST OF 1-LINER CASES WITH MISSING INFO ;05/04/07

 ;;3.0; Surgery ;**153,160**;24 Jun 93;Build 7

 S (GRAND,SRNEW,SRSOUT,TOT)=0,(SRHDR,SRPAGE)=1,SRTITLE="1-LINER CASES MISSING INFORMATION" K ^TMP("SRA",$J)

 I SRFLG,SRASP S SRSPEC=$P(^SRO(137.45,SRASP,0),"^")

 F  S SRSD=$O(^SRF("AC",SRSD)) Q:'SRSD!(SRSD>SRED)!SRSOUT  S SRTN=0 F  S SRTN=$O(^SRF("AC",SRSD,SRTN)) Q:'SRTN!SRSOUT  I $D(^SRF(SRTN,0)),$$MANDIV^SROUTL0(SRINSTP,SRTN) D UTL

 I SRSP S SRSS="" F  S SRSS=$O(^TMP("SRA",$J,SRSS)) Q:SRSS=""  D SRSD Q:SRSOUT  D:TOT TOT

 I 'SRSP S SRNEW=1,(SRSD,TOT)=0 F  S SRSD=$O(^TMP("SRA",$J,SRSD)) Q:'SRSD!SRSOUT  S SRTN=0 F  S SRTN=$O(^TMP("SRA",$J,SRSD,SRTN)) Q:'SRTN  S SRA=^(SRTN) D CASE Q:SRSOUT

 Q:SRSOUT  I SRSP,'SRFLG,GRAND D GRAND

 I SRFLG,'GRAND S SRSS=SRSPEC D HDR,GRAND

 I SRSP,'SRFLG,'GRAND S SRSS="" D HDR,GRAND

 I 'SRSP,'GRAND S SRSS="" D HDR,GRAND

 I 'SRSP,GRAND S SRSS="" D GRAND

 Q

UTL ; set up TMP global

 I '$P($G(^SRF(SRTN,.2)),"^",3)&'$P($G(^SRF(SRTN,.2)),"^",12) Q

 I $P($G(^SRF(SRTN,30)),"^") Q

 S SRA=$G(^SRF(SRTN,"RA")) I $P(SRA,"^",2)="N",$P(SRA,"^",6)="Y" Q

 I SRFLG,$P(^SRF(SRTN,0),"^",4)'=SRASP Q

 I SRSP S SRSS=$P(^SRF(SRTN,0),"^",4),SRSS=$S(SRSS:$P(^SRO(137.45,SRSS,0),"^"),1:"SPECIALTY NOT ENTERED"),^TMP("SRA",$J,SRSS,SRSD,SRTN)=SRA Q

 S ^TMP("SRA",$J,SRSD,SRTN)=SRA

 Q

SRSD S SRNEW=1,(SRSD,TOT)=0 F  S SRSD=$O(^TMP("SRA",$J,SRSS,SRSD)) Q:'SRSD!SRSOUT  S SRTN=0 F  S SRTN=$O(^TMP("SRA",$J,SRSS,SRSD,SRTN)) Q:'SRTN  S SRA=^(SRTN) D CASE Q:SRSOUT

 Q

CASE I $P(SRA,"^",2)="N",$P(SRA,"^",6)="N" S SRATYPE="EXCLUDED"

 S:$P(SRA,"^",2)="C" SRATYPE="CARDIAC" S:$P(SRA,"^",2)="" SRATYPE="NON-ASSESSED" D LNR

 S SRFLD="" I $O(SRX(SRFLD))'="" S TOT=TOT+1,GRAND=GRAND+1 D PRINT Q

 I '$P($G(^SRO(136,SRTN,10)),"^")!('$P($G(^SRO(136,SRTN,0)),"^",2))!('$P($G(^SRO(136,SRTN,0)),"^",3)) D PRINT

 Q

LNR ; check for missing 1-liner information

 K SRX,DA,DIC,DIQ,DR,SRY S DIC="^SRF(",DA=SRTN,DIQ="SRY",DIQ(0)="I"

 I SRATYPE'="EXCLUDED" S DR=".011;.03;.04;.035;.166;1.09;1.13"

 I SRATYPE="EXCLUDED" S DR=".035;.03;102"

 D EN^DIQ1 D ^SROAUTL2 K DA,DIC,DIQ,DR,SRY,SRZ

 D TECH^SROPRIN I SRTECH="NOT ENTERED" S SRX("ANESTHESIA TECHNIQUE")="Anesthesia Technique"

 Q

PRINT ; print assessments

 K SRCPTT S SRCPTT="NOT ENTERED"

 I $Y+5>IOSL!SRNEW D PAGE I SRSOUT Q

 S SRA(0)=^SRF(SRTN,0),DFN=$P(SRA(0),"^") N I D DEM^VADPT S SRANM=VADM(1),SRASSN=VA("PID") K VADM

 I $L(SRANM)>19 S SRANM=$P(SRANM,",")_","_$E($P(SRANM,",",2))_"."

 S SROPER=$P(^SRF(SRTN,"OP"),"^") I $O(^SRF(SRTN,13,0)) S SROTHER=0 F I=0:0 S SROTHER=$O(^SRF(SRTN,13,SROTHER)) Q:'SROTHER  D OTHER

 K SROPS,MM,MMM S:$L(SROPER)<63 SROPS(1)=SROPER I $L(SROPER)>62 S SROPER=SROPER_"  " F M=1:1 D LOOP Q:MMM=""

 S X=$P(SRA,"^"),SRSTATUS=$S(X="T":"TRANSMITTED",X="C":"COMPLETE",X="I":"INCOMPLETE",1:"NO ASSESSMENT"),Y=SRSD D D^DIQ S SRDT=$P(Y,"@")

 I $Y+5>IOSL D PAGE I SRSOUT Q

 W !,SRTN,?18,SRANM_" "_VA("PID"),?53,SRATYPE,?67,SRSTATUS,!,SRDT F I=1:1 Q:'$D(SROPS(I))  W ?18,SROPS(I),!

 N I,SRPROC,SRL S SRL=100 D CPTS^SROAUTL0 W ?18,"CPT Codes: "

 F I=1:1 Q:'$D(SRPROC(I))  W:I=1 ?29,SRPROC(I) W:I'=1 !,?29,SRPROC(I)

 S CNT=1 W !,?5,"Missing information:"

 I '$P($G(^SRO(136,SRTN,10)),"^")!('$P($G(^SRO(136,SRTN,0)),"^",2))!('$P($G(^SRO(136,SRTN,0)),"^",3)) W !,$J(CNT_". ",8),"The final coding for Procedure and Diagnosis is not complete." S CNT=CNT+1

 F  S SRFLD=$O(SRX(SRFLD)) Q:SRFLD=""  D:$Y+5>IOSL PAGE Q:SRSOUT  W !,$J(CNT_". ",8),SRX(SRFLD) S CNT=CNT+1

 I 'SRSOUT W ! F LINE=1:1:80 W "-"

 Q

OTHER ; other operations

 S SRLONG=1 I $L(SROPER)+$L($P(^SRF(SRTN,13,SROTHER,0),"^"))>125 S SRLONG=0,SROTHER=999,SROPERS=" ..."

 I SRLONG S SROPERS=$P(^SRF(SRTN,13,SROTHER,0),"^")

 S SROPER=SROPER_$S(SROPERS'=" ...":", "_SROPERS,1:SROPERS)

 Q

LOOP ; break procedures

 S SROPS(M)="" F LOOP=1:1 S MM=$P(SROPER," "),MMM=$P(SROPER," ",2,200) Q:MMM=""  Q:$L(SROPS(M))+$L(MM)'<63  S SROPS(M)=SROPS(M)_MM_" ",SROPER=MMM

 Q

PAGE I $E(IOST)="P"!SRHDR G HDR

 W !!,"Press <RET> to continue, or '^' to quit  " R X:DTIME I '$T!(X["^") S SRSOUT=1 Q

 I X["?" W !!,"If you want to continue the listing, press the 'Enter' key.",!,"Type '^' to return to the menu." G PAGE

HDR ; print heading

 W @IOF,!,?(80-$L(SRTITLE)\2),SRTITLE,?70,$J("PAGE "_SRPAGE,9) W:$E(IOST)="P" !,?(80-$L(SRINST)\2),SRINST W !,?(80-$L(SRFRTO)\2),SRFRTO

 W:$E(IOST)="P" !,?(80-$L(SRPRINT)\2),SRPRINT I SRSP,SRSS'="" W !!,"** "_SRSS

 W !!,"CASE #",?18,"PATIENT",?53,"TYPE",?67,"STATUS",!,"OP DATE",?18,"OPERATION(S)",! F LINE=1:1:80 W "="

 S SRHDR=0,SRNEW=0,SRPAGE=SRPAGE+1

 Q

TOT W !!,"TOTAL FOR "_SRSS_": ",TOT

 Q

GRAND I 'SRSP W !!,"TOTAL: ",GRAND Q

 I SRSP,'SRFLG W !!,"TOTAL FOR ALL SPECIALTIES: ",GRAND Q

 I SRSP,SRFLG S SRSS=SRSPEC D TOT

 Q

SROALMN   ;BIR/ADM - LIST OF 1-LINER CASES WITH MISSING INFO ;05/04/07

 +1       ;;3.0; Surgery ;**153,160**;24 Jun 93;Build 7

 +2        SET (GRAND,SRNEW,SRSOUT,TOT)=0

           SET (SRHDR,SRPAGE)=1

           SET SRTITLE="1-LINER CASES MISSING INFORMATION"

           KILL ^TMP("SRA",$JOB)

 +3        IF SRFLG

               IF SRASP

                   SET SRSPEC=$PIECE(^SRO(137.45,SRASP,0),"^")

 +4        FOR 

               SET SRSD=$ORDER(^SRF("AC",SRSD))

               IF 'SRSD!(SRSD>SRED)!SRSOUT

                   QUIT 

               SET SRTN=0

               FOR 

                   SET SRTN=$ORDER(^SRF("AC",SRSD,SRTN))

                   IF 'SRTN!SRSOUT

                       QUIT 

                   IF $DATA(^SRF(SRTN,0))

                       IF $$MANDIV^SROUTL0(SRINSTP,SRTN)

                           DO UTL

 +5        IF SRSP

               SET SRSS=""

               FOR 

                   SET SRSS=$ORDER(^TMP("SRA",$JOB,SRSS))

                   IF SRSS=""

                       QUIT 

                   DO SRSD

                   IF SRSOUT

                       QUIT 

                   IF TOT

                       DO TOT

 +6        IF 'SRSP

               SET SRNEW=1

               SET (SRSD,TOT)=0

               FOR 

                   SET SRSD=$ORDER(^TMP("SRA",$JOB,SRSD))

                   IF 'SRSD!SRSOUT

                       QUIT 

                   SET SRTN=0

                   FOR 

                       SET SRTN=$ORDER(^TMP("SRA",$JOB,SRSD,SRTN))

                       IF 'SRTN

                           QUIT 

                       SET SRA=^(SRTN)

                       DO CASE

                       IF SRSOUT

                           QUIT 

 +7        IF SRSOUT

               QUIT 

           IF SRSP

               IF 'SRFLG

                   IF GRAND

                       DO GRAND

 +8        IF SRFLG

               IF 'GRAND

                   SET SRSS=SRSPEC

                   DO HDR

                   DO GRAND

 +9        IF SRSP

               IF 'SRFLG

                   IF 'GRAND

                       SET SRSS=""

                       DO HDR

                       DO GRAND

 +10       IF 'SRSP

               IF 'GRAND

                   SET SRSS=""

                   DO HDR

                   DO GRAND

 +11       IF 'SRSP

               IF GRAND

                   SET SRSS=""

                   DO GRAND

 +12       QUIT 

UTL       ; set up TMP global

 +1        IF '$PIECE($GET(^SRF(SRTN,.2)),"^",3)&'$PIECE($GET(^SRF(SRTN,.2)),"^",12)

               QUIT 

 +2        IF $PIECE($GET(^SRF(SRTN,30)),"^")

               QUIT 

 +3        SET SRA=$GET(^SRF(SRTN,"RA"))

           IF $PIECE(SRA,"^",2)="N"

               IF $PIECE(SRA,"^",6)="Y"

                   QUIT 

 +4        IF SRFLG

               IF $PIECE(^SRF(SRTN,0),"^",4)'=SRASP

                   QUIT 

 +5        IF SRSP

               SET SRSS=$PIECE(^SRF(SRTN,0),"^",4)

               SET SRSS=$SELECT(SRSS:$PIECE(^SRO(137.45,SRSS,0),"^"),1:"SPECIALTY NOT ENTERED")

               SET ^TMP("SRA",$JOB,SRSS,SRSD,SRTN)=SRA

               QUIT 

 +6        SET ^TMP("SRA",$JOB,SRSD,SRTN)=SRA

 +7        QUIT 

SRSD       SET SRNEW=1

           SET (SRSD,TOT)=0

           FOR 

               SET SRSD=$ORDER(^TMP("SRA",$JOB,SRSS,SRSD))

               IF 'SRSD!SRSOUT

                   QUIT 

               SET SRTN=0

               FOR 

                   SET SRTN=$ORDER(^TMP("SRA",$JOB,SRSS,SRSD,SRTN))

                   IF 'SRTN

                       QUIT 

                   SET SRA=^(SRTN)

                   DO CASE

                   IF SRSOUT

                       QUIT 

 +1        QUIT 

CASE       IF $PIECE(SRA,"^",2)="N"

               IF $PIECE(SRA,"^",6)="N"

                   SET SRATYPE="EXCLUDED"

 +1        IF $PIECE(SRA,"^",2)="C"

               SET SRATYPE="CARDIAC"

           IF $PIECE(SRA,"^",2)=""

               SET SRATYPE="NON-ASSESSED"

           DO LNR

 +2        SET SRFLD=""

           IF $ORDER(SRX(SRFLD))'=""

               SET TOT=TOT+1

               SET GRAND=GRAND+1

               DO PRINT

               QUIT 

 +3        IF '$PIECE($GET(^SRO(136,SRTN,10)),"^")!('$PIECE($GET(^SRO(136,SRTN,0)),"^",2))!('$PIECE($GET(^SRO(136,SRTN,0)),"^",3))

               DO PRINT

 +4        QUIT 

LNR       ; check for missing 1-liner information

 +1        KILL SRX,DA,DIC,DIQ,DR,SRY

           SET DIC="^SRF("

           SET DA=SRTN

           SET DIQ="SRY"

           SET DIQ(0)="I"

 +2        IF SRATYPE'="EXCLUDED"

               SET DR=".011;.03;.04;.035;.166;1.09;1.13"

 +3        IF SRATYPE="EXCLUDED"

               SET DR=".035;.03;102"

 +4        DO EN^DIQ1

           DO ^SROAUTL2

           KILL DA,DIC,DIQ,DR,SRY,SRZ

 +5        DO TECH^SROPRIN

           IF SRTECH="NOT ENTERED"

               SET SRX("ANESTHESIA TECHNIQUE")="Anesthesia Technique"

 +6        QUIT 

PRINT     ; print assessments

 +1        KILL SRCPTT

           SET SRCPTT="NOT ENTERED"

 +2        IF $Y+5>IOSL!SRNEW

               DO PAGE

               IF SRSOUT

                   QUIT 

 +3        SET SRA(0)=^SRF(SRTN,0)

           SET DFN=$PIECE(SRA(0),"^")

           NEW I

           DO DEM^VADPT

           SET SRANM=VADM(1)

           SET SRASSN=VA("PID")

           KILL VADM

 +4        IF $LENGTH(SRANM)>19

               SET SRANM=$PIECE(SRANM,",")_","_$EXTRACT($PIECE(SRANM,",",2))_"."

 +5        SET SROPER=$PIECE(^SRF(SRTN,"OP"),"^")

           IF $ORDER(^SRF(SRTN,13,0))

               SET SROTHER=0

               FOR I=0:0

                   SET SROTHER=$ORDER(^SRF(SRTN,13,SROTHER))

                   IF 'SROTHER

                       QUIT 

                   DO OTHER

 +6        KILL SROPS,MM,MMM

           IF $LENGTH(SROPER)<63

               SET SROPS(1)=SROPER

           IF $LENGTH(SROPER)>62

               SET SROPER=SROPER_"  "

               FOR M=1:1

                   DO LOOP

                   IF MMM=""

                       QUIT 

 +7        SET X=$PIECE(SRA,"^")

           SET SRSTATUS=$SELECT(X="T":"TRANSMITTED",X="C":"COMPLETE",X="I":"INCOMPLETE",1:"NO ASSESSMENT")

           SET Y=SRSD

           DO D^DIQ

           SET SRDT=$PIECE(Y,"@")

 +8        IF $Y+5>IOSL

               DO PAGE

               IF SRSOUT

                   QUIT 

 +9        WRITE !,SRTN,?18,SRANM_" "_VA("PID"),?53,SRATYPE,?67,SRSTATUS,!,SRDT

           FOR I=1:1

               IF '$DATA(SROPS(I))

                   QUIT 

               WRITE ?18,SROPS(I),!

 +10       NEW I,SRPROC,SRL

           SET SRL=100

           DO CPTS^SROAUTL0

           WRITE ?18,"CPT Codes: "

 +11       FOR I=1:1

               IF '$DATA(SRPROC(I))

                   QUIT 

               IF I=1

                   WRITE ?29,SRPROC(I)

               IF I'=1

                   WRITE !,?29,SRPROC(I)

 +12       SET CNT=1

           WRITE !,?5,"Missing information:"

 +13       IF '$PIECE($GET(^SRO(136,SRTN,10)),"^")!('$PIECE($GET(^SRO(136,SRTN,0)),"^",2))!('$PIECE($GET(^SRO(136,SRTN,0)),"^",3))

               WRITE !,$JUSTIFY(CNT_". ",8),"The final coding for Procedure and Diagnosis is not complete."

               SET CNT=CNT+1

 +14       FOR 

               SET SRFLD=$ORDER(SRX(SRFLD))

               IF SRFLD=""

                   QUIT 

               IF $Y+5>IOSL

                   DO PAGE

               IF SRSOUT

                   QUIT 

               WRITE !,$JUSTIFY(CNT_". ",8),SRX(SRFLD)

               SET CNT=CNT+1

 +15       IF 'SRSOUT

               WRITE !

               FOR LINE=1:1:80

                   WRITE "-"

 +16       QUIT 

OTHER     ; other operations

 +1        SET SRLONG=1

           IF $LENGTH(SROPER)+$LENGTH($PIECE(^SRF(SRTN,13,SROTHER,0),"^"))>125

               SET SRLONG=0

               SET SROTHER=999

               SET SROPERS=" ..."

 +2        IF SRLONG

               SET SROPERS=$PIECE(^SRF(SRTN,13,SROTHER,0),"^")

 +3        SET SROPER=SROPER_$SELECT(SROPERS'=" ...":", "_SROPERS,1:SROPERS)

 +4        QUIT 

LOOP      ; break procedures

 +1        SET SROPS(M)=""

           FOR LOOP=1:1

               SET MM=$PIECE(SROPER," ")

               SET MMM=$PIECE(SROPER," ",2,200)

               IF MMM=""

                   QUIT 

               IF $LENGTH(SROPS(M))+$LENGTH(MM)'<63

                   QUIT 

               SET SROPS(M)=SROPS(M)_MM_" "

               SET SROPER=MMM

 +2        QUIT 

PAGE       IF $EXTRACT(IOST)="P"!SRHDR

               GOTO HDR

 +1        WRITE !!,"Press <RET> to continue, or '^' to quit  "

           READ X:DTIME

           IF '$TEST!(X["^")

               SET SRSOUT=1

               QUIT 

 +2        IF X["?"

               WRITE !!,"If you want to continue the listing, press the 'Enter' key.",!,"Type '^' to return to the menu."

               GOTO PAGE

HDR       ; print heading

 +1        WRITE @IOF,!,?(80-$LENGTH(SRTITLE)\2),SRTITLE,?70,$JUSTIFY("PAGE "_SRPAGE,9)

           IF $EXTRACT(IOST)="P"

               WRITE !,?(80-$LENGTH(SRINST)\2),SRINST

           WRITE !,?(80-$LENGTH(SRFRTO)\2),SRFRTO

 +2        IF $EXTRACT(IOST)="P"

               WRITE !,?(80-$LENGTH(SRPRINT)\2),SRPRINT

           IF SRSP

               IF SRSS'=""

                   WRITE !!,"** "_SRSS

 +3        WRITE !!,"CASE #",?18,"PATIENT",?53,"TYPE",?67,"STATUS",!,"OP DATE",?18,"OPERATION(S)",!

           FOR LINE=1:1:80

               WRITE "="

 +4        SET SRHDR=0

           SET SRNEW=0

           SET SRPAGE=SRPAGE+1

 +5        QUIT 

TOT        WRITE !!,"TOTAL FOR "_SRSS_": ",TOT

 +1        QUIT 

GRAND      IF 'SRSP

               WRITE !!,"TOTAL: ",GRAND

               QUIT 

 +1        IF SRSP

               IF 'SRFLG

                   WRITE !!,"TOTAL FOR ALL SPECIALTIES: ",GRAND

                   QUIT 

 +2        IF SRSP

               IF SRFLG

                   SET SRSS=SRSPEC

                   DO TOT

 +3        QUIT