Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: TIUALSET

TIUALSET.m

Go to the documentation of this file. 
  1. TIUALSET ;SLC/AJB - TIU Alerts ; Mar 17, 2003
  1.  ;;1.0;TEXT INTEGRATION UTILITIES;**158**;Jun 20, 1997
  1.  ;
  1.  Q
  1. DETDISP ; detailed display
  1.  N D0,DIROUT,RSTRCTD,TIUDA,TIUD,TIUDATA,TIUGDATA,TIUSEL,TIUI,TIUQUIT,Y
  1.  D FULL^VALM1
  1.  I TIU("CNT")=0 W !,"No documents to select." H 3 Q
  1.  S TIUSEL=$P(XQORNOD(0),"=",2)
  1.  I TIUSEL="" D  Q:TIUSEL=U!($D(DIRUT))
  1.  . N DIR,X,Y
  1.  . S DIR("A")="Select Document: (1-"_VALMLST_") "
  1.  . S DIR(0)="NA^1:"_VALMLST
  1.  . D ^DIR S TIUSEL=Y
  1.  I $A($E(TIUSEL,$L(TIUSEL)))<48!($A($E(TIUSEL,$L(TIUSEL)))>57) S TIUSEL=$E(TIUSEL,1,$L(TIUSEL)-1)
  1.  F X=1:1  Q:$P(TIUSEL,",",X)=""  S TIUC($P(TIUSEL,",",X))=$O(@VALMAR@("IDX",$P(TIUSEL,",",X),""))
  1.  S TIUDA=TIUC(TIUSEL)
  1.  D
  1.  . N TIUVIEW
  1.  . D CLEAR^VALM1
  1.  . S TIUVIEW=$$CANDO^TIULP(TIUDA,"VIEW")
  1.  . I +TIUVIEW'>0 D  Q
  1.  . . W !!,$C(7),$P(TIUVIEW,U,2),!
  1.  . . I $$READ^TIUU("EA","RETURN to continue...") ; pause
  1.  . S RSTRCTD=$$DOCRES^TIULRR(TIUDA)
  1.  . I RSTRCTD D  Q
  1.  . . W !!,$C(7),"Ok, no harm done...",!
  1.  . . I $$READ^TIUU("EA","RETURN to continue...") ; pause
  1.  . D EN^TIUAUDIT
  1.  . I +$G(TIUQUIT) D FIXLSTNW^TIULM Q
  1.  K VALMY S VALMBCK="R"
  1.  Q
  1. UPDATE ; update LM display for edited documents
  1.  ;
  1.  N TIUAS,TIUDISP
  1.  S TIUAS="",TIUAS=$O(^TIU(8925.7,"AE",TIUDA,TIU("P"),TIUAS))
  1.  S TIUDISP=@VALMAR@(TIUSEL,0)
  1.  S TIUDISP("REFDT")=$$FMTDT^TIUAL1(+^TIU(8925,TIUDA,13))
  1.  S TIUDISP("S")=$$GET1^DIQ(8925,TIUDA,.05)
  1.  S TIUDISP("A/D")=$$GET1^DIQ(8925,TIUDA,1202)
  1.  S TIUDISP("EC")=$$GET1^DIQ(8925,TIUDA,1208)
  1.  S TIUDISP("ATT")=$$GET1^DIQ(8925,TIUDA,1209)
  1.  S TIUDISP("ADS")=$$GET1^DIQ(8925.7,TIUAS,.03)
  1.  S TIUDISP=$$SETSTR^VALM1(TIUDISP("REFDT"),TIUDISP,60,68)
  1.  S TIUDISP=$$SETSTR^VALM1($$LOW^XLFSTR(TIUDISP("S")),TIUDISP,70,80)
  1.  S TIUDISP=$$SETSTR^VALM1(TIUSEL,TIUDISP,81,86)
  1.  S TIUDISP=$$SETSTR^VALM1($E(TIUDISP("A/D"),1,17),TIUDISP,88,105)
  1.  S TIUDISP=$$SETSTR^VALM1($E($G(TIUDISP("EC")),1,17),TIUDISP,107,124)
  1.  S TIUDISP=$$SETSTR^VALM1($E($G(TIUDISP("ATT")),1,17),TIUDISP,126,143)
  1.  S TIUDISP=$$SETSTR^VALM1($E($G(TIUDISP("ADS")),1,15),TIUDISP,145,160)
  1.  D SET^VALM10(TIUSEL,TIUDISP,TIUDA)
  1.  D RE^VALM4
  1.  Q
  1. SETUP ; user required input for search parameters
  1.  N TIUCAT,TIUCNT,TIUPERS,TIUTMP,TIUSTAT
  1.  D   I TIUSTAT=-1 S TIU("QUIT")=1 Q
  1.  . S TIUSTAT=$$SELSTAT^TIUAL1(.TIUSTAT,"A","UNSIGNED","TIU STATUS MENU")
  1.  D   I TIUCAT=-1 S TIU("QUIT")=1 Q
  1.  . S TIUCAT=$$SELSTAT^TIUAL1(.TIUCAT,"A","AUTHOR","TIU ALERTS SEARCH MENU")
  1.  D   I TIUPERS=-1 S TIU("QUIT")=1 Q
  1.  . N DIC
  1.  . S DIC="^VA(200,",DIC(0)="AEMQ"
  1.  . S DIC("A")="Select NEW PERSON: "
  1.  . D ^DIC S TIUPERS=+Y
  1.  . I $$GET1^DIQ(200,+Y,7,"I")!$$GET1^DIQ(200,+Y,9.2,"I") D
  1.  . . W !
  1.  . . W:$$GET1^DIQ(200,+Y,7,"I") !,$$GET1^DIQ(200,+Y,.01)," is INACTIVE (DIUSER'd)"
  1.  . . W:$$GET1^DIQ(200,+Y,9.2,"I") !,$$GET1^DIQ(200,+Y,.01)," has a termination date of ",$$GET1^DIQ(200,+Y,9.2)
  1.  . . W !
  1.  D   I '$G(TIUTMP("DT1"))!('$G(TIUTMP("DT2"))) S TIU("QUIT")=1 Q   ; select date range
  1.  . F TIUCNT=1:1:2 D
  1.  . . N %DT S %DT="AET"
  1.  . . S %DT("A")=$S(TIUCNT=1:" Start Reference Date [Time]: ",TIUCNT=2:"Ending Reference Date [Time]: ")
  1.  . . S %DT("B")=$S(TIUCNT=1:"T-7",TIUCNT=2:$P($$HTE^XLFDT($H),"@"))
  1.  . . D ^%DT
  1.  . . I Y=-1 S TIUCNT=2 Q
  1.  . . I TIUCNT=1 S TIUTMP("DT1")=+Y
  1.  . . I TIUTMP("DT1")>+Y S TIUTMP("DT3")=TIUTMP("DT1"),TIUTMP("DT1")=+Y,Y=TIUTMP("DT3")
  1.  . . I TIUCNT=2,Y["." S TIUTMP("DT2")=+Y
  1.  . . E  I TIUCNT=2 S TIUTMP("DT2")=+Y_".24"
  1.  K TIU
  1.  F TIUCNT=1:1:TIUCAT D
  1.  . S TIUCAT=$S(+TIUCAT(TIUCNT)=1:"CA",+TIUCAT(TIUCNT)=2:"CA",+TIUCAT(TIUCNT)=3:"CS",+TIUCAT(TIUCNT)=4:"CS",+TIUCAT(TIUCNT)=5:"AE") S:'$D(TIU("C",TIUCAT)) TIU("C",TIUCAT)=""
  1.  . S TIU("C",TIUCAT)=TIU("C",TIUCAT)_U_$S(+TIUCAT(TIUCNT)=1:"Author",+TIUCAT(TIUCNT)=2:"Dictator",+TIUCAT(TIUCNT)=3:"Expected Cosigner",+TIUCAT(TIUCNT)=4:"Attending Physician",+TIUCAT(TIUCNT)=5:"Add'l Signer")
  1.  S TIU("P")=+TIUPERS
  1.  S TIU("S")=TIUSTAT
  1.  F TIUCNT=1:1:TIUSTAT S TIU("S",TIUCNT)=TIUSTAT(TIUCNT) S $P(TIU("S",TIUCNT),U)=$S(+TIU("S",TIUCNT)=10:14,+TIU("S",TIUCNT)=11:15,1:+TIU("S",TIUCNT))
  1.  S TIU("D",1)=TIUTMP("DT1")
  1.  S TIU("D",2)=TIUTMP("DT2")
  1.  Q