Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: TIUFLD1

TIUFLD1.m

Go to the documentation of this file. 
  1. TIUFLD1 ; SLC/MAM - Lib; Template D Related; SETBOIL(FIELDA,LASTLIN), EDBOIL(FILEDA), DEDBOIL(FILEDA), DSETSHAR(FILEDA)  ;4/6/95  11:02
  1.  ;;1.0;TEXT INTEGRATION UTILITIES;;Jun 20, 1997
  1.  ;
  1. SETBOIL(FILEDA,LASTLIN) ; Sets Boilerplate Text of FILEDA into
  1.  ;LM Array for Template D.
  1.  ; Kills LM Array from LASTLIN+1 to the end before setting boiltxt.
  1.  ; Requires FILEDA.
  1.  ; Requires LASTLIN = Last array line set, if setting array; = Last
  1.  ;line to keep before resetting the rest if resetting array.
  1.  ; Updates LASTLIN to Last array line set by this module.
  1.  N TIUFJ,TIUFI,LINENO
  1.  F TIUFJ=LASTLIN+1:1 Q:'$D(^TMP("TIUF3",$J,TIUFJ,0))  K ^TMP("TIUF3",$J,TIUFJ,0)
  1.  S LINENO=LASTLIN,TIUFI=0
  1.  F  S TIUFI=$O(^TIU(8925.1,+FILEDA,"DFLT",TIUFI)) Q:+TIUFI'>0  D
  1.  . S LINENO=LINENO+1,^TMP("TIUF3",$J,LINENO,0)=$G(^TIU(8925.1,+FILEDA,"DFLT",+TIUFI,0))
  1.  S LASTLIN=LINENO
  1. SETBX Q
  1.  ;
  1. DSETBOIL(FILEDA,VCNT3) ; Sets boilerplate Text for descendants of FILEDA.
  1.  ; Requires FILEDA, VCNT3=VALMCNT for TIUF3 when DSETBOIL is called.
  1.  ; Updates VCNT3.
  1.  N TIUFITEM,TIUI,LINENO,ITENDA,TENODE0,NAME
  1.  Q:'$G(FILEDA)
  1.  Q:$G(VCNT3)=""
  1.  D ITEMS^TIUFLT(FILEDA)
  1.  S TIUI=0,LINENO=VCNT3
  1.  F  S TIUI=$O(TIUFITEM(TIUI)) Q:'TIUI  D
  1.  . S ITENDA=$P(TIUFITEM(TIUI),U,2)
  1.  . S TENODE0=^TIU(8925.1,FILEDA,10,ITENDA,0),NAME=$P(^TIU(8925.1,+TENODE0,0),U)
  1.  . S LINENO=LINENO+1,^TMP("TIUF3",$J,LINENO,0)=NAME_":"
  1.  . D SETBOIL(+TENODE0,.LINENO)
  1.  . D DSETBOIL(+TENODE0,.LINENO)
  1.  . Q
  1. DSETX S VCNT3=LINENO
  1.  Q
  1.  ;
  1. EDBOIL(FILEDA,NODE0) ; Edit Boilerplate Text of FILEDA.
  1.  ; Requires FILEDA, NODE0 of FILEDA
  1.  D FULL^VALM1
  1.  N DIC,DWPK,DIWESUB
  1.  S DIC="^TIU(8925.1,"_FILEDA_",""DFLT"",",DWPK=1
  1.  S DIWESUB=$P(NODE0,U)
  1.  D EN^DIWE
  1. EDBOX Q
  1.  ;
  1. DEDBOIL(FILEDA) ; Edit Boilerplate Text for descendants of FILEDA.
  1.  N TIUI,IFILEDA,INODE0,TIUFITEM,ITENDA
  1.  G:'$O(^TIU(8925.1,FILEDA,10,0)) DEDBX
  1.  D ITEMS^TIUFLT(FILEDA)
  1.  S TIUI=0 K DUOUT
  1.  F  S TIUI=$O(TIUFITEM(TIUI)) Q:'TIUI  D  Q:$D(DTOUT)!$D(DUOUT)
  1.  . S ITENDA=$P(TIUFITEM(TIUI),U,2)
  1.  . S IFILEDA=+^TIU(8925.1,FILEDA,10,ITENDA,0),INODE0=^TIU(8925.1,IFILEDA,0)
  1.  . I $P(INODE0,U,10),'$$PERSOWNS^TIUFLF2(IFILEDA,DUZ) W !!," ",$P(INODE0,U),!,"is a Shared Component; Only an Owner can edit its Boilerplate Text.",!! D PAUSE^TIUFXHLX Q
  1.  . I $P(INODE0,U,10),TIUFTMPL'="A" W !!," ",$P(INODE0,U),!,"is a Shared Component; it can be edited only through the SORT option",!! D PAUSE^TIUFXHLX Q
  1.  . D EDBOIL(IFILEDA,INODE0) Q:$D(DTOUT)
  1.  . D DEDBOIL(IFILEDA)
  1.  . Q
  1. DEDBX Q
  1.  ;
  1. DSETSHAR(FILEDA) ;  Sets all descendants of FILEDA to SHARED
  1.  ; Requires FILEDA
  1.  N TIUI,IFILEDA,INODE0,DIE,X,Y,SHARED,DA,DR
  1.  S TIUI=0,DIE=8925.1,SHARED="YES"
  1.  F  S TIUI=$O(^TIU(8925.1,FILEDA,10,TIUI)) Q:'TIUI  D
  1.  . S IFILEDA=+^TIU(8925.1,FILEDA,10,TIUI,0)
  1.  . S INODE0=$G(^TIU(8925.1,IFILEDA,0))
  1.  . I INODE0="" W !!," File Entry "_FILEDA_" has Nonexistent item "_IFILEDA_"; See IRM",! D PAUSE^TIUFXHLX Q
  1.  . S DA=IFILEDA,DR=".1///^S X=SHARED" D ^DIE
  1.  . D DSETSHAR(IFILEDA)
  1.  Q
  1.  ;