Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: TIUPXAP1

TIUPXAP1.m

Go to the documentation of this file. 
  1. TIUPXAP1 ; SLC/JER - Interface w/PCE/Visit Tracking ;28-OCT-2003 16:45:37 [8/18/04 11:24am]
  1.  ;;1.0;TEXT INTEGRATION UTILITIES;**15,29,20,89,82,107,117,126,124,149,179,205**;Jun 20, 1997;Build 1
  1. QUE ; Use a RESOURCE to post visit tracking information in background
  1.  N ZTDTH,ZTIO,ZTSAVE,ZTSK,ZTRTN,ZTDESC
  1.  ; if there is already a visit, and no workload data quit
  1.  I +$P($G(TIUDPRM(0)),U,16),(+$P($G(^TIU(8925,$S(+$G(TIUDA):+$G(TIUDA),1:+$G(DA)),0)),U,11)=0),+$$WORKOK($S(+$G(TIUDA):+$G(TIUDA),1:+$G(DA))) D  Q:'$$BROKER^XWBLIB
  1.  . D DEFER($S(+$G(TIUDA):+$G(TIUDA),1:+$G(DA)))
  1.  I +$G(TIU("VISIT")),($D(CPT)'>9) Q
  1.  I +$P($G(^TIU(8925,$S(+$G(TIUDA):+$G(TIUDA),1:+$G(DA)),0)),U,3),($D(CPT)'>9) Q
  1.  S (ZTSAVE("TIU("),ZTSAVE("DFN"),ZTSAVE("TIUDA"),ZTSAVE("DA"))=""
  1.  S (ZTSAVE("DUZ("),ZTSAVE("ICD("),ZTSAVE("CPT("),ZTSAVE("SC("))=""
  1.  S (ZTSAVE("TIUPRLST("),ZTSAVE("XWBOS"))=""
  1.  S ZTDTH=$H,ZTIO="TIU/PXAPI RESOURCE",ZTRTN="ENQ^TIUPXAP1"
  1.  S ZTDESC="TIU/PCE/AmbCare API Call" D ^%ZTLOAD
  1.  I '$D(ZTSK) D ENQ ; If can't get Resource, Run PXAPI call in foreground
  1.  Q
  1. WORKOK(DA) ; Evaluate whether workload collection is appropriate
  1.  N TIUD0 S TIUD0=$G(^TIU(8925,DA,0))
  1.  Q $S($P(TIUD0,U,13)="A":1,$P(TIUD0,U,13)="I":1,$P(TIUD0,U,13)="T":1,1:0)
  1. ENQ ; Entry point for Resource
  1.  I $D(ZTQUEUED) S ZTREQ="@"
  1.  D POST(.TIU,DFN,$S(+$G(TIUDA):+$G(TIUDA),1:$G(DA)),.ICD,.CPT,.SC)
  1.  Q
  1. POST(TIUX,DFN,TIUDA,ICD,CPT,SC) ; Call on commitment to post data to PCE/AmbCare
  1.  N TIULOC,TIUVDT,TIUSTOP,TIUVCAT,TIUVSIT,TIUD0
  1.  S TIULOC=$P($G(TIUX("VSTR")),";"),TIUVDT=+$P($G(TIUX("VSTR")),";",2)
  1.  S TIUVCAT=$P($G(TIUX("VSTR")),";",3),TIUSTOP=$P($G(^SC(+TIULOC,0)),U,7)
  1.  D PXAPI(.TIUVSIT,DFN,TIULOC,TIUVDT,TIUVCAT,TIUSTOP,.ICD,.CPT,.SC,TIUDA)
  1.  I +$G(TIUVSIT)>0,+$G(TIUDA)>0,$D(^TIU(8925,+TIUDA,0)) S TIUD0=^(0) D
  1.  . I $P(TIUD0,U,2)=DFN,$P(TIUD0,U,7)=TIUVDT,$P($G(^TIU(8925,+TIUDA,12)),U,11)=TIULOC D
  1.  . . N DIE,DR,DA S DA=+$G(TIUDA)
  1.  . . S DIE=8925,DR=".03////^S X="_+$G(TIUVSIT)
  1.  . . D ^DIE
  1.  . . S TIUX("VISIT")=+$G(TIUVSIT)_U_TIUVDT
  1.  Q
  1. PXAPI(TIUVSIT,DFN,VLOC,VDT,VCAT,VSTOP,ICD,CPT,SC,TIUDA) ; Build input root
  1.  N TIUPXAPI,SUCCESS,TIUI,TIUPROV,DA,TIUAUTH
  1.  K ^TMP("TIUPXAPI",$J) S TIUPXAPI=$NA(^TMP("TIUPXAPI",$J))
  1.  S:+$G(VDT) @TIUPXAPI@("ENCOUNTER",1,"ENC D/T")=+$G(VDT)
  1.  S:+$G(DFN) @TIUPXAPI@("ENCOUNTER",1,"PATIENT")=+$G(DFN)
  1.  S:+$G(VLOC) @TIUPXAPI@("ENCOUNTER",1,"HOS LOC")=+$G(VLOC)
  1.  I $D(SC)>9 D
  1.  . S @TIUPXAPI@("ENCOUNTER",1,"SC")=$P($G(SC("SC")),U)
  1.  . I $G(SC("AO"))]"" S @TIUPXAPI@("ENCOUNTER",1,"AO")=$P($G(SC("AO")),U)
  1.  . I $G(SC("IR"))]"" S @TIUPXAPI@("ENCOUNTER",1,"IR")=$P($G(SC("IR")),U)
  1.  . I $G(SC("EC"))]"" S @TIUPXAPI@("ENCOUNTER",1,"EC")=$P($G(SC("EC")),U)
  1.  . I $G(SC("MST"))]"" S @TIUPXAPI@("ENCOUNTER",1,"MST")=$P($G(SC("MST")),U)
  1.  . I $G(SC("HNC"))]"" S @TIUPXAPI@("ENCOUNTER",1,"HNC")=$P($G(SC("HNC")),U)
  1.  I $D(CPT) S @TIUPXAPI@("ENCOUNTER",1,"CHECKOUT D/T")=$E($$NOW^XLFDT,1,12)
  1.  S:$G(VCAT)]"" @TIUPXAPI@("ENCOUNTER",1,"SERVICE CATEGORY")=$G(VCAT)
  1.  S:+$G(VSTOP) @TIUPXAPI@("ENCOUNTER",1,"DSS ID")=+$G(VSTOP)
  1.  S @TIUPXAPI@("ENCOUNTER",1,"APPT")=9
  1.  S @TIUPXAPI@("ENCOUNTER",1,"ENCOUNTER TYPE")="P"
  1.  I $D(TIUPRLST) D
  1.  . M @TIUPXAPI@("PROVIDER")=TIUPRLST
  1.  . S TIUPROV=$S($G(TIUPRLST(1,"PRIMARY")):$G(TIUPRLST(1,"NAME")),1:$G(TIUPRLST(2,"NAME")))
  1.  E  D
  1.  . N TIUDDOC
  1.  . I +$G(TIUDA) D
  1.  . . S TIUAUTH=$P($G(^TIU(8925,+$G(TIUDA),12)),U,2) Q:+TIUAUTH'>0
  1.  . . I +$$PROVIDER(TIUAUTH,$G(VDT))'>0 S TIUAUTH=0
  1.  . S TIUDDOC=+$$DFLTDOC^TIUPXAPI(+$G(VLOC))
  1.  . D:'$D(TIUPRM0) SETPARM^TIULE
  1.  . S TIUPROV=$S(+$G(TIUAUTH):+$G(TIUAUTH),+$$PROVIDER(DUZ,$G(VDT)):+$G(DUZ),1:"")
  1.  . I +TIUPROV>0,'$D(XWBOS) D
  1.  . . I +TIUDDOC'=+TIUPROV,(+$P(TIUPRM0,U,8)=1),+TIUDDOC>0 D
  1.  . . . ; Get Provider information from Encounter.
  1.  . . . ; If ENC has no provicders then add default provider as primary. 
  1.  . . . ; Add TIUPROV unless already primary provider for encounter.
  1.  . . . N TIUPRIME,TIUPVCNT,TIUTVST,TIUTPRV,TIUPDATA
  1.  . . . S TIUPRIME="",TIUPVCNT=1
  1.  . . . D GETENC^PXAPI($G(DFN),$G(VDT),$G(VLOC))
  1.  . . . S TIUTVST=""
  1.  . . . F  S TIUTVST=$O(^TMP("PXKENC",$J,TIUTVST)) Q:TIUTVST=""  D
  1.  . . . . S TIUTPRV=""
  1.  . . . . F  S TIUTPRV=$O(^TMP("PXKENC",$J,TIUTVST,"PRV",TIUTPRV)) Q:TIUTPRV=""  D
  1.  . . . . . S TIUPDATA=$G(^TMP("PXKENC",$J,TIUTVST,"PRV",TIUTPRV,0))
  1.  . . . . . I $P(TIUPDATA,"^",4)="P" S TIUPRIME=+TIUPDATA
  1.  . . . I 'TIUPRIME D
  1.  . . . . S @TIUPXAPI@("PROVIDER",TIUPVCNT,"NAME")=+TIUDDOC
  1.  . . . . S @TIUPXAPI@("PROVIDER",TIUPVCNT,"PRIMARY")=1
  1.  . . . . S TIUPVCNT=TIUPVCNT+1
  1.  . . . S @TIUPXAPI@("PROVIDER",TIUPVCNT,"NAME")=+TIUPROV
  1.  . . E  D
  1.  . . . S @TIUPXAPI@("PROVIDER",1,"NAME")=+TIUPROV
  1.  I $D(ICD)>9 S TIUI=0 F  S TIUI=$O(ICD(TIUI)) Q:+TIUI'>0  D
  1.  . S @TIUPXAPI@("DX/PL",TIUI,"ENC PROVIDER")=$G(TIUPROV)
  1.  . S @TIUPXAPI@("DX/PL",TIUI,"DIAGNOSIS")=$P(ICD(TIUI),U)
  1.  . S @TIUPXAPI@("DX/PL",TIUI,"NARRATIVE")=$P(ICD(TIUI),U,3)
  1.  . S:$P(ICD(TIUI),U,4)]"" @TIUPXAPI@("DX/PL",TIUI,"CATEGORY")=$P(ICD(TIUI),U,4)
  1.  . S:+$G(ICD(TIUI,"PRIMARY")) @TIUPXAPI@("DX/PL",TIUI,"PRIMARY")=$G(ICD(TIUI,"PRIMARY"))
  1.  I $D(CPT)>9 S TIUI=0 F  S TIUI=$O(CPT(TIUI)) Q:+TIUI'>0  D
  1.  . S @TIUPXAPI@("PROCEDURE",TIUI,"PROCEDURE")=$P(CPT(TIUI),U)
  1.  . S @TIUPXAPI@("PROCEDURE",TIUI,"QTY")=$S(+$G(CPT(TIUI,"QTY")):+$G(CPT(TIUI,"QTY")),1:1)
  1.  . ;Set CPT Modifiers in Array for PCE
  1.  . N MODCNT,MODATA
  1.  . S MODCNT=0
  1.  . F  S MODCNT=$O(CPT(TIUI,"MOD",MODCNT)) Q:'MODCNT  D
  1.  . . S MODATA=$G(CPT(TIUI,"MOD",MODCNT))
  1.  . . S:$P(MODATA,U,2)'="" @TIUPXAPI@("PROCEDURE",TIUI,"MODIFIERS",$P(MODATA,U,2))=""
  1.  . S @TIUPXAPI@("PROCEDURE",TIUI,"ENC PROVIDER")=$G(TIUPROV)
  1.  . S @TIUPXAPI@("PROCEDURE",TIUI,"NARRATIVE")=$P(CPT(TIUI),U,2)
  1.  . S:$P(CPT(TIUI),U,3)]"" @TIUPXAPI@("PROCEDURE",TIUI,"CATEGORY")=$P(CPT(TIUI),U,3)
  1.  S SUCCESS=$$DATA2PCE^PXAPI(TIUPXAPI,"TIU","TEXT INTEGRATION UTILITIES",.TIUVSIT,DUZ,0)
  1.  K @TIUPXAPI
  1.  Q
  1. PROVIDER(USER,DATE) ; Was USER a PROVIDER on DATE?
  1.  N TIUY,PRVCL,EXCL S TIUY=0
  1.  S EXCL="V0802V0805V0806V0808V0809V0812V0813"
  1.  I +$$ISA^USRLM(USER,"PROVIDER") S TIUY=1 G PROVIDEX
  1.  S PRVCL=$$PRVCLASS^PXAPI(USER,DATE) I PRVCL'>0 G PROVIDEX
  1.  I $P(PRVCL,U,7)]"",(EXCL'[$E($P(PRVCL,U,7),1,5)) S TIUY=1
  1. PROVIDEX Q TIUY
  1. DEFER(DA) ; Mark record to defer workload collection
  1.  N DIE,DR,TIUVSIT
  1.  I +$P($G(^TIU(8925,$S(+$G(TIUDA):+$G(TIUDA),1:+$G(DA)),0)),U,11)=1 Q
  1.  S DIE=8925,DR=".11////1" D ^DIE
  1.  ;If not called via the broker try to link document to an existing visit
  1.  I '$$BROKER^XWBLIB,$$LNKVST^TIUPXAP3(+DA,.TIUVSIT)
  1.  Q