Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: XBHFMAN1

XBHFMAN1.m

Go to the documentation of this file. 
  1. XBHFMAN1 ; IHS/ADC/GTH - HELP FRAME MANUAL (2/2) ; [ 02/07/97   3:02 PM ]
  1.  ;;3.0;IHS/VA UTILITIES;;FEB 07, 1997
  1.  ;
  1.  ; ----- Print Title and Preface page.
  1.  ;
  1.  ;
  1.  S X=XBNS_"HFMN"
  1.  X ^%ZOSF("TEST")
  1.  E  G MAIN
  1.  S XBNOHDR=1
  1.  NEW A,B
  1.  F A="TITLE","PREFACE" Q:$D(DIRUT)  D ^DIWW,TOF F B=1:1 S X=$T(@A+B^@(XBNS_"UMAN")) Q:$L($P(X,";",1))>1  D PR($P(X,";",3)) Q:$D(DIRUT)
  1.  ;
  1.  I $D(DIRUT) G HATOUT
  1.  D ^DIWW
  1.  ;
  1. MAIN ; ----- $ORDER thru the list of OPTIONS, and print them.
  1.  S (XBNAME,XBNOHDR)=0
  1.  F  S XBNAME=$O(^TMP("XBHFMAN",$J,XBNAME)) Q:'XBNAME  D MAKEHDRS,TOF Q:$D(DIRUT)  D HDR(XBNAME),DESC(+^TMP("XBHFMAN",$J,XBNAME)),HF($P($G(^DIC(19,+^TMP("XBHFMAN",$J,XBNAME),0)),U,7)),^DIWW
  1.  I $D(DIRUT) G HATOUT
  1.  ;
  1. INDEX ; ----- Print the index.
  1.  S XBHDR="Index"
  1.  D TOF
  1.  I $D(DIRUT) G HATOUT
  1.  W !!!
  1.  S X="|NOWRAP||SETTAB(""C"")||TAB|INDEX"
  1.  D ^DIWP,^DIWW
  1.  W !!!
  1.  D CONT("INDEX^^"_XBPG)
  1.  S (XB,XBCONT)="",$P(XBCONT,".",81)=""
  1.  F  S XB=$O(^TMP("XBHFMAN-INDEX",$J,XB)) Q:XB=""  S X="" D  Q:$D(DIRUT)
  1.  .F XBX=0:0 S XBX=$O(^TMP("XBHFMAN-INDEX",$J,XB,XBX)) S X=X_XBX_"," I '$O(^(XBX)) D  Q
  1.  ..S X=XB_"..."_$E(XBCONT,1,DIWR-DIWL-$L(XB)-3-$L(X))_$E(X,1,$L(X)-1)
  1.  ..S XBSAVX=X
  1.  ..F  S X=$E(XBSAVX,1,DIWR-DIWL),XBSAVX=$E(XBSAVX,DIWR-DIWL+1,$L(XBSAVX)) Q:'$L(X)  D TOF:$Y>XBBM Q:$D(DIRUT)  D ^DIWP
  1.  ..Q
  1.  .Q
  1.  I $D(DIRUT) G HATOUT
  1.  D ^DIWW,RTRN^XBHFMAN
  1.  I $D(DIRUT) G HATOUT
  1.  ;
  1. CONTENTS ; ----- Print the table of Contents.
  1.  S XBNOHDR=1
  1.  W @IOF,!!!!!
  1.  S X="|SETTAB(""C"")||TAB|CONTENTS"
  1.  D ^DIWP,^DIWW
  1.  W !!
  1.  S XB=0
  1.  F  S XB=$O(^TMP("XBHFMAN-CONTENTS",$J,XB)) Q:'+XB  S X=^(XB),X=$P(X,U)_" "_$P(X,U,2)_$E(XBCONT,1,DIWR-DIWL-$L(X)+1)_$P(X,U,3) D TOF:$Y>XBBM Q:$D(DIRUT)  D ^DIWP
  1.  I $D(DIRUT) G HATOUT
  1.  D ^DIWW,RTRN^XBHFMAN
  1.  I $D(DIRUT) G HATOUT
  1. END ;EP - Paginate, close, kill, quit.
  1.  W @IOF
  1. HATOUT ;  
  1.  D ^%ZISC
  1.  KILL ^TMP("XBHFMAN",$J),XB,XBBM,XBCHAP,XBCONT,XBODD,XBHDR,XBIEN,XBPARA,XBPG,XBROOT,XBTITL,XBTM,XBX,XBY,DIC,DIWF,DIWL,DIWR
  1.  Q
  1.  ;
  1. PR(X) ;EP - Process one line of text.
  1.  NEW A,B,I,N,Y
  1.  I X="|TOP|" D TOF Q
  1.  D INDX(X),^DIWP,TOF:$Y>XBBM
  1.  Q
  1.  ;
  1. INDX(X) ; ----- Parse/capitalize one line of text.  Check for indexed words.
  1.  Q:'$D(XBPG)
  1.  NEW Y,Z
  1.  S X=$TR(X,"abcdefghijklmnopqrstuvwxyz","ABCDEFGHIJKLMNOPQRSTUVWXYZ")
  1.  S X=$TR(X,"~`!@#$%^&*()_-+=|\{[}]:;""""'<,>.?/"," ")
  1.  X XBSTRIP
  1.  F  S %=$F(X,"  ") Q:'%  S X=$E(X,1,%-2)_$E(X,%,$L(X))
  1.  F %=1:1 S Y=$P(X," ",%) Q:Y=""  I $D(^TMP("XBHFMAN-I",$J,Y)) S ^TMP("XBHFMAN-INDEX",$J,Y,XBPG)=""
  1.  Q
  1.  ;
  1. HDR(XB) ; ----- Print a chapter heading.
  1.  S %=$P(^TMP("XBHFMAN",$J,XB),U,2),XB=%_U_$P($G(^DIC(19,+^TMP("XBHFMAN",$J,XB),0)),U,2)
  1.  F X="|SETTAB(""C"")||TAB|Chapter "_$P(XB,U),"|SETTAB(""C"")||TAB|"_$P(XB,U,2) D ^DIWP
  1.  W !!
  1.  D CONT($P(XB,U)_U_$P(XB,U,2)_U_XBPG)
  1.  Q
  1.  ;
  1. TOF ;EP ----- Move to bottom of page, print footer, paginate, print header.
  1.  I XBNOHDR D RTRN^XBHFMAN Q:$D(DIRUT)  W @IOF Q
  1.  F  Q:$Y>XBBM  W !
  1.  I XBPG W !?(DIWL-1),XBDASH,!,?$S(XBODD:DIWR-$L(XBTITL),1:DIWL-1),XBTITL
  1.  D RTRN^XBHFMAN
  1.  I $D(DIRUT) Q
  1.  W @IOF
  1.  S XBPG=XBPG+1,XBODD=XBPG#2
  1.  F  Q:$Y=(XBTM-2)  W !
  1.  W ?$S(XBODD:DIWR-$L("Page "_XBPG),1:DIWL-1),"Page ",XBPG
  1.  I '(XBHDR="Index") W !?DIWL-1,$S(XBODD:XBHDRO,1:XBHDRE)
  1.  W !?(DIWL-1),XBDASH,!!
  1.  Q
  1.  ;
  1. MAKEHDRS ; ----- Make headers for odd and even pages.
  1.  S (XBHDRE,XBHDRO)=$P($G(^DIC(19,+^TMP("XBHFMAN",$J,XBNAME),0)),U,2)
  1.  S XBCHAP=$P(^TMP("XBHFMAN",$J,XBNAME),U,2)
  1.  F %=1:1 I '$P(XBCHAP,".",%) S XBCHAP=$P(XBCHAP,".",1,%-1) Q
  1.  S XBHDRO=XBHDRO_$J("",DIWR-DIWL-$L(XBHDRO)-$L("Chapter "_XBCHAP)+1)_"Chapter "_XBCHAP
  1.  S XBHDRE="Chapter "_XBCHAP_$J("",DIWR-DIWL-$L(XBHDRE)-$L("Chapter "_XBCHAP)+1)_XBHDRE
  1.  Q
  1.  ;
  1. CONT(X) ; ----- Add chapter number, title, and page number to list.
  1.  S XBCONT=XBCONT+1,^TMP("XBHFMAN-CONTENTS",$J,XBCONT)=X
  1.  Q
  1.  ;
  1. DESC(A) ; ----- Print descriptions of the OPTIONs as the first of the chapter.
  1.  NEW B,I,N,Y
  1.  I '$D(^DIC(19,A,1)) D PR("<NO DESCRIPTION>") Q
  1.  S B=0
  1.  F  S B=$O(^DIC(19,A,1,B)) Q:'B  D PR(^(B,0)) Q:$D(DIRUT)
  1.  Q
  1.  ;
  1. HF(A) ; ----- Print the HELP FRAME text.
  1.  I 'A D PR("<NO HELP FRAME>") Q
  1.  I '$D(^DIC(9.2,A,1)) D PR("<NO HELP FRAME TEXT>") Q
  1.  NEW B,I,N,Y
  1.  S B=0
  1.  F  S B=$O(^DIC(9.2,A,1,B)) Q:'B  D PR(^(B,0)) Q:$D(DIRUT)
  1.  ; ----- Print any tied HELP FRAMEs.
  1.  I $O(^DIC(9.2,A,2,0)) S B=0 F  S B=$O(^DIC(9.2,A,2,B)) Q:'B  D HF($P($G(^(B,0)),U,2)) Q:$D(DIRUT)
  1.  Q
  1.  ;