XBLUTL.m

XBLUTL ; IHS/ADC/GTH - LIST ^UTILITY FOR $J ; [ 10/29/2002   7:42 AM ]

 ;;3.0;IHS/VA UTILITIES;**9**;FEB 07, 1997

 ; XB*3*9 IHS/SET/GTH XB*3*9 10/29/2002 Cache' mods.

 ;

 ; This routine lists all entries in the ^UTILITY global for

 ; the current $J where $J is the first or second subscript.

 ;

 ; This is most useful from programmer mode.  If used thru the

 ; XB menu, ^UTILITY($J) is killed in ^XBKSET before this

 ; routine is run.

 ;

START ;

 W @($S($D(IOF):IOF,1:"#"))

 X ^%ZOSF("UCI")

 ;W !,"^UTILITY nodes for job ",$J," in UCI ",Y,!;IHS/SET/GTH XB*3*9 10/29/2002

 W !,"^UTILITY nodes for job ",$J," in ",$S($$VERSION^%ZOSV(1)["Cache":"Namespace",1:"UCI")," ",Y,! ;IHS/SET/GTH XB*3*9 10/29/2002

 S XBLUTL("QFLG")=0,XBLUTL("X")="^UTILITY($J,"""")"

 F  S XBLUTL("X")=$Q(@XBLUTL("X")) Q:$P($P(XBLUTL("X"),"(",2),",")'=$J  D LIST Q:XBLUTL("QFLG")

 S XBLUTL("Y")=" "

 F  S XBLUTL("Y")=$O(^UTILITY(XBLUTL("Y"))) Q:XBLUTL("Y")=""  I $D(^UTILITY(XBLUTL("Y"),$J)) D

 . S XBLUTL("X")="^UTILITY("""_XBLUTL("Y")_""","_$J_")",XBLUTL("Z")="1""^UTILITY("""""_XBLUTL("Y")_""""","_$J_"""1P.E"

 . D:$D(@(XBLUTL("X")))#2 LIST

 . Q:XBLUTL("QFLG")

 . F  S XBLUTL("X")=$Q(@XBLUTL("X")) Q:XBLUTL("X")'?@XBLUTL("Z")  D LIST Q:XBLUTL("QFLG")

 . Q

 KILL XBLUTL

 Q

 ;

LIST ;

 I $Y>($S($D(IOSL):IOSL,1:24)-3) S Y=$$DIR^XBDIR("E"),XBLUTL("QFLG")='Y W:Y @($S($D(IOF):IOF,1:"#"))

 Q:XBLUTL("QFLG")

 W !,XBLUTL("X")," = ",@XBLUTL("X")

 Q

 ;

XBLUTL    ; IHS/ADC/GTH - LIST ^UTILITY FOR $J ; [ 10/29/2002   7:42 AM ]

 +1       ;;3.0;IHS/VA UTILITIES;**9**;FEB 07, 1997

 +2       ; XB*3*9 IHS/SET/GTH XB*3*9 10/29/2002 Cache' mods.

 +3       ;

 +4       ; This routine lists all entries in the ^UTILITY global for

 +5       ; the current $J where $J is the first or second subscript.

 +6       ;

 +7       ; This is most useful from programmer mode.  If used thru the

 +8       ; XB menu, ^UTILITY($J) is killed in ^XBKSET before this

 +9       ; routine is run.

 +10      ;

START     ;

 +1        WRITE @($SELECT($DATA(IOF):IOF,1:"#"))

 +2        XECUTE ^%ZOSF("UCI")

 +3       ;W !,"^UTILITY nodes for job ",$J," in UCI ",Y,!;IHS/SET/GTH XB*3*9 10/29/2002

 +4       ;IHS/SET/GTH XB*3*9 10/29/2002

           WRITE !,"^UTILITY nodes for job ",$JOB," in ",$SELECT($$VERSION^%ZOSV(1)["Cache":"Namespace",1:"UCI")," ",Y,!

 +5        SET XBLUTL("QFLG")=0

           SET XBLUTL("X")="^UTILITY($J,"""")"

 +6        FOR 

               SET XBLUTL("X")=$QUERY(@XBLUTL("X"))

               IF $PIECE($PIECE(XBLUTL("X"),"(",2),",")'=$JOB

                   QUIT 

               DO LIST

               IF XBLUTL("QFLG")

                   QUIT 

 +7        SET XBLUTL("Y")=" "

 +8        FOR 

               SET XBLUTL("Y")=$ORDER(^UTILITY(XBLUTL("Y")))

               IF XBLUTL("Y")=""

                   QUIT 

               IF $DATA(^UTILITY(XBLUTL("Y"),$JOB))

                   Begin DoDot:1

 +9                    SET XBLUTL("X")="^UTILITY("""_XBLUTL("Y")_""","_$JOB_")"

                       SET XBLUTL("Z")="1""^UTILITY("""""_XBLUTL("Y")_""""","_$JOB_"""1P.E"

 +10                   IF $DATA(@(XBLUTL("X")))#2

                           DO LIST

 +11                   IF XBLUTL("QFLG")

                           QUIT 

 +12                   FOR 

                           SET XBLUTL("X")=$QUERY(@XBLUTL("X"))

                           IF XBLUTL("X")'?@XBLUTL("Z")

                               QUIT 

                           DO LIST

                           IF XBLUTL("QFLG")

                               QUIT 

 +13                   QUIT 

                   End DoDot:1

 +14       KILL XBLUTL

 +15       QUIT 

 +16      ;

LIST      ;

 +1        IF $Y>($SELECT($DATA(IOSL):IOSL,1:24)-3)

               SET Y=$$DIR^XBDIR("E")

               SET XBLUTL("QFLG")='Y

               IF Y

                   WRITE @($SELECT($DATA(IOF):IOF,1:"#"))

 +2        IF XBLUTL("QFLG")

               QUIT 

 +3        WRITE !,XBLUTL("X")," = ",@XBLUTL("X")

 +4        QUIT 

 +5       ;