Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: XDRMERGB

XDRMERGB.m

Go to the documentation of this file. 
  1. XDRMERGB ;SF-IRMFO.SEA/JLI - TENATIVE UPDATE POINTER NODES ;5/14/98  10:30
  1.  ;;7.3;TOOLKIT;**23,137**;Apr 25, 1995;Build 11
  1.  ;;
  1.  Q
  1.  ;
  1. MERGEIT ; MERGE TWO ENTRIES IN FILE
  1.  N NODE,NODE1,NODE2,NODEA,SFILE,XDRFROM,XDRTO,NODEA,VALUE,XVALUE,XDRXX,NODEB,DIK,DA,I,Y,VREF,XNN,XFILNO,IENTOSTR,DFN,XDRZZ
  1.  N XDRAA ; DEBUG STATEMENT
  1.  ;
  1.  S XFILNO=+$P(@(XDRDIC_"0)"),U,2)
  1.  S IENTOSTR=IENTO_","_XDRIENS
  1.  S DFN=IENTO
  1.  ;
  1.  ; NOW MERGE DATA GOING NODE BY NODE
  1.  ;
  1.  S NODE=""
  1.  F  D  Q:NODE=""
  1.  . S NODE1=$O(@(XDRDIC_IENFROM_","""_NODE_""")"))
  1.  . I NODE1="" S NODE="" Q  ; NOTHING MORE TO MOVE OVER
  1.  . S NODE2=$O(@(XDRDIC_IENTO_","""_NODE_""")"))
  1.  . I NODE2'="",NODE1]NODE2 S NODE=NODE2 Q  ; NODE ON TO, BUT NOT ON FROM - GO TO NEXT
  1.  . S NODE=NODE1
  1.  . I $D(@(XDRDIC_IENFROM_","""_NODE_""")"))=1 D  Q  ; SINGLE NODE, MERGE DATA
  1.  . . I NODE2]NODE1!(NODE2="") D  Q  ;  MISSING NODE, JUST MOVE IT OVER
  1.  . . . N XDRXX,FLD,N,J
  1.  . . . F N=0:0 S N=$O(^DD(XFILNO,"GL",NODE,N)) Q:N'>0  S FLD=$O(^(N,0)) I $O(^DD(XFILNO,FLD,1,0))>0 D
  1.  . . . . S X=0 F J=0:0 S J=$O(^DD(XFILNO,FLD,1,J)) Q:J'>0  I $O(^(J,0))>0 S X=1 Q
  1.  . . . . I X>0 D
  1.  . . . . . S XDRXX(XFILNO,IENTOSTR,FLD)=$P(@(XDRDIC_IENFROM_","""_NODE_""")"),U,N)
  1.  . . . K XDRAA I $D(XDRTESTK),$D(XDRXX) M XDRAA=XDRXX ; DEBUT STATEMENT
  1.  . . . K XDRZZ
  1.  . . . I $D(XDRXX) D FILE^DIE("","XDRXX","XDRZZ")
  1.  . . . I $D(XDRTESTK),$D(XDRZZ) S XDRTESTK=XDRTESTK+1 M ^XTMP("XDRTESTK",$$NOW^XLFDT(),XDRTESTK,"XX")=XDRAA,^("ZZ")=XDRZZ ; DEBUG STATMENT
  1.  . . . M @(XDRDIC_IENTO_","""_NODE_""")")=@(XDRDIC_IENFROM_","""_NODE_""")")
  1.  . . I $D(@(XDRDIC_IENTO_","""_NODE_""")"))>1 Q  ; MISMATCH SO QUIT
  1.  . . N XDRXX,FLD
  1.  . . S X1=@(XDRDIC_IENFROM_","""_NODE_""")")
  1.  . . S (X2,X3)=@(XDRDIC_IENTO_","""_NODE_""")")
  1.  . . F I=1:1 Q:X1=""  S X=$P(X1,U),X1=$P(X1,U,2,999) I X'="" D
  1.  . . . S Y=$P(X2,U,I)
  1.  . . . I Y=""  D
  1.  . . . . ;S $P(X2,U,I)=X ;LLS 26-OCT-2013 replaced with conditional SET below
  1.  . . . . S FLD=$O(^DD(XFILNO,"GL",NODE,I,0)) S JXFLD=FLD
  1.  . . . . I (XFILNO'=2)!(FLD'=.6) S $P(X2,U,I)=X ;LLS 26-OCT-2013 - replaced set of X2 so do not move 'test patient indicator'
  1.  . . . . I XFILNO=2,FLD=.6 Q  ;LLS 26-OCT-2013 - Do not want to move 'test patient indicator' 
  1.  . . . . I FLD>0,$O(^DD(XFILNO,FLD,1,0))>0 S XDRXX(XFILNO,IENTOSTR,FLD)=X
  1.  . . I X2'=X3 D
  1.  . . . I $D(XDRXX) D
  1.  . . . . K XDRAA I $D(XDRTESTK) M XDRAA=XDRXX ; DEBUG STATEMENT
  1.  . . . . K XDRZZ
  1.  . . . . N X2 D FILE^DIE("","XDRXX","XDRZZ")
  1.  . . . . I $D(XDRTESTK),$D(XDRZZ) S XDRTESTK=XDRTESTK+1 M ^XTMP("XDRTESTK",$$NOW^XLFDT(),XDRTESTK,"XX")=XDRAA,^("ZZ")=XDRZZ ; DEBUG STATMENT
  1.  . . . S @(XDRDIC_IENTO_","""_NODE_""")")=X2 ; SET MERGED DATA ON NODE
  1.  . ;
  1.  . ; THE FOLLOWING HANDLES NODES THAT HAVE MULTIPLES
  1.  . ;
  1.  . S XDRFROM=XDRDIC_IENFROM_","""_NODE_""","
  1.  . S XDRTO=XDRDIC_IENTO_","""_NODE_""","
  1.  . I NODE="DIS",XFILNO=2 D DODIS^XDRMERGA Q
  1.  . S IENTOSTR=IENTO_","_XDRIENS
  1.  . D DOSUBS^XDRMERGA(XDRFROM,XDRTO,IENTOSTR,IENTO)
  1.  S XDRXX=$P(@(XDRDIC_IENFROM_",0)"),U)
  1.  K DA N DIU S DIU(0)=1 S DIK=XDRDIC,DA=IENFROM,DFN=DA D ^DIK ; KILL OFF MERGED FROM ENTRY
  1.  S @(XDRDIC_IENFROM_",0)")=XDRXX
  1.  Q
  1.  ;
  1. SAVEMERG(FILE,IENFROM,IENTO) ;
  1.  N IENS,XDRFILE,YYY,ZZZ,XDRFDA,FROMARG,TOARG,XDRDA,Q,Q1,IENVAL,XDRSUB
  1.  S FROMARG=$O(@FROM@(IENFROM,IENTO,"")) Q:FROMARG=""
  1.  S TOARG=$O(@FROM@(IENFROM,IENTO,FROMARG,""))
  1.  S XDRDA=$$FIND1^DIC(15.4,"","Q",FROMARG)
  1.  I XDRDA>0,$P(^XDRM(XDRDA,0),U)'=FROMARG S XDRDA=0
  1.  I XDRDA'>0 D
  1.  . N XDRFDA
  1.  . S XDRFDA(15.4,"+1,",.01)=FROMARG
  1.  . S XDRFDA(15.4,"+1,",.02)=TOARG
  1.  . S XDRFDA(15.4,"+1,",.03)=DT
  1.  . D UPDATE^DIE("","XDRFDA","YYY") S IENS=YYY(1)
  1.  . S XDRDA=YYY(1)
  1.  S XDRFILE=$P(^DIC(FILE,0),U)
  1.  S IENS=$$FIND1^DIC(15.41,","_XDRDA_",","Q",XDRFILE)
  1.  I IENS'>0 D
  1.  . S IENS="+1,"_XDRDA_","
  1.  . S XDRFDA(15.41,IENS,.01)=XDRFILE
  1.  . I IENFROM>0 S XDRFDA(15.41,IENS,.02)=IENFROM
  1.  . K YYY
  1.  . D UPDATE^DIE("","XDRFDA","YYY","ZZZ") S IENS=YYY(1)
  1.  I IENFROM>0 D
  1.  . S XDRSUB=15.411,IENVAL=IENFROM
  1.  . D STORMERG
  1.  K XDRFDA
  1.  S IENS=$$FIND1^DIC(15.42,","_XDRDA_",","Q",XDRFILE)
  1.  I IENS'>0 D
  1.  . S IENS="+1,"_XDRDA_","
  1.  . S XDRFDA(15.42,IENS,.01)=XDRFILE
  1.  . I IENTO>0 S XDRFDA(15.42,IENS,.02)=IENTO
  1.  . K YYY,ZZZ
  1.  . D UPDATE^DIE("","XDRFDA","YYY","ZZZ") S IENS=YYY(1)
  1.  I IENTO>0 D
  1.  . S XDRSUB=15.421,IENVAL=IENTO
  1.  . D STORMERG
  1.  Q
  1. STORMERG ;
  1.  K ^VA(15.4,XDRDA,$S(XDRSUB=15.411:1,1:2),IENS,1) ; REMOVE ANY PREVIOUS TRIES
  1.  S IENS="+1,"_IENS_","_XDRDA_","
  1.  S Q=^DIC(FILE,0,"GL")_IENVAL_")",Q1=$E(Q,1,$L(Q)-1)
  1.  F  S Q=$Q(@Q) Q:Q'[Q1  D
  1.  . K XDRFDA
  1.  . S XDRFDA(XDRSUB,IENS,.01)=$E(Q,2,$L(Q))
  1.  . I @Q'="" S XDRFDA(XDRSUB,IENS,1.01)=@Q
  1.  . D UPDATE^DIE("","XDRFDA")
  1.  Q
  1.  ;
  1. SAVEPNTR(IENFROM,IENTO,FILE,IENS,FIELD,VALUE) ;
  1.  N XDRFDA,XDRDA,FROMARG
  1.  S FROMARG=$O(@FROM@(IENFROM,IENTO,"")) Q:FROMARG=""
  1.  S XDRDA=$$FIND1^DIC(15.4,"","Q",FROMARG)
  1.  S X=FILE_";"_IENS_";"_FIELD
  1.  S XDRFDA(15.43,"+1,"_XDRDA_",",.01)=X
  1.  S XDRFDA(15.43,"+1,"_XDRDA_",",1.01)=VALUE
  1.  D UPDATE^DIE("","XDRFDA")
  1.  Q
  1. SNDMSG(XDRFDA) ;Sends msg when merge process has completed.
  1.  N XDRGRP,XMTEXT,XMSUB,XMDUZ,XDRNAME
  1.  S XDRNAME=$$GET1^DIQ(15.2,XDRFDA,.01)
  1.  S R(1,0)=XDRNAME_" merge process has completed."
  1.  S XDRGRP=$$GET1^DIQ(15.1,"2,",.29,"I")
  1.  S:XDRGRP>0 XDRGRPN=$$GET1^DIQ(3.8,XDRGRP,.01)
  1.  S XDRGRP=$S(XDRGRP>0:"G."_XDRGRPN,1:"")
  1.  S:XDRGRP'="" XMY(XDRGRP)=""
  1.  S:XDRGRP="" XMY(.5)="" ;If no mail grp found, send msg to postmaster
  1.  S XMTEXT="R(",XMSUB=XDRNAME_" Completed",XMDUZ=.5,XMCHAN=1
  1.  D ^XMD
  1.  Q
  1.  ;
  1. QUE ;  (Moved from XDRMERG0)
  1.  ;
  1.  N XDRXX,XDRYY,XDRMA,DIE,DIC,DIR,DR,ZTDTH,ZTSK
  1.  N XDRX,XDRY,XDRFIL,XDRGLOB,X,Y,XDRNAME
  1.  N XDRFDA,XDRIENS,XDRI,XDRJ,XDRK,DA,DIK
  1.  ;
  1.  S XDRFIL=$$FILE^XDRDPICK() Q:XDRFIL'>0
  1.  I XDRFIL=2 D  Q:Y
  1.  . N X,XDRKEY
  1.  . S (X,XDRKEY)=0 F  S X=$O(^VA(200,DUZ,51,"B",X)) Q:X'>0!(XDRKEY)  D
  1.  . . I $$GET1^DIQ(19.1,X,.01)="DG ELIGIBILITY" S XDRKEY=1
  1.  . . Q
  1.  . S Y=0 I 'XDRKEY W !!,"You should hold the 'DG ELIGIBILITY' key to run a patient file merge." S Y=1
  1.  . Q
  1.  S XDRDIC=^DIC(XDRFIL,0,"GL")
  1.  S XDRGLOB=$E(XDRDIC,2,999)
  1.  S X=""
  1.  S XNCNT=0,XNCNT0=0
  1.  F  S X=$O(^VA(15,"AVDUP",XDRGLOB,X)) Q:X=""  S Y=$O(^(X,0)) D
  1.  . N YVAL S YVAL=^VA(15,Y,0)
  1.  . I $P(YVAL,U,20)>0 Q  ; ALREADY DONE OR SCHEDULED
  1.  . I $P(YVAL,U,3)'="V" Q  ; TAKE ONLY VERIFIED
  1.  . I $P(YVAL,U,5)'=1 Q  ; TAKE ONLY IF MARKED READY TO MERGE
  1.  . I $P(YVAL,U,13)>0 D
  1.  . . I '$D(@(XDRDIC_(+YVAL)_",0)"))!'$D(@(XDRDIC_(+$P(YVAL,U,2))_",0)")) Q
  1.  . . I $P(YVAL,U,4)'=2 S XDRX(+YVAL,+$P(YVAL,U,2))=Y ; get ien numbers from duplicate file
  1.  . . E  S XDRX(+$P(YVAL,U,2),+YVAL)=Y ; Reverse - merge to switched
  1.  . . S XNCNT=XNCNT+1
  1.  W !!,XNCNT,"  Entries Ready to be included in merge"
  1.  I $O(XDRX(0))'>0 D  Q
  1.  . W !!?15,$C(7),"No Verified Duplicates included in merge",$C(7),!!
  1.  ;
  1.  K DIR S DIR(0)="Y"
  1.  S DIR("A",1)="This process will take a **LONG** time (usually over 15 hours, and sometimes"
  1.  S DIR("A",2)="considerably longer), but you CAN stop and restart the process when you"
  1.  S DIR("A")="want using the options.  OK"
  1.  D ^DIR K DIR Q:Y'>0
  1. NAME W !! S DIR(0)="F^2:30"
  1.  S DIR("A")="Name for Merge Process"
  1.  S DIR("?",1)="Enter a unique name by which the MERGE PROCESS will be identified"
  1.  S DIR("?")="This name should be 2 to 30 characters in length"
  1.  D ^DIR
  1.  K DIR Q:Y=U  S XDRNAME=Y
  1.  I $$FIND1^DIC(15.2,",","Q",XDRNAME)>0 D  G NAME
  1.  . W !!,$C(7),"The name entered has already been used.  The name must be unique.",!!
  1.  ;
  1.  ; CREATE PROCESS ENTRY
  1.  ;
  1.  S XDRXX(15.2,"+1,",.01)=XDRNAME
  1.  S XDRXX(15.2,"+1,",.02)=XDRFIL
  1.  D UPDATE^DIE("","XDRXX","XDRYY","XDRMA")
  1.  S XDRFDA=$G(XDRYY(1))
  1.  ;
  1.  ; NOW MOVE LIST OF DUPLICATES TO BE PROCESSED INTO THIS ENTRY
  1.  S XDRIENS="+1,"_XDRFDA_","
  1.  F XDRI=0:0 S XDRI=$O(XDRX(XDRI)) Q:XDRI'>0  D
  1.  . S XDRJ=$O(XDRX(XDRI,0))
  1.  . S XDRK=XDRX(XDRI,XDRJ)
  1.  . K XDRXX,XDRYY
  1.  . S XDRXX(15.22,XDRIENS,.01)=XDRI ; IEN1
  1.  . S XDRXX(15.22,XDRIENS,.02)=XDRJ ; IEN2
  1.  . S XDRXX(15.22,XDRIENS,.03)=XDRK ; ENTRY # IN FILE 15
  1.  . D UPDATE^DIE("","XDRXX","XDRYY","XDRMA")
  1.  . K XDRXX,XDRYY,XDRMA
  1.  . ;    AND MARK THEM AS IN THIS MERGE PROCESS IN FILE 15
  1.  . S XDRXX(15,XDRK_",",.05)=3
  1.  . S XDRXX(15,XDRK_",",.2)=XDRFDA
  1.  . D FILE^DIE("","XDRXX")
  1.  . ; JLI 3/12/98 - FOR SOME REASON THE .05 FIELD STILL DOESN'T SEEM TO BE GETTING SET TO 3, SO CHECK IT AND IF THAT IS THE CASE, HARDSET IT.
  1.  . I $P(^VA(15,XDRK,0),U,5)'=3 S $P(^(0),U,5)=3
  1.  ;
  1.  K DR S DR=".03;.04///S;" ; GET DESIRED START TIME AND MARK PROCESS AS SCHEDULED
  1.  S DIE="^VA(15.2,"
  1.  S DA=XDRFDA
  1.  D ^DIE
  1.  S ZTDTH=$P(^VA(15.2,XDRFDA,0),U,3) ; TAKE DESIRED TIME
  1.  I ZTDTH>0 D  Q:$G(ZTSK)>0  ;         AND SET UP TASK
  1.  . S ZTRTN="DQ^XDRMERG0",ZTDESC="MERGE PROCESS "_XDRNAME
  1.  . S ZTIO="NULL",ZTSAVE("XDRFDA")=""
  1.  . D ^%ZTLOAD
  1.  . I $G(ZTSK)>0 D
  1.  . . K DR S DR=".08///"_ZTSK_";",DIE="^VA(15.2,",DA=XDRFDA D ^DIE
  1.  . . W !!,"Merge process '",$P(^VA(15.2,XDRFDA,0),U),"' for Verified Duplicates in File ",XDRFIL," scheduled",!,"as task ",ZTSK,".",!
  1.  ;
  1.  ;  TASK INFO, TIME, ETC. NOT COMPLETE - SO REVERSE IT
  1.  ;
  1.  F XDRI=0:0 S XDRI=$O(XDRX(XDRI)) Q:XDRI'>0  D
  1.  . S XDRJ=$O(XDRX(XDRI,0))
  1.  . S XDRK=XDRX(XDRI,XDRJ)
  1.  . K XDRXX,XDRYY
  1.  . S XDRXX(15,XDRK_",",.2)="@" ; UNMARK ENTRY IN FILE 15
  1.  . S XDRXX(15,XDRK_",",.05)=1
  1.  . D UPDATE^DIE("","XDRXX")
  1.  S DA=XDRFDA
  1.  S DIK="^VA(15.2,"
  1.  D ^DIK
  1.  W !!,$C(7),"The Merge Process has been aborted, no changes made."
  1.  Q
  1.  ;