Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: XMCX

XMCX.m

Go to the documentation of this file. 
  1. XMCX ;ISC-SF/GMB-Play a Script / Queue Transmit Task ;12/04/2002  13:45
  1.  ;;8.0;MailMan;**6,10**;Jun 28, 2002
  1.  ; Was (WASH ISC)/THM
  1.  ;
  1.  ; Entry points used by MailMan options (not covered by DBIA):
  1.  ; PLAY    XMSCRIPTPLAY     (was GO^XMC11)
  1.  ; Q1      XMSTARTQUE       (was Q^XMC2)
  1.  ; QALL    XMSTARTQUE-ALL   (was REQUE^XMS5)
  1.  Q
  1. PLAY ; Play a script
  1.  N XM,XMB,XMC,XMINST,XMSITE,XMIO,XMHOST,XMABORT
  1.  K XMTLER
  1.  S XM="D",XMABORT=0
  1.  D ASKINST^XMCXU(.XMINST,.XMSITE,.XMABORT) Q:XMABORT
  1.  D CHKTSK^XMCXU(XMINST,2,.XMABORT) Q:XMABORT
  1.  D ASKSCR^XMCXU(XMINST,XMSITE,.XMB,.XMABORT) Q:XMABORT
  1.  S XMIO=$P(XMB("SCR REC"),U,5)
  1. AGAIN ;
  1.  D ENT^XMC1
  1.  I ER=25!($G(XMHOST)="NO-IP") D  G:'XMABORT AGAIN
  1.  . N XMTEXT,XMIPSAVE
  1.  . I '$$USEDNS^XMKPR1 D  Q
  1.  . . S XMABORT=1
  1.  . . ;DNS is not activated at this site, so you'll have to figure
  1.  . . ;out the correct IP address yourself.
  1.  . . D BLD^DIALOG(42263,"","","XMTEXT","F")
  1.  . . D MSG^DIALOG("WM","","","","XMTEXT")
  1.  . ;Let's see what we can do...
  1.  . ;We've tried these: |1|
  1.  . D BLD^DIALOG(42264,XMB("IP TRIED"),"","XMTEXT","F")
  1.  . D MSG^DIALOG("WM","","","","XMTEXT")
  1.  . S XMB("TRIES")=XMB("TRIES")+1
  1.  . S XMIPSAVE=XMB("IP TRIED"),XMC("PLAY")=1
  1.  . D NEXTIP^XMKPR1(XMSITE,.XMB) K XMC("PLAY")
  1.  . I XMIPSAVE=XMB("IP TRIED") D  Q
  1.  . . S XMABORT=1
  1.  . . ;The DNS did not return any other addresses to try.  Sorry!
  1.  . . D BLD^DIALOG(42265,"","","XMTEXT","F")
  1.  . . D MSG^DIALOG("WM","","","","XMTEXT")
  1.  . W !,$$EZBLD^DIALOG(42266,$P(XMB("SCR REC"),U,6)) ;Now, let's try: |1|
  1.  . K ER,XMER
  1.  I 'XMABORT,'ER S XMC("PLAY")=1 D CHKSETIP^XMTDR(XMINST,XMSITE,.XMB)
  1.  D KL^XMC
  1.  Q
  1. Q1 ; Trigger a queue for transmission
  1.  N XMB,XMINST,XMSITE,XMTSK,XMABORT
  1.  S XMABORT=0 ; pick a queue w/msgs
  1.  D ASKINST^XMCXU(.XMINST,.XMSITE,.XMABORT,"M") Q:XMABORT
  1.  D CHKTSK^XMCXU(XMINST,1,.XMABORT) Q:XMABORT
  1.  D ASKSCR^XMCXU(XMINST,XMSITE,.XMB,.XMABORT) Q:XMABORT
  1.  D QUEUE(XMINST,XMSITE,.XMB)
  1.  Q
  1. TASK ;
  1. QALL ;
  1.  N XMDUZ,XMK,XMIEN,XMSITE
  1.  S:$D(ZTQUEUED) ZTREQ="@"
  1.  D RESEQ^XMCQA
  1.  K ^TMP("XM",$J)
  1.  S XMK=1000
  1.  F  S XMK=$O(^XMB(3.7,.5,2,XMK)) Q:'XMK  Q:XMK>9999  D
  1.  . Q:'$$BMSGCT^XMXUTIL(.5,XMK)
  1.  . W:'$D(ZTQUEUED) "."
  1.  . S XMIEN=XMK-1000
  1.  . S:'$$TSKEXIST^XMKPR(XMIEN) ^TMP("XM",$J,$P(^DIC(4.2,XMIEN,0),U))=XMIEN
  1.  I '$D(^TMP("XM",$J)) D  Q
  1.  . W:'$D(ZTQUEUED) !!,$$EZBLD^DIALOG(42125) ;All queues with messages have tasks.
  1.  I '$D(ZTQUEUED) D  Q:'$D(^TMP("XM",$J))
  1.  . W:$E($G(IOST),1,2)="C-" @IOF
  1.  . W !,$$EZBLD^DIALOG(42126),! ;These queues with messages have no tasks:
  1.  . S XMSITE=""
  1.  . F  S XMSITE=$O(^TMP("XM",$J,XMSITE)) Q:XMSITE=""  D
  1.  . . I $Y+3>IOSL D
  1.  . . . D WAIT^XMXUTIL
  1.  . . . W @IOF
  1.  . . S XMIEN=^TMP("XM",$J,XMSITE)
  1.  . . W !,$E(XMSITE,1,37)
  1.  . . Q:$P(^DIC(4.2,XMIEN,0),U,2)["S"
  1.  . . W ?40,$$EZBLD^DIALOG(42127) ;No Send Flag - Will not task
  1.  . . K ^TMP("XM",$J,XMSITE)
  1.  . Q:'$D(^TMP("XM",$J))
  1.  . N DIR
  1.  . S DIR(0)="YO"
  1.  . S DIR("A")=$$EZBLD^DIALOG(42128) ;Requeue the missing tasks
  1.  . S DIR("B")=$$EZBLD^DIALOG(39053) ;No
  1.  . D BLD^DIALOG(42129,"","","DIR(""?"")") ;Answer YES to create tasks to transmit these queues.
  1.  . D ^DIR Q:Y
  1.  . W !!,$$EZBLD^DIALOG(42130) ;Tasks not requeued.
  1.  . K ^TMP("XM",$J)
  1.  S XMSITE=""
  1.  F  S XMSITE=$O(^TMP("XM",$J,XMSITE)) Q:XMSITE=""  D
  1.  . S XMIEN=^TMP("XM",$J,XMSITE)
  1.  . I $$UP^XLFSTR($P(^DIC(4.2,XMIEN,0),U,2))'["S" D  Q
  1.  . . W:'$D(ZTQUEUED) !,$E(XMSITE,1,37),?40,$$EZBLD^DIALOG(42127) ;No Send Flag - Will not task
  1.  . D QUEUE(XMIEN,XMSITE)
  1.  W:'$D(ZTQUEUED) !,$$EZBLD^DIALOG(42132) ;Finished.
  1.  K ^TMP("XM",$J)
  1.  Q
  1. QUEUE(XMINST,XMSITE,XMB,XMWHEN,XMTSK) ;
  1.  D QUEUE^XMKPR(XMINST,XMSITE,.XMB,.XMWHEN,.XMTSK) Q:$D(ZTQUEUED)
  1.  W !,$E(XMSITE,1,37),?40,$$EZBLD^DIALOG($S($D(XMTSK):42131,1:39311),$G(XMTSK)) ;Task |1| queued / Task creation failed
  1.  Q