Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: XMJMF1

XMJMF1.m

Go to the documentation of this file. 
  1. XMJMF1 ;ISC-SF/GMB-XMJMF (cont.) ;07/12/2002  11:08
  1.  ;;8.0;MailMan;;Jun 28, 2002
  1. FIND(XMDUZ,XMK,XMKCHOOS,XMKN) ; Search mailbox or message file
  1.  ; XMK       !=Search the message file
  1.  ;           *=Search the user's mailbox
  1.  ;           n=Search user's basket number n
  1.  ; XMKCHOOS  1=user may choose which basket
  1.  ;           0=user is locked into current basket
  1.  ;           U=user is doing a Postmaster Super Search
  1.  N XMDIR,XMOPT,XMOX,XMY,XMF,XMABORT,XMFFRN,XMFBSKTN,XMFTDTX,XMFFDTX,XMFRFRN,XMSRCHED,XMHDR
  1.  S (XMABORT,XMSRCHED)=0
  1.  I XMK="!" D  Q:XMABORT
  1.  . I $G(XMKCHOOS)="U" D  Q:XMABORT
  1.  . . I '$$SSPRIV^XMXSEC1 D  Q
  1.  . . . D SHOW^XMJERR
  1.  . . . D WAIT^XMXUTIL
  1.  . . . S XMABORT=1
  1.  . . S XMF("FLAGS")="U"
  1.  . . S XMHDR=$$EZBLD^DIALOG(34435.5) ; Current 'All Messages Super Search' search criteria:
  1.  . E  S XMHDR=$$EZBLD^DIALOG(34435) ; Current 'All Messages' search criteria:
  1.  . S XMF("FDATE")=$$FMADD^XLFDT(DT,-30) ; Search period is last 30 days.
  1.  . S XMF("TDATE")=DT
  1.  . S XMFFDTX=$$MMDT^XMXUTIL1(XMF("FDATE"))
  1.  . S XMFTDTX=$$MMDT^XMXUTIL1(XMF("TDATE"))
  1.  E  D
  1.  . S XMHDR=$$EZBLD^DIALOG(34436) ; Current 'Mailbox' search criteria:
  1.  . S XMF("BSKT")=XMK
  1.  . I XMK S XMFBSKTN=$G(XMKN,$$BSKTNAME^XMXUTIL(XMDUZ,XMK))
  1.  F  D  Q:XMABORT
  1.  . W @IOF,XMHDR
  1.  . S XMDIR("A")=$$EZBLD^DIALOG(34420) ; Select search action
  1.  . I XMK'="!" D
  1.  . . I +XMF("BSKT")=XMF("BSKT") D
  1.  . . . W !,$$EZBLD^DIALOG(34437),":",?30,XMFBSKTN ; Search basket
  1.  . . . Q:'XMKCHOOS
  1.  . . . D SET^XMXSEC1("B",34421.1,.XMOPT,.XMOX) ; Change Search basket
  1.  . . . D SET^XMXSEC1("BA",34421.2,.XMOPT,.XMOX) ; Search all baskets
  1.  . . E  D
  1.  . . . W !,$$EZBLD^DIALOG(34437),":",?30,$$EZBLD^DIALOG(34437.1) ; Search basket / All baskets
  1.  . . . D SET^XMXSEC1("B",34421,.XMOPT,.XMOX) ; Search one basket
  1.  . I $D(XMF("SUBJ")) D
  1.  . . W !,$$EZBLD^DIALOG(34438),":",?30,XMF("SUBJ") ; Subject contains
  1.  . . D SET^XMXSEC1("S",34422.1,.XMOPT,.XMOX) ; Change 'Subject contains' string
  1.  . E  D SET^XMXSEC1("S",34422,.XMOPT,.XMOX) ; Enter 'Subject contains' string
  1.  . I $D(XMF("FROM")) D
  1.  . . W !,$$EZBLD^DIALOG(34440),":",?30,XMFFRN ; Message from
  1.  . . D SET^XMXSEC1("F",34423.1,.XMOPT,.XMOX) ; Change 'Message from' person
  1.  . E  D SET^XMXSEC1("F",34423,.XMOPT,.XMOX) ; Enter 'Message from' person
  1.  . I $D(XMF("TO")) D
  1.  . . W !,$$EZBLD^DIALOG(34440.2),":",?30,XMF("TO") ; Message to
  1.  . . D SET^XMXSEC1("T",34424.1,.XMOPT,.XMOX) ; Change 'Message to' addressee
  1.  . E  D SET^XMXSEC1("T",34424,.XMOPT,.XMOX) ; Enter 'Message to' addressee
  1.  . I $D(XMF("FDATE")) D
  1.  . . W !,$$EZBLD^DIALOG(34444),":",?30,XMFFDTX ; Message sent on or after
  1.  . . D SET^XMXSEC1("DA",34426.1,.XMOPT,.XMOX) ; Change 'Message sent on or after' date
  1.  . E  D SET^XMXSEC1("DA",34426,.XMOPT,.XMOX) ; Enter 'Message sent on or after' date
  1.  . I $D(XMF("TDATE")) D
  1.  . . W !,$$EZBLD^DIALOG(34445),":",?30,XMFTDTX ; Message sent on or before
  1.  . . D SET^XMXSEC1("DB",34427.1,.XMOPT,.XMOX) ; Change 'Message sent on or before' date
  1.  . E  D SET^XMXSEC1("DB",34427,.XMOPT,.XMOX) ; Enter 'Message sent on or before' date
  1.  . I $D(XMF("FLINE")) D
  1.  . . W !,$$EZBLD^DIALOG(34449),":",?30,XMF("FLINE") ; Lines of text, minimum
  1.  . . D SET^XMXSEC1("LM",34430.1,.XMOPT,.XMOX) ; Change 'Minimum Lines of text' number
  1.  . E  D SET^XMXSEC1("LM",34430,.XMOPT,.XMOX) ; Enter 'Minimum Lines of text' number
  1.  . ;I $D(XMF("TLINE")) D
  1.  . ;. W !,$$EZBLD^DIALOG(34450),":",?30,XMF("TLINE") ; Lines of text, maximum
  1.  . ;. D SET^XMXSEC1("LX",34431.1,.XMOPT,.XMOX) ; Change 'Maximum Lines of text' number
  1.  . ;E  D SET^XMXSEC1("LX",34431,.XMOPT,.XMOX) ; Enter 'Maximum Lines of text' number
  1.  . I $D(XMF("RFROM")) D
  1.  . . W !,$$EZBLD^DIALOG(34440.1),":",?30,XMFRFRN ; Response from
  1.  . . D SET^XMXSEC1("R",34428.1,.XMOPT,.XMOX) ; Change 'Response from' person
  1.  . E  D SET^XMXSEC1("R",34428,.XMOPT,.XMOX) ; Enter 'Response from' person
  1.  . I $D(XMF("TEXT")) D
  1.  . . ; x.1:Message / x.2:Message or Response / x.3:Response contains
  1.  . . W !,$$EZBLD^DIALOG(34446+(XMF("TEXT","L")/10)),":",?30,XMF("TEXT")
  1.  . . D SET^XMXSEC1("X",34429.1,.XMOPT,.XMOX) ; Change 'Message contains' string
  1.  . E  D SET^XMXSEC1("X",34429,.XMOPT,.XMOX) ; Enter 'Message contains' string
  1.  . D SET^XMXSEC1("Q",34420.1,.XMOPT,.XMOX) ; Quit
  1.  . I $D(XMF("SUBJ"))!$D(XMF("FROM"))!$D(XMF("FDATE"))!$D(XMF("TDATE"))!$D(XMF("TO"))!$D(XMF("RFROM"))!$D(XMF("TEXT"))!$D(XMF("FLINE"))!$D(XMF("TLINE")) D
  1.  . . D SET^XMXSEC1("G",34420.2,.XMOPT,.XMOX) ; Go search
  1.  . . S XMDIR("B")=$S(XMSRCHED:34420.1,1:34420.2) ; Q:Quit / G:Go search
  1.  . E  D
  1.  . . S XMDIR("B")=34422 ; S:Enter 'Subject contains' string
  1.  . S XMDIR("??")="XM-U-Q-SEARCH CRITERIA"
  1.  . S XMDIR(0)="SC" ; show choices/split into columns, if necessary
  1.  . D XMDIR^XMJDIR(.XMDIR,.XMOPT,.XMOX,.XMY,.XMABORT) Q:XMABORT
  1.  . S XMSRCHED=(XMY="G")
  1.  . K XMOPT,XMOX,XMDIR
  1.  . D @XMY^XMJMF2
  1.  Q