Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: XMJMR1

XMJMR1.m

Go to the documentation of this file. 
  1. XMJMR1 ;ISC-SF/GMB-Interactive Reply (cont.) ;08/24/2001  08:29
  1.  ;;8.0;MailMan;;Jun 28, 2002
  1. INIT(XMDUZ,XMK,XMKN,XMZO,XMZOSUBJ,XMZOFROM,XMINSTR,XMINCL,XMZI,XMWHICH,XMABORT) ;
  1.  N DIR,Y,DIRUT,XMRESPS
  1.  I XMDUZ=.6,DUZ=.6 D  Q
  1.  . ; This is already handled in OPTMSG^XMXSEC2, but, just in case...
  1.  . S XMABORT=1
  1.  . W !,$$EZBLD^DIALOG(37422.6) ; SHARED,MAIL may not Reply to a message.
  1.  . G H^XUS
  1.  D CHKLOCK^XMJMS(XMDUZ,.XMABORT) Q:XMABORT
  1.  I XMINSTR("FLAGS")["P" D  Q:XMABORT
  1.  . N XMTEXT
  1.  . W !,$C(7)
  1.  . D BLD^DIALOG(34200,"","","XMTEXT","F") ; Responses to priority messages are not ... (need priority? send a new msg)
  1.  . D MSG^DIALOG("WH","","","","XMTEXT")
  1.  . W !
  1.  . D PAGE^XMXUTIL(.XMABORT)
  1.  I XMZOFROM["POSTMASTER",XMZOFROM["@" D  Q:XMABORT
  1.  . N XMTEXT
  1.  . W !,$C(7)
  1.  . D BLD^DIALOG(34201,"","","XMTEXT","F") ; Because this message is from a remote ... (reply stays local)
  1.  . D MSG^DIALOG("WH","","","","XMTEXT")
  1.  . W !
  1.  . D PAGE^XMXUTIL(.XMABORT)
  1.  D CHKBSKT^XMJMOI(XMDUZ,XMZO,.XMK,.XMKN)
  1.  I +XMK<1 D
  1.  . W !
  1.  . D SAVEMSG^XMJMOI(XMDUZ,.XMK,.XMKN,XMZO,XMZOSUBJ,XMZOFROM,$G(XMINSTR("RCPT BSKT")))
  1.  S XMRESPS=+$P($G(^XMB(3.9,XMZO,3,0)),U,4)
  1.  D WHICH(XMDUZ,XMZO,XMINCL,.XMZI,.XMWHICH,.XMABORT)
  1.  Q
  1. WHICH(XMDUZ,XMZO,XMINCL,XMZI,XMWHICH,XMABORT) ;
  1.  ; XMINCL =0 Do not include previous responses.  Just reply.
  1.  ;        =1 Include previous response(s) from this message
  1.  ;           or include response(s) from another message in reply.
  1.  ;        =2 Include response(s) from another message in a new message.
  1.  Q:XMINCL=0
  1.  D WHICHMSG(XMDUZ,XMZO,XMINCL,.XMZI,.XMABORT) Q:XMABORT
  1.  D WHICH^XMJMC(XMZI,$$EZBLD^DIALOG(34209),.XMWHICH,.XMABORT) ; include
  1.  Q
  1. WHICHMSG(XMDUZ,XMZO,XMINCL,XMZI,XMABORT) ; Include responses from which (different) message
  1.  N DIR,X,Y,XMIN,XMAX,XMPARM
  1.  S (XMPARM(1),XMIN)=$O(^XMB(3.9,0)),(XMPARM(2),XMAX)=$O(^XMB(3.9,":"),-1)
  1.  W !
  1.  S DIR("A")=$$EZBLD^DIALOG(34270) ; Include responses from which message
  1.  I XMINCL=1 D
  1.  . S DIR("B")=$$EZBLD^DIALOG(34271) ; This message
  1.  . S DIR(0)="FO^"_$$MIN^XLFMTH($L(XMIN),$L(DIR("B")))_":"_$$MAX^XLFMTH($L(XMAX),$L(DIR("B")))_"^D CHKMSG^XMJMR1(.Y)"
  1.  . D BLD^DIALOG(34272,.XMPARM,"","DIR(""?"")")
  1.  . ;Press Enter to include previous responses from this message
  1.  . ;or enter the internal entry number of a different message
  1.  . ;(_XMIN_-_XMAX_) to include any of its responses.
  1.  E  D
  1.  . S DIR(0)="NO^"_XMIN_":"_XMAX_":0^D CHKMSG^XMJMR1(.Y)"
  1.  . D BLD^DIALOG(34273,.XMPARM,"","DIR(""?"")")
  1.  . ;Enter the internal entry number of a different message
  1.  . ;(_XMIN_-_XMAX_) to include any of its responses.
  1.  D ^DIR
  1.  I 'Y S XMABORT=1 Q
  1.  S XMZI=+Y
  1.  Q:XMINCL=1
  1.  ; Do you want to review this message first?
  1.  Q
  1. CHKMSG(XMZI) ;
  1.  I XMINCL=1,XMZI=DIR("B") S XMZI=XMZO Q  ; Include previous responses from this message.
  1.  I XMINCL=1,$S(XMZI'?.N:1,XMZI<XMIN:1,XMZI>XMAX:1,1:0) K X W $C(7)," ?" Q
  1.  I XMINCL=2,XMZI=XMZO D  Q
  1.  . K X
  1.  . W !,$$EZBLD^DIALOG(34274) ; You can't include the message you're editing.
  1.  N XMZIREC ; Include responses from another message.
  1.  S XMZIREC=$G(^XMB(3.9,XMZI,0))
  1.  I XMZIREC="" K X Q
  1.  I '$$INCLUDE^XMXSEC(XMDUZ,XMZI) D  Q
  1.  . K X
  1.  . D SHOW^XMJERR
  1.  W "  ",$P(XMZIREC,U,1)
  1.  Q
  1. COPYTEXT(XMZI,XMZ,XMWHICH,XMHDR) ;
  1.  N I,XMRESP,XMRANGE,XMC
  1.  I $G(XMHDR) S XMHDR("XMZ")=XMZI,XMHDR("REC")=^XMB(3.9,XMZI,0)
  1.  W !,$$EZBLD^DIALOG(34202) ; Copying...
  1.  S XMC=+$O(^XMB(3.9,XMZ,2,""),-1)
  1.  F I=1:1:$L(XMWHICH,",") D
  1.  . S XMRANGE=$P(XMWHICH,",",I)
  1.  . Q:XMRANGE=""  ; (XMWHICH can end with a ",", giving us a null piece.)
  1.  . F XMRESP=$P(XMRANGE,"-",1):1:$S(XMRANGE["-":$P(XMRANGE,"-",2),1:XMRANGE) D
  1.  . . I XMRESP=0 D COPYRESP(XMRESP,XMZI,XMZ,.XMC,.XMHDR) Q
  1.  . . D COPYRESP(XMRESP,+$G(^XMB(3.9,XMZI,3,XMRESP,0)),XMZ,.XMC,.XMHDR)
  1.  S ^XMB(3.9,XMZ,2,0)="^3.92A^"_XMC_U_XMC_U_DT
  1.  Q
  1. COPYRESP(XMRESP,XMZI,XMZ,XMC,XMHDR) ;
  1.  N XMF,XMFROM,XMDT,XMZREC,XMPARM
  1.  S XMC=XMC+1
  1.  S ^XMB(3.9,XMZ,2,XMC,0)=""
  1.  S XMZREC=$G(^XMB(3.9,XMZI,0))
  1.  S XMFROM=$$NAME^XMXUTIL($P(XMZREC,U,2))
  1.  S XMDT=$P(XMZREC,U,3)
  1.  I $G(XMHDR) D
  1.  . S XMC=XMC+1
  1.  . S ^XMB(3.9,XMZ,2,XMC,0)="In the message:"
  1.  . S XMC=XMC+1
  1.  . S ^XMB(3.9,XMZ,2,XMC,0)=">"_$$EZBLD^DIALOG(34536,$$SUBJ^XMXUTIL2(XMHDR("REC")))_"  "_$$EZBLD^DIALOG(34537,XMHDR("XMZ")) ; Subj: / [#]
  1.  . S XMC=XMC+1
  1.  . S ^XMB(3.9,XMZ,2,XMC,0)=">"_$$EZBLD^DIALOG(34538,$$FROM^XMXUTIL2(XMHDR("REC")))_$S($P(XMHDR("REC"),U,4)="":"",1:" "_$$EZBLD^DIALOG(34533,$$NAME^XMXUTIL($P(XMHDR("REC"),U,4)))) ; From: |1| (Sender: |1|)
  1.  . S XMC=XMC+1
  1.  . S ^XMB(3.9,XMZ,2,XMC,0)=">"_$$EZBLD^DIALOG(34585,$$MMDT^XMXUTIL1($P(XMHDR("REC"),U,3))) ; Sent: |1|
  1.  S XMC=XMC+1
  1.  S XMPARM(1)=$$MMDT^XMXUTIL1(XMDT)
  1.  S XMPARM(2)=$S(XMRESP:$$EZBLD^DIALOG(34204,XMRESP),1:$$EZBLD^DIALOG(34205)) ; Response #|1| / Original message
  1.  S XMPARM(3)=XMFROM
  1.  S ^XMB(3.9,XMZ,2,XMC,0)=$$EZBLD^DIALOG(34203,.XMPARM) ; On |1| (|2|) |3| wrote:
  1.  S XMF=.999999
  1.  F  S XMF=$O(^XMB(3.9,XMZI,2,XMF)) Q:XMF=""  D
  1.  . S XMC=XMC+1
  1.  . W:XMC#50=0 "."
  1.  . S ^XMB(3.9,XMZ,2,XMC,0)=$E(">"_^XMB(3.9,XMZI,2,XMF,0),1,254)
  1.  Q