Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: XPDI

XPDI.m

Go to the documentation of this file. 
  1. XPDI ;SFISC/RSD - Install Process ;9/16/02  13:29 [ 03/19/2004  12:04 PM ]
  1.  ;;8.0;KERNEL;**10,21,39,41,44,58,68,108,145,184,229,1009**;Jul 10, 1995
  1. EN ;install
  1.  N DIR,DIRUT,POP,XPD,XPDA,XPDD,XPDIJ,XPDDIQ,XPDIT,XPDIABT,XPDNM,XPDNOQUE,XPDPKG,XPDREQAB,XPDST,XPDSET,XPDSET1,XPDT,XPDQUIT,XPDQUES,Y,ZTSK,%
  1.  S %="I '$P(^(0),U,9),$D(^XPD(9.7,""ASP"",Y,1,Y)),$D(^XTMP(""XPDI"",Y))",XPDST=$$LOOK^XPDI1(%)
  1.  Q:'XPDST!$D(XPDQUIT)
  1.  S XPDIT=0,(XPDSET,XPDSET1)=$P(^XPD(9.7,XPDST,0),U) K ^TMP($J)
  1.  ;Check each part of XPDT array
  1.  F  S XPDIT=$O(XPDT(XPDIT)) Q:'XPDIT  D  Q:'$D(XPDT)!$D(XPDQUIT)
  1.  .S XPDA=+XPDT(XPDIT),XPDNM=$P(XPDT(XPDIT),U,2),XPDPKG=+$P($G(^XPD(9.7,+XPDT(XPDIT),0)),U,2),%=$P(^(0),U,5)
  1.  .W !,"Checking Install for Package ",XPDNM
  1.  .;check that Install file was created correctly
  1.  .I '$D(^XPD(9.7,XPDA,"INI"))!'$D(^("INIT")) W !,"**INSTALL FILE IS CORRUPTED**",!,*7 S XPDQUIT=1 Q
  1.  .;run enviroment check routine
  1.  .;XPDREQAB req. build missing, =2 global killed
  1.  .I $$ENV^XPDIL1(1) S:$G(XPDREQAB)=2 XPDQUIT=1 Q
  1.  .;save variables that are setup in environ. chck. routine
  1.  .I $D(XPDNOQUE)!$D(XPDDIQ) D
  1.  ..S:$D(XPDNOQUE) ^XTMP("XPDI",XPDA,"ENVVAR","XPDNOQUE")=XPDNOQUE
  1.  ..I $D(XPDDIQ) M ^XTMP("XPDI",XPDA,"ENVVAR","XPDDIQ")=XPDDIQ
  1.  .D QUES^XPDI1(XPDA) Q:'$D(XPDT(+XPDIT))!$D(XPDQUIT)
  1.  .;XPDIJ=XPDA if XPDIJ routine is part of Build
  1.  .S:$D(^XTMP("XPDI",XPDA,"RTN","XPDIJ")) XPDIJ=XPDA
  1.  .D XQSET^XPDI1(XPDA)
  1.  ;NONE = no Build to install
  1.  G NONE:'$O(XPDT(""))!$D(XPDQUIT)!($G(XPDREQAB))
  1.  ;check that we have all Builds to install
  1.  S XPDA=XPDST,XPDNM=XPDSET,Y=0
  1.  F  S Y=$O(^XPD(9.7,"ASP",XPDA,Y)) Q:'Y  S %=+$O(^(Y,0)) I '$D(XPDT("DA",%)) G NONE
  1.  W !
  1.  ;See if a Master Build
  1.  S %=$O(^XTMP("XPDI",XPDA,"BLD",0)),%=$P(^(%,0),U,3) S:%=1 XPDT("MASTER")=XPDA
  1.  ;Inhibit Logon Question
  1.  D DIR^XPDIQ("XPI") I $D(DIRUT) D ABRTALL(2) Q
  1.  ;disable options question
  1.  D DIR^XPDIQ("XPZ") I $D(DIRUT) D ABRTALL(2) Q
  1.  ;XPDSET=set name,(also build name), of options that will be disabled
  1.  ;XPDSET1=setname or null if they don't want to disable
  1.  D  I XPDSET1="^" D ABRTALL(2) Q
  1.  .;if they say no, set XPDET1=""
  1.  .S:'$G(XPDQUES("XPZ1")) XPDSET1="",Y=0
  1.  .S ^XTMP("XQOO",XPDSET,0)=XPDSET_" is being installed by KIDS^"_DT_U_DUZ
  1.  .I XPDSET1]"" D  Q:XPDSET1="^"!(XPDSET1="")
  1.  ..;merge the options/protocols that were put in ^TMP($J,"XQOO",build name)
  1.  ..M ^XTMP("XQOO",XPDSET)=^TMP($J,"XQOO",XPDSET)
  1.  ..D INIT^XQOO(.XPDSET1) Q:"^"[XPDSET1
  1.  ..N DIR S DIR(0)="N^0:60:0",DIR("B")=0
  1.  ..S DIR("A")="Delay Install (Minutes)",DIR("?")="Enter the number of minutes to delay the installing of Routines after the Disable of Options"
  1.  ..W ! D ^DIR I $D(DIRUT) S XPDSET1="^"
  1.  .;Y is set in the call to DIR in previous .DO
  1.  .;save setname into first Build and the Delay in minutes, Y
  1.  .K XPD S XPD(9.7,XPDST_",",7)=(XPDSET1]"")_XPDSET,XPD(9.7,XPDST_",",8)=Y
  1.  .D FILE^DIE("","XPD")
  1.  ;check if they want to update other CPUs
  1.  I $G(XPDQUES("XPZ2")) D  I $D(DIRUT) D ABRTALL(2) Q
  1.  .N DA,DIE,DIR,DR,I,XPD,X,Y,Z
  1.  .;if they haven't already added Volume Sets, populate the mulitple
  1.  .I '$O(^XPD(9.7,XPDA,"VOL",0)) D  I $D(XPD) D UPDATE^DIE("","XPD")
  1.  ..X ^%ZOSF("UCI") S Y=$P(Y,",",2),(I,Z)=0
  1.  ..F  S I=$O(^%ZIS(14.5,I)) Q:'I  S X=$G(^(I,0)) S:$P(X,U)]""&$P(X,U,11)&($P(X,U)'=Y) Z=Z+1,XPD(9.703,"+"_Z_","_XPDA_",",.01)=$P(X,U)
  1.  .W !!,"I will Update the following VOLUME SETS:",!
  1.  .S I=0 F  S I=$O(^XPD(9.7,XPDA,"VOL",I)) Q:'I  W ?3,$P(^(I,0),U),!
  1.  .W ! S DIR(0)="Y",DIR("A")="Want to edit this list",DIR("B")="NO"
  1.  .D ^DIR Q:$D(DIRUT)  D:Y
  1.  ..S DA=XPDA,DIE="^XPD(9.7,",DR=30,DR(2,9.703)=".01"
  1.  ..D ^DIE
  1.  .I '$O(^XPD(9.7,XPDA,"VOL",0)) W !!,"No VOLUME SETS selected!!" Q
  1.  .Q:$$TM^%ZTLOAD  ;quit if Taskman is running
  1.  .W !!,"TASKMAN is not running. If you install now, you must run the routine XPDCPU",!,"in the production UCI for each of the VOLUME SETS you have listed once"
  1.  .W !,"the installation starts!!",!,"If you Queue the install, the VOLUME SETS will be updated automatically.",*7,*7,!!
  1. DEV S POP=0 S:'$D(^DD(3.5,0)) POP=1
  1.  ;check if home device is defined
  1.  I 'POP S IOP="",%ZIS=0 D ^%ZIS
  1.  ;Kernel Virgin Install
  1.  I POP S XPDA=XPDST D:$G(XPDIJ) XPDIJ^XPDI1 G EN^XPDIJ
  1.  ;set XPDA=starting Build, ask for device for messages
  1.  ;XPDNOQUE is defined means don't let them queue output
  1.  W !!,"Enter the Device you want to print the Install messages."
  1.  W:'$D(XPDNOQUE) !,"You can queue the install by enter a 'Q' at the device prompt."
  1.  W !,"Enter a '^' to abort the install.",!
  1.  S XPDA=XPDST,%ZIS=$P("Q",U,'$D(XPDNOQUE))
  1.  D ^%ZIS G:POP ASKABRT
  1.  ;reset expiration date to T+7 on transport global
  1.  S XPDD=$$FMADD^XLFDT(DT,7),^XTMP("XPDI",0)=XPDD_U_DT
  1.  I $D(IO("Q")) D  G ASKABRT:$D(ZTSK)[0 D XPDIJ^XPDI1:$G(XPDIJ),QUIT^XPDI1(XPDST) Q
  1.  . N DIR,NOW S NOW=$$HTFM^XLFDT($$HADD^XLFDT($H,,,2)) ;Must be in future
  1.  . S DIR(0)="DA^"_NOW_":"_XPDD_":AEFRSX"
  1.  . S DIR("A")="Request Start Time: "
  1.  . S DIR("B")=$$FMTE^XLFDT(NOW)
  1.  . S DIR("?",1)="Enter a Date including Time"
  1.  . S DIR("?",2)="The time must be in the future and not to exceed 7 days in the future."
  1.  . S DIR("?")="Current date/time: "_DIR("B")
  1.  . D ^DIR
  1.  .Q:$D(DIRUT)
  1.  .S ZTDTH=Y,ZTRTN="EN^XPDIJ",ZTDESC=XPDNM_" KIDS install",ZTSAVE("XPDA")=""
  1.  .D ^%ZTLOAD,HOME^%ZIS K IO("Q")
  1.  .Q:$D(ZTSK)[0
  1.  .W !,"Install Queued!",!!
  1.  .;save task into first Build
  1.  .K XPD S XPD(9.7,XPDST_",",5)=ZTSK,XPDIT=0
  1.  .F  S XPDIT=$O(XPDT(XPDIT)) Q:'XPDIT  S XPD(9.7,+XPDT(XPDIT)_",",.02)=1 D FILE^DIE("","XPD") K XPD
  1.  ;run install
  1.  U IO D XPDIJ^XPDI1:$G(XPDIJ),QUIT^XPDI1(XPDST) G EN^XPDIJ
  1.  Q
  1.  ;
  1.  ;XPDA=ien to del, XPDK=1 kill global, XPDALL=1 deleting all
  1.  ;XPDST=starting package.
  1. ABORT(XPDA,XPDK,XPDALL) ;abort install of Build XPDA
  1.  N %,DA,DIK,XPDJ,XPDNM,Y
  1.  Q:'$D(^XPD(9.7,XPDA,0))  S XPDNM=$P(^(0),U)
  1.  D BMES^XPDUTL(XPDNM_" Build will not be installed"_$S(XPDK=1:", Transport Global deleted!",1:"")),MES^XPDUTL("               "_$$HTE^XLFDT($H))
  1.  S DIK="^XPD(9.7,",XPDJ=XPDT("NM",XPDNM),DA=XPDA
  1.  ;kill XPDT array, but don't kill global if XPDK=2
  1.  K XPDT("NM",XPDNM),XPDT("DA",XPDA),XPDT(XPDJ),XPDT("GP") Q:XPDK=2
  1.  K ^XTMP("XPDI",XPDA)
  1.  ;if we are not deleting all packages and we are deleting the starting package
  1.  ;set the next package to the starting package. It must always be 1.
  1.  I '$G(XPDALL),XPDA=XPDST S Y=$O(XPDT(0)) D:Y
  1.  .;unlock starting install
  1.  .L -^XPD(9.7,XPDST)
  1.  .S XPDST=+XPDT(Y),XPDT(1)=XPDT(Y),XPDT("DA",XPDST)=1,XPDT("NM",$P(XPDT(Y),U,2))=1,XPDIT=0
  1.  .K XPDT(Y) N XPD
  1.  .S %="XPD(9.7,"""_XPDST_","")",@%@(3)=XPDST,@%@(4)=1
  1.  .;loop thru the rest of the packages and reset the starting package field
  1.  .F  S Y=$O(XPDT(Y)) Q:'Y  D
  1.  ..S XPD(9.7,+XPDT(Y)_",",3)=XPDST
  1.  .D FILE^DIE("","XPD")
  1.  D ^DIK
  1.  Q
  1. ASKABRT ;ask if want to unload distribution
  1.  N DIR,DIRUT,X,Y
  1.  S XPDQUIT=1,DIR(0)="Y",DIR("A")="Install ABORTED, Want to remove the Transport Globals",DIR("B")="YES"
  1.  W ! D ^DIR I Y D ABRTALL(1) Q
  1.  L -^XPD(9.7,XPDST)
  1.  Q
  1. ABRTALL(XPDK) ;abort all Builds
  1.  N XPDA
  1.  S XPDT=0
  1.  F  S XPDT=$O(XPDT(XPDT)) Q:'XPDT  S XPDA=+XPDT(XPDT) D ABORT(XPDA,XPDK,1)
  1.  ;unlock starting install
  1.  L -^XPD(9.7,XPDST)
  1.  Q
  1. NONE W !!,"**NOTHING INSTALLED**",!
  1.  Q