Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: XUMFI

XUMFI.m

Go to the documentation of this file. 
  1. XUMFI ;CIOFO-SF/RAM - Master File Interface ;8/14/06
  1.  ;;8.0;KERNEL;**206,217,218,335,261,369**;Jul 10, 1995;Build 27
  1.  ;
  1.  ; This routine is the Master File Server HL7 message builder API.
  1.  ; The routine will generate messages for both trigger events and
  1.  ; queries.
  1.  ;
  1.  ; Use the routine XUMFP to initialize the PARAM array.
  1.  ; See XUMFP for a full description of the parameters.
  1.  ;
  1.  ; use of $O(^HLCS(870,"C",institution_ptr)) supported by IA# 3550
  1.  ;
  1. MAIN(IFN,IEN,TYPE,PARAM,ERROR) ;  -- entry point
  1.  ;
  1.  ;
  1.  N HLFS,HLCS,HLRESLT,QUERY,UPDATE,ALL,CNT,ROOT,PROTOCOL,MFR,MFQ,MTYP,I
  1.  N ARRAY,GROUP,MFK,CDSYS,J,HLSCS
  1.  ;
  1.  M ^TMP("XUMF MFS",$J,"PARAM")=PARAM K PARAM
  1.  ;
  1.  D INIT^XUMFI0,BUILD,LLNK,SEND,EXIT
  1.  ;
  1.  ;
  1.  Q
  1.  ;
  1. BUILD ; -- build message
  1.  ;
  1.  I MFK D MFK Q
  1.  ;
  1.  Q:ERROR
  1.  ;
  1.  N ID,APP,EVENT,ENDT,EFFDT,RESP,MFI,MFN,EDT,CODE,MFE
  1.  ;
  1.  I QUERY D QRD Q:MFQ
  1.  ;
  1.  D MFI
  1.  ;
  1.  I GROUP D GROUP Q
  1.  ;
  1.  D MFE,ZZZ
  1.  ;
  1.  Q
  1.  ;
  1. MFK ; -- master file acknowledgement
  1.  ;
  1.  N X
  1.  S X="MSA"_HLFS_$S(ERROR:"AE",1:"AA")_HLFS_HL("MID")_HLFS_$P(ERROR,U,2)
  1.  S ^TMP(MTYP,$J,CNT)=X
  1.  S CNT=CNT+1
  1.  ;
  1.  Q
  1.  ;
  1. QRD ; -- query definition segment
  1.  ;
  1.  I TYPE>10 D
  1.  .S ^TMP(MTYP,$J,CNT)="MSA"_HLFS_$S(ERROR:"AE",1:"AA")_HLFS_HL("MID")
  1.  .S CNT=CNT+1
  1.  ;
  1.  Q:ERROR
  1.  ;
  1.  N QDT,QFC,QP,QID,ZDRT,ZDRDT,QLR,WHO,WHAT,WDDC,WDCVQ,QRL,QRD
  1.  ;
  1.  S QDT=$G(^TMP("XUMF MFS",$J,"PARAM","QDT"))
  1.  S QFC=$G(^TMP("XUMF MFS",$J,"PARAM","QFC"))
  1.  S QP=$G(^TMP("XUMF MFS",$J,"PARAM","QP"))
  1.  S QID=$G(^TMP("XUMF MFS",$J,"PARAM","QID"))
  1.  S ZDRT=$G(^TMP("XUMF MFS",$J,"PARAM","DRT"))
  1.  S ZDRDT=$G(^TMP("XUMF MFS",$J,"PARAM","DRDT"))
  1.  S QLR=$G(^TMP("XUMF MFS",$J,"PARAM","QLR"))
  1.  S WHO=$G(^TMP("XUMF MFS",$J,"PARAM","WHO"))
  1.  S WHAT=$G(^TMP("XUMF MFS",$J,"PARAM","WHAT"))
  1.  S WDDC=$G(^TMP("XUMF MFS",$J,"PARAM","WDDC"))
  1.  S WDCVQ=$G(^TMP("XUMF MFS",$J,"PARAM","WDCVQ"))
  1.  S QRL=$G(^TMP("XUMF MFS",$J,"PARAM","QRL"))
  1.  S QRD="QRD"_HLFS_QDT_HLFS_QFC_HLFS_QP_HLFS_QID_HLFS_ZDRT_HLFS_ZDRDT
  1.  S QRD=QRD_HLFS_QLR_HLFS_WHO_HLFS_WHAT_HLFS_WDDC_HLFS_WDCVQ_HLFS_QRL
  1.  S ^TMP(MTYP,$J,CNT)=QRD
  1.  S CNT=CNT+1
  1.  ;
  1.  Q
  1.  ;
  1. MFI ; master file identifier segment
  1.  ;
  1.  Q:ERROR
  1.  ;
  1.  N ID,APP,EVENT,ENDT,EFFDT,RESP,MFI
  1.  ;
  1.  S ID=$G(^TMP("XUMF MFS",$J,"PARAM","MFI"))
  1.  S APP=$G(^TMP("XUMF MFS",$J,"PARAM","MFAI"))
  1.  S EVENT=$G(^TMP("XUMF MFS",$J,"PARAM","FLEV"))
  1.  S ENDT=$G(^TMP("XUMF MFS",$J,"PARAM","ENDT"))
  1.  S EFFDT=$G(^TMP("XUMF MFS",$J,"PARAM","MFIEDT"))
  1.  S RESP=$G(^TMP("XUMF MFS",$J,"PARAM","RLC"))
  1.  S:APP="" APP="MFS" S:EVENT="" EVENT="REP" S:RESP="" RESP="NE"
  1.  S:ENDT="" ENDT=$$NOW^XLFDT S:EFFDT="" EFFDT=$$NOW^XLFDT
  1.  S MFI=$$MFI^XUMFMFI(ID,APP,EVENT,ENDT,EFFDT,RESP)
  1.  I $E(MFI)="-" S ERROR=MFI Q
  1.  S ^TMP(MTYP,$J,CNT)=MFI
  1.  S CNT=CNT+1
  1.  ;
  1.  Q
  1.  ;
  1. MFE ; master file entry segment
  1.  ;
  1.  Q:ERROR
  1.  ;
  1.  N EVENT,MFN,EDT,CODE,MFE
  1.  ;
  1.  S EVENT=$G(^TMP("XUMF MFS",$J,"PARAM","RLEC"))
  1.  S MFN=$G(^TMP("XUMF MFS",$J,"PARAM","MFNCID"))
  1.  S EDT=$G(^TMP("XUMF MFS",$J,"PARAM","MFEEDT"))
  1.  S CODE=$G(^TMP("XUMF MFS",$J,"PARAM","PKV"))
  1.  S:EDT="" EDT=$$NOW^XLFDT S:EVENT="" EVENT="MAD"
  1.  S MFE=$$MFE^XUMFMFE(EVENT,MFN,EDT,CODE)
  1.  I $E(MFE)="-" S ERROR=MFE Q
  1.  S ^TMP(MTYP,$J,CNT)=MFE
  1.  S CNT=CNT+1
  1.  ;
  1.  Q
  1.  ;
  1. ZZZ ; [Z...] segment
  1.  ;
  1.  Q:ERROR
  1.  ;
  1.  N SEG,SEQ,ZZZ,FLD,FILE,IENS,VALUE,ERR,ZDTYP,FIELD,SEQ1,SEQ2,SEQ3
  1.  N SEQ0,SEQ9,CNT1,CNT2,NODE,XXX
  1.  ;
  1.  S SEG="",SEQ=0
  1.  F  S SEG=$O(^TMP("XUMF MFS",$J,"PARAM","SEG",SEG)) Q:SEG=""  D
  1.  .S ZZZ=SEG
  1.  .F  S SEQ=$O(^TMP("XUMF MFS",$J,"PARAM","SEG",SEG,"SEQ",SEQ)) Q:'SEQ  D
  1.  ..;
  1.  ..S SEQ1=$P(SEQ,"."),SEQ2=$P(SEQ,".",2)
  1.  ..S SEQ3=$O(^TMP("XUMF MFS",$J,"PARAM","SEG",SEG,"SEQ",SEQ,"HLSCS",0))
  1.  ..;
  1.  ..I SEQ3 D SUBCOMP Q
  1.  ..;
  1.  ..S FLD=$O(^TMP("XUMF MFS",$J,"PARAM","SEG",SEG,"SEQ",SEQ,0))
  1.  ..;
  1.  ..I 'FLD D
  1.  ...S FILE=^TMP("XUMF MFS",$J,"PARAM","SEG",SEG,"SEQ",SEQ,"FILE")
  1.  ...S IENS=$G(^TMP("XUMF MFS",$J,"PARAM","IENS",SEG,SEQ))
  1.  ...S FIELD=^TMP("XUMF MFS",$J,"PARAM","SEG",SEG,"SEQ",SEQ,"FIELD")
  1.  ...S ZDTYP=^TMP("XUMF MFS",$J,"PARAM","SEG",SEG,"SEQ",SEQ,"DTYP")
  1.  ...I $P(ZDTYP,U,3)[":" S FIELD=FIELD_$P(ZDTYP,U,3)
  1.  ...S VALUE=$$GET1^DIQ(FILE,IENS,FIELD)
  1.  ...S VALUE=$$DTYP^XUMFP(VALUE,ZDTYP,HLCS,1)
  1.  ..I FLD D
  1.  ...S ZDTYP=$G(^TMP("XUMF MFS",$J,"PARAM","SEG",SEG,"SEQ",SEQ,FLD))
  1.  ...I $P(ZDTYP,U,3)[":" S FLD=FLD_$P(ZDTYP,U,3)
  1.  ...S VALUE=$$GET1^DIQ(IFN,IEN_",",FLD)
  1.  ...S VALUE=$$DTYP^XUMFP(VALUE,ZDTYP,HLCS,1)
  1.  ..;
  1.  ..S ZZZ(SEQ)=VALUE
  1.  .;
  1.  .S X=0
  1.  .F  S X=$O(ZZZ(X)) Q:'X  D
  1.  ..S SEQ1=$P(X,"."),SEQ2=+$P(X,".",2)
  1.  ..S XXX(SEQ1,SEQ2)=ZZZ(X)
  1.  .K ZZZ
  1.  .M ZZZ=XXX
  1.  .;
  1.  .K NODE
  1.  .S (SEQ,SEQ0,SEQ9,SEQ1,CNT1,CNT2)=0,NODE=""
  1.  .F  S SEQ1=$O(ZZZ(SEQ1)) Q:'SEQ1  D
  1.  ..S SEQ2=0,VALUE=$G(ZZZ(SEQ1,SEQ2))
  1.  ..F  S SEQ2=$O(ZZZ(SEQ1,SEQ2)) Q:'SEQ2  D
  1.  ...S $P(VALUE,HLCS,SEQ2)=ZZZ(SEQ1,SEQ2)
  1.  ..S NODE(CNT1)=$G(NODE(CNT1))
  1.  ..I NODE(CNT1)'="",$L(NODE(CNT1)_VALUE)>200 D
  1.  ...S CNT1=CNT1+1,SEQ9=SEQ0+SEQ9
  1.  ..S SEQ=$S('CNT1:SEQ1,1:SEQ1-SEQ9)
  1.  ..S $P(NODE(CNT1),HLFS,SEQ)=VALUE
  1.  ..S SEQ0=SEQ-1
  1.  .;
  1.  .S NODE=SEG_HLFS_$G(NODE(0)) K NODE(0)
  1.  .;
  1.  .M ^TMP(MTYP,$J,CNT)=NODE
  1.  .S CNT=CNT+1
  1.  .;
  1.  .I $D(^TMP("XUMF MFS",$J,"PARAM",IEN,"ROUTINE",5)) D
  1.  ..S X=0 F  S X=$O(^TMP("XUMF MFS",$J,"PARAM",IEN,"ROUTINE",5,X)) Q:'X  D
  1.  ...S IENS=$G(^TMP("XUMF MFS",$J,"PARAM",IEN,"ROUTINE",5,X))
  1.  ...S VALUE=$$GET1^DIQ(9.818,IENS,.01),$P(NODE,HLFS,6)=VALUE
  1.  ...S VALUE=$$GET1^DIQ(9.818,IENS,2),$P(NODE,HLFS,7)=VALUE
  1.  ...S ^TMP(MTYP,$J,CNT)=NODE
  1.  ...S CNT=CNT+1
  1.  ;
  1.  Q
  1.  ;
  1. SUBCOMP ; -- subcomponents
  1.  ;
  1.  N A,YYY
  1.  ;
  1.  M A=^TMP("XUMF MFS",$J,"PARAM","SEG",SEG,"SEQ",SEQ,"HLSCS")
  1.  S YYY=""
  1.  ;
  1.  S SEQ3=0
  1.  F  S SEQ3=$O(A(SEQ3)) Q:'SEQ3  D
  1.  .S FLD=$O(A(SEQ3,0))
  1.  .S ZDTYP=$G(A(SEQ3,FLD))
  1.  .I $P(ZDTYP,U,3)[":" S FLD=FLD_$P(ZDTYP,U,3)
  1.  .S VALUE=$$GET1^DIQ(IFN,IEN_",",FLD)
  1.  .S VALUE=$$DTYP^XUMFP(VALUE,ZDTYP,HLSCS,1)
  1.  .S $P(YYY,HLSCS,SEQ3)=VALUE
  1.  ;
  1.  S ZZZ(SEQ)=YYY
  1.  ;
  1.  Q
  1.  ;
  1. GROUP ; -- query group records
  1.  ;
  1.  Q:ERROR
  1.  ;
  1.  S IEN=0
  1.  F  S IEN=$O(^TMP("XUMF MFS",$J,"PARAM","IEN",IEN)) Q:'IEN  D
  1.  .K ^TMP("XUMF MFS",$J,"PARAM","PKV")
  1.  .K ^TMP("XUMF MFS",$J,"PARAM","IENS")
  1.  .S ^TMP("XUMF MFS",$J,"PARAM","PKV")=^TMP("XUMF MFS",$J,"PARAM",IEN,"PKV")
  1.  .M ^TMP("XUMF MFS",$J,"PARAM","IENS")=^TMP("XUMF MFS",$J,"PARAM",IEN,"IENS")
  1.  .D MFE,ZZZ
  1.  ;
  1.  Q
  1.  ;
  1. SEND ; -- send HL7 message
  1.  ;
  1.  I 'MFK,ERROR Q
  1.  ;
  1.  S HLP("PRIORITY")="I"
  1.  ;
  1.  I 'TYPE D GENERATE^HLMA(PROTOCOL,"GM",1,.HLRESLT,"",.HLP)
  1.  I TYPE,(TYPE<10) D DIRECT^HLMA(PROTOCOL,"GM",1,.HLRESLT,"",.HLP)
  1.  I (TYPE>9),$G(HLMTIENS) D
  1.  .D GENACK^HLMA1(HL("EID"),HLMTIENS,HL("EIDS"),"GM",1,.HLRESLT)
  1.  ;
  1.  ; check for error
  1.  I ($P($G(HLRESLT),U,3)'="") D  Q
  1.  .S ERROR=1_U_$P(HLRESLT,HLFS,3)_U_$P(HLRESLT,HLFS,2)_U_$P(HLRESLT,U)
  1.  ;
  1.  ; successful call, message ID returned
  1.  S ERROR="0^"_$P($G(HLRESLT),U,1)
  1.  ;
  1.  Q
  1.  ;
  1. EXIT ; -- exit
  1.  ;
  1.  D CLEAN^DILF
  1.  ;
  1.  K ^TMP("HLS",$J),^TMP("HLA",$J)
  1.  K ^TMP("XUMF MFS",$J)
  1.  ;
  1.  Q
  1.  ;
  1. LLNK ; -- dynamic addressing BROADCAST
  1.  ;
  1.  Q:TYPE>9
  1.  ;
  1.  I $G(^TMP("XUMF MFS",$J,"PARAM","LLNK"))'="" D  Q
  1.  .S HLL("LINKS",1)=^TMP("XUMF MFS",$J,"PARAM","LLNK")
  1.  ;
  1.  Q:'$$SERVER()
  1.  ;
  1.  Q:TYPE
  1.  Q:'$G(^TMP("XUMF MFS",$J,"PARAM","BROADCAST"))
  1.  ;
  1.  N I,J,LLNK
  1.  ;
  1.  S (I,J)=0
  1.  F  S I=$O(^HLCS(870,"C",I)) Q:'I  D
  1.  .S J=$O(^HLCS(870,"C",I,0)) Q:'J
  1.  .S LLNK=$P($G(^HLCS(870,J,0)),U)
  1.  .S HLL("LINKS",I)="XUMF MFK^"_LLNK
  1.  ;
  1.  Q
  1.  ;
  1. SERVER() ; -- servers
  1.  ;
  1.  N I
  1.  ;
  1.  S I=$$KSP^XUPARAM("INST") Q:'I 0
  1.  ;
  1.  Q:I=442 1  ;BP TEST
  1.  Q:I=12000 1  ;FORUM
  1.  Q:I=100002 1  ;HEC
  1.  ;
  1.  Q 0
  1.  ;