Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: ZISFMSM

ZISFMSM.m

Go to the documentation of this file.
  1. %ZISF ;SFISC/AC - HOST FILE CODE FOR MSM ;05/07/98  10:56 [ 04/02/2003   8:29 AM ]
  1.  ;;8.0;KERNEL;**1002,1003,1004,1005,1007**;APR 1, 2003
  1.  ;;8.0;KERNEL;**104**;JUL 10, 1995
  1. HFS Q:$D(IOP)&$D(%IS("HFSIO"))&$D(%IS("IOPAR"))
  1.  I $D(%ZIS("HFSNAME")) D  Q:$D(%ZIS("HFSMODE"))
  1.  .I $D(%ZIS("HFSMODE")) D
  1.  ..S %ZISOPAR=$$MODE^%ZISF(%ZIS("HFSNAME"),%ZIS("HFSMODE"))
  1.  ..W:'$D(IOP) "    HOST FILE TO USE:  "_%ZIS("HFSNAME") Q
  1.  .S %X=%ZIS("HFSNAME") D SETOPAR
  1.  .W:'$D(IOP) "    HOST FILE TO USE:  "_%ZIS("HFSNAME"),! Q
  1.  E  D ASKHFS ;Note the HFS name is part of the IO parameter string
  1. H S:$D(%ZIS("HFSMODE")) %ZISOPAR=$$MODE^%ZISF(%X,%ZIS("HFSMODE"))
  1. H1 S:$D(IO("Q"))!(%IS["Z") IO("HFSIO")=""
  1.  S:$E(%ZISOPAR)'="(" %ZISOPAR="("""_%ZISOPAR_""":""W"")"
  1.  S:$D(IO("HFSIO")) IO("HFSIO")=IO
  1.  D ASKPAR^%ZIS6,SETPAR^%ZIS3 K %ZY
  1. HFSIOO Q:$D(%ZIS("HFSMODE"))
  1.  I '$D(IOP),$$ASKHFSIO(%E) W ?45,"INPUT/OUTPUT OPERATION: "
  1.  Q:'$T  D SBR^%ZIS1 I $D(DTOUT)!$D(DFOUT)!$D(DUOUT) S POP=1 Q
  1.  D HOPT(1):%X="?"!($F("?^R^W^M^A",%X)'>1),HOPT1:%X="??" G HFSIOO:%X="?"!($F("?^R^W^M^A",%X)'>1)
  1.  S $P(%ZISOPAR,"""",4)=%X Q
  1.  ;
  1. HOPT(X) ;Display Input/Output operation -- X=1 for scroll, X=2 for MWAPI.
  1.  I X=1 D
  1.  .W !,"Enter one of the following host file input/ouput operation:"
  1.  .W !,?16,"R = READ",!,?16,"W = WRITE",!,?16,"M = READ/WRITE",!,?16,"A =  APPEND" Q
  1.  E  D
  1.  .K TMP("ZISGHFS","G","HFSOPER","CHOICE")
  1.  .S TMP("ZISGHFS","G","HFSOPER","CHOICE","1^R")="READ"
  1.  .S TMP("ZISGHFS","G","HFSOPER","CHOICE","2^W")="WRITE"
  1.  .S TMP("ZISGHFS","G","HFSOPER","CHOICE","3^M")="READ/WRITE"
  1.  .S TMP("ZISGHFS","G","HFSOPER","CHOICE","4^A")="APPEND"
  1.  Q
  1. HOPT1 S %ZISI=$O(^DIC(9.2,"B","XUHFSPARAM-MSM",0)) Q:'%ZISI  Q:'$D(^DIC(9.2,+%ZISI,0))  Q:$P(^(0),"^",1)'="XUHFSPARAM-MSM"
  1.  Q:$D(^DIC(9.2,+%ZISI,1))'>9  F %X=0:0 S %X=$O(^DIC(9.2,+%ZISI,1,%X)) Q:%X'>0  I $D(^(%X,0)) W !,^(0)
  1.  W ! S %X="??" Q
  1.  ;
  1. CHKNM(H) ;Check HFS name for dir
  1.  I $$OSTYPE^%ZOSV<3 S H=$TR(H,"/","\") ;for DOS/NT only
  1.  I H[":"!(H["\")!(H["/") Q H
  1.  Q $$DEFDIR^%ZISH("")_H
  1.  ;
  1. ASKHFS ;---Ask host file name here---
  1.  S %X='$P($G(^%ZIS(1,%E,1)),"^",5)
  1.  S:'%X %X=""
  1.  Q:$D(IOP)!%X!$D(%ZIS("HFSNAME"))
  1. ASKAGN W !,"HOST FILE NAME: " S %ZY=$$GETHFSNM(%ZISOPAR)
  1.  W:%ZY]"" %ZY_"//" D SBR^%ZIS1
  1.  I %X?1."?".E W !,"ENTER HOST FILE NAME" G ASKAGN
  1.  I $D(DTOUT)!$D(DUOUT) K %ZY S POP=1 Q
  1.  S %X=$S(%X]"":%X,1:%ZY)
  1.  I %X="" W *7,!,"You must enter the name of a host file" G ASKAGN
  1.  D SETOPAR Q
  1.  ;
  1. SETOPAR ;Set the file name into %ZISOPAR
  1.  S %X=$$CHKNM(%X)
  1.  I %ZISOPAR?1"("1"""".ANP1""""1":"1"""".AN1""""1")" S $P(%ZISOPAR,"""",2)=%X Q
  1.  S %ZISOPAR=%X
  1.  Q
  1. MODE(X1,X2) ;Return value in Y
  1.  N Y
  1.  S Y="("_""""_X1_""":"_""""_$S(X2="RW":"M",X2="R":"R",X2="W":"W",X2="A":"A",1:"W")_""")"
  1.  Q Y
  1. ASKHFSIO(DA)       ;
  1.  I $G(^%ZIS(1,DA,"TYPE"))="HFS",'$D(%ZIS("HFSMODE")),'$P(^(0),"^",4),$P($G(^(1)),"^",6) Q 1
  1.  Q 0
  1. GETHFSNM(X)        ;Extract host file name from variable X.
  1.  N Y
  1.  S Y=X
  1.  S:Y?1"("1"""".ANP1""""1":"1"""".AN1""""1")" Y=$P(Y,"""",2)
  1.  I $D(%IS("B","HFS"))#2,%IS("B","HFS")]"" S Y=%IS("B","HFS")
  1.  Q Y