Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: ZOSVKRO

ZOSVKRO.m

Go to the documentation of this file.
  1. %ZOSVKR ;SF/KAK - Collect RUM Statistics for OpenM/Cache;8/20/99 08:43 ;3/27/00 11:24 [ 04/02/2003 8:29 AM ]
  1. ;;8.0;KERNEL;**1005,1007**;APR 1, 2003
  1. ;;8.0;KERNEL;**90,94,107,122,143**;Jul 21, 1998
  1. ;
  1. RO(OPT) ; Record option resource usage in ^XTMP("KMPR","JOB"
  1. ;
  1. N KMPRTYP S KMPRTYP=0 ; option
  1. G EN
  1. ;
  1. RP(PRTCL) ; Record protocol resource usage in ^XTMP("KMPR","JOB"
  1. ;
  1. ; Variable PRTCL = option_name^protocol_name
  1. N OPT,KMPRTYP
  1. S OPT=$P(PRTCL,"^"),PRTCL=$P(PRTCL,"^",2) Q:PRTCL=""
  1. ; protocol
  1. S KMPRTYP=1
  1. G EN
  1. ;
  1. RU(KMPROPT,KMPRTYP,KMPRSTAT) ;-- record resource usage in ^XTMP("KMPR","JOB"
  1. ;---------------------------------------------------------------------
  1. ; KMPROPT... Option name (may be option, protocol, rpc, etc.).
  1. ; KMPRTYP... Type of option:
  1. ; 0 - Option.
  1. ; 1 - Protocol.
  1. ; 2 - RPC (Remote Procedure Call).
  1. ; 3 - HL7.
  1. ; KMPRSTAT.. Status (for future use). 1 - start
  1. ; 2 - stop
  1. ;---------------------------------------------------------------------
  1. ;
  1. Q:$G(KMPROPT)=""
  1. S KMPRTYP=+$G(KMPRTYP)
  1. S KMPRSTAT=$G(KMPRSTAT)
  1. ;
  1. N OPT,PRTCL
  1. ;
  1. ; OPT = option name.
  1. ; PRTCL = protocol name (optional).
  1. S OPT=$P(KMPROPT,"^"),PRTCL=$P(KMPROPT,"^",2)
  1. ;
  1. EN ;
  1. ; C........ comma (,)
  1. ; CURRENT.. current stats
  1. ; DATE..... date in fileman format
  1. ; DIFF..... difference (CURRENT minus PREV)
  1. ; DOW...... day of week
  1. ; HDATE.... date/time in $h format
  1. ; NODE..... current node
  1. ; PRIMETM.. prime time or non-prime time
  1. ; PREV..... previous stats
  1. ;
  1. N C,CURRENT,CURRHR,DATE,DIFF,DOW,HDATE,I,NODE,PREV,PREVHR
  1. N PRIMETM,TIME,Y
  1. ; quit if not in "PROD" uci.
  1. S Y="" X $G(^%ZOSF("UCI")) Q:Y'[$G(^%ZOSF("PROD"))
  1. D GETENV^%ZOSV S NODE=$P(Y,"^",3)
  1. S C=",",U="^"
  1. I KMPRTYP I OPT="" S:$P($G(^XTMP("KMPR","JOB",NODE,$J)),U,10)["$LOGIN$" OPT="$LOGIN$"
  1. I OPT="" Q:'+$G(^XUTL("XQ",$J,"T")) S OPT=$P($G(^XUTL("XQ",$J,^XUTL("XQ",$J,"T"))),U,2) Q:OPT=""
  1. ;
  1. ; CURRENT = current stats for this $job.
  1. ; cpu^dio^bio^pg_fault^cmd^glo^$H_date^$H_sec^ascii_time
  1. S CURRENT=$$STATS Q:CURRENT=""
  1. ; concatenate ^OPTion^option_type
  1. S CURRENT=CURRENT_U_$S(KMPRTYP=2:"`"_OPT,KMPRTYP=3:"&"_OPT,1:OPT)_"***"_$G(PRTCL)_U_$G(XQT)
  1. ; if option and login or taskman
  1. I 'KMPRTYP I OPT="$LOGIN$"!(OPT="$STRT ZTMS$") S ^XTMP("KMPR","JOB",NODE,$J)=CURRENT Q
  1. ; if logout or stopping task or programmer mode
  1. I OPT="$LOGOUT$"!(OPT="$STOP ZTMS$")!(OPT="XUPROGMODE") K ^XTMP("KMPR","JOB",NODE,$J)
  1. ;
  1. ; PREV = previous stats for this $job.
  1. S PREV=$G(^XTMP("KMPR","JOB",NODE,$J)) S ^($J)=CURRENT
  1. Q:PREV=""
  1. ;
  1. ; check for negative numbers for m commands and glo references
  1. F I=5,6 D
  1. .S:$P(CURRENT,U,I)<0 $P(CURRENT,U,I)=$P(CURRENT,U,I)+(2**32)
  1. .S:$P(PREV,U,I)<0 $P(PREV,U,I)=$P(PREV,U,I)+(2**32)
  1. ;
  1. S $P(CURRENT,U,7)=$P(CURRENT,U,7)-$P(PREV,U,7)*86400+$P(CURRENT,U,8)
  1. S HDATE=$P(PREV,U,7),$P(PREV,U,7)=$P(PREV,U,8)
  1. ; quit if not $h
  1. Q:'HDATE
  1. ;
  1. ; DIFF = CURRENT - PREV (current stats minus previous stats)
  1. ; cpu^dio^bio^pg_fault^cmd^glo^elapsed_sec^option_type
  1. F I=1:1:7 S $P(DIFF,U,I)=$P(CURRENT,U,I)-$P(PREV,U,I)
  1. ; option name time
  1. S OPT=$P(PREV,U,10),TIME=$P($P(PREV,U,8),".")
  1. ; date in fm format.
  1. S DATE=$$HTFM^XLFDT(HDATE),DATE=$P(DATE,".")
  1. ; day of week.
  1. S DOW=$$DOW^XLFDT(DATE,1)
  1. ; PRIMETM = 0: non-prime time
  1. ; 1: prime time
  1. S PRIMETM=0
  1. ; prime time if not saturday or sunday or holiday
  1. ; if after 8am and before 5pm.
  1. I DOW>0&(DOW<6)&('$G(^HOLIDAY(DATE,0))) I TIME>28799&(TIME<61201) S PRIMETM=1
  1. ; daily stats by $j.
  1. F I=1:1:7 S $P(^XTMP("KMPR","DLY",NODE,HDATE,OPT,$J,PRIMETM),U,I)=$P($G(^XTMP("KMPR","DLY",NODE,HDATE,OPT,$J,PRIMETM)),U,I)+$P(DIFF,U,I)
  1. ; 8th piece is count.
  1. S $P(^XTMP("KMPR","DLY",NODE,HDATE,OPT,$J,PRIMETM),U,8)=$P(^XTMP("KMPR","DLY",NODE,HDATE,OPT,$J,PRIMETM),U,8)+1
  1. ;
  1. ; keep track of hours with activity - this will be used to determine
  1. ; actual hours of activity when moving data to file 8971.1
  1. S DATE=$$HTFM^XLFDT(HDATE_","_TIME)
  1. ;S TIME=+$E($P(DATE,".",2),1,2),DATE=$P(DATE,".")
  1. ; hour for 'previous' dat.
  1. S PREVHR=+$E($P(DATE,".",2),1,2),DATE=$P(DATE,".")
  1. ; current hour.
  1. S CURRHR=+$E($P($$HTFM^XLFDT($H),".",2),1,2)
  1. ; record all hours this option ran.
  1. F TIME=PREVHR:1:CURRHR D
  1. .; because of zero hour add 1 to time - will offset each hour by 1
  1. .S:DATE $P(^XTMP("KMPR","HOURS",DATE,NODE),U,(TIME+1))=1
  1. ;
  1. Q
  1. ;
  1. STATS() ;-- extrinsic - return current stats for this $job
  1. ;
  1. N V
  1. S V=$V(-1,$J)
  1. ; current stats for this $job.
  1. ; cpu^dio^bio^pg_fault^cmd^glo^$H_date^$H_sec^time in thousands
  1. Q "^^^^"_$P($P(V,"^",7),",")_"^"_$P($P(V,"^",7),",",2)_"^"_+$H_"^"_$P($H,",",2)_"^"_$ZTIMESTAMP