Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: SROUTL0

SROUTL0.m

Go to the documentation of this file. 
  1. SROUTL0 ;BIR/DLR,ADM - UTILITY ROUTINE ; [ 06/20/01  2:33 PM ]
  1.  ;;3.0; Surgery ;**50,100**;24 Jun 93
  1.  ;
  1.  ; Reference to ^SC( supported by DBIA #964
  1.  ;
  1. NODATA() ;;utility to write no data
  1.  W !!
  1.  Q "No data for selected date range."
  1. DIV(CASE) ;define the division of this case
  1.  ; CASE - File 130 ien
  1.  ; returns 0 - non-divisional match; 1 - divisonal match
  1.  N SRDIV,SROR I '$D(^SRF(CASE,0)) Q 0
  1.  I '$O(^SRO(133,1)) Q 1
  1.  I '$D(^SRF(CASE,"NON")) S SRDIV="",SROR=$P(^SRF(CASE,0),U,2) I SROR'="" S SROR=$P(^SRS(SROR,0),U) I SROR'="" S SRDIV=$P(^SC(SROR,0),U,4)
  1.  I $D(^SRF(CASE,"NON")) S SRDIV="",SROR=$P(^SRF(CASE,"NON"),U,2) I SROR'="" S SRDIV=$P(^SC(SROR,0),U,4)
  1.  I SRDIV="" S SRDIV=$P($G(^SRF(CASE,8)),U)
  1.  Q SRDIV=$G(SRSITE("DIV"))
  1. ORDIV(OR,SRINST) ;define the division of this OR
  1.  ; OR - .01 of Operating Room in file 131.7
  1.  ; returns 0 - non-divisional match; 1 - divisonal match
  1.  N SRDIV
  1.  I '$O(^SRO(133,1)) Q 1
  1.  I SRINST="" Q 1
  1.  I SRINST["ALL" Q 1
  1.  I $G(OR)'="" S OR=$P(^SRS(OR,0),U),SRDIV=$P($G(^SC(OR,0)),U,4) I SRDIV'="" S SRDIV=$P(^(0),U,4)
  1.  Q SRDIV=SRINST
  1. NONORDIV(CASE,NONOR) ;define nonor divisional locations (File #130,119 input transform)
  1.  ; CASE - File 130 ien
  1.  ; NONOR - File 44 ien
  1.  ; returns 0 - non-divisional match; 1 - divisonal match
  1.  N CD,IORD,RORD,SRDIV
  1.  ; CD - case date
  1.  ; SRDIV - boolean (case division MATCH)
  1.  ; IORD - Location file inactive date
  1.  ; RORD - Location file inactive date
  1.  ; 
  1.  S SRDIV=1
  1.  I '$D(^SC(NONOR,0))!$G(NONOR)=""!$G(CASE)="" Q SRDIV
  1.  I '$D(^SRF(CASE,"NON")) Q 0
  1.  ;if there is no institution set for this non-or location quit
  1.  I $P(^SC(NONOR,0),U,4)="" Q 0
  1.  I $D(SRSITE("DIV")) I $P(^SC(NONOR,0),U,4)'=$G(SRSITE("DIV")) Q 0
  1.  I $D(^SC(NONOR,"I")) S CD=$P(^SRF(CASE,"NON"),U,3),IORD=$P(^SC(NONOR,"I"),U),RORD=$P(^SC(NONOR,"I"),U,2) D:IORD'=""
  1.  .I CD'<IORD,((RORD="")!(CD<RORD)) S SRDIV=0 Q
  1.  Q SRDIV
  1. MANDIV(SRINST,CASE) ;a boolean divisional call for managerial reports
  1.  I '$D(^SRF(CASE,0)) Q 0
  1.  I '$O(^SRO(133,1)) Q 1
  1.  I SRINST["ALL" Q 1
  1.  I +SRINST'>0 Q 0
  1.  N SRDIV,SROR
  1.  I '$D(^SRF(CASE,"NON")) S SRDIV="",SROR=$P(^SRF(CASE,0),U,2) I SROR'="" S SROR=$P(^SRS(SROR,0),U) I SROR'="" S SRDIV=$P(^SC(SROR,0),U,4)
  1.  I $D(^SRF(CASE,"NON")) S SRDIV="",SROR=$P(^SRF(CASE,"NON"),U,2) I SROR'="" S SRDIV=$P(^SC(SROR,0),U,4)
  1.  I SRDIV="" S SRDIV=$P($G(^SRF(CASE,8)),U)
  1.  Q SRDIV=SRINST
  1. INST() ;extrinsic call used by the management reports to determine division
  1.  ; Returns:
  1.  ;   inst#^inst name - for one division
  1.  ;   "ALL DIVISIONS" - all divisions
  1.  ;   "^"             - no division
  1.  N SR,SRCNT,SRINST,X S (SRCNT,X)=0 F  S X=$O(^SRO(133,X)) Q:'X  I '$P($G(^SRO(133,X,0)),"^",21) S SRCNT=SRCNT+1
  1.  I SRCNT=1 S SRINST=$P($$SITE^SROVAR,"^",1,2) Q SRINST
  1.  W ! K DIR,Y S DIR(0)="YO",DIR("?")="Enter 'Yes' to include all divisions, or 'No' to pick one division",DIR("A")="Do you want to print all divisions",DIR("B")="YES" D ^DIR S SRINST=$S($G(Y(0))'="":Y(0),1:"^")
  1.  I SRINST="YES" S SRINST=$P($$SITE^SROVAR,U,2)_" - ALL DIVISIONS"
  1.  I SRINST="NO" D LIST^DIC(133,"",".01","B","*","","","","","","SR") W ! D
  1.  .S X=0 F  S X=$O(SR("DILIST",1,X)) Q:'X  W !,X,". ",SR("DILIST",1,X)
  1.  .K DIR W ! S DIR(0)="NO^1:"_$P(SR("DILIST",0),U),DIR("A")="Select Number" D ^DIR S:+Y<1 SRINST="^" S:+Y>0 SRINST=SR("DILIST",2,+Y),DIR("?")="Enter the corresponding number of the hospital for which you want the report to run"
  1.  Q $S(SRINST["ALL DIVISIONS":SRINST,SRINST=U:SRINST,1:$P(^SRO(133,SRINST,0),U)_U_SR("DILIST",1,+Y))
  1. SITE(CASE) ; returns pointer to file 133 indicating where case was performed
  1.  ; CASE - ien in File 130
  1.  N SRDIV,SROR S SRDIV="" I '$D(^SRF(CASE,"NON")) S SROR=$P($G(^SRF(CASE,0)),"^",2) I SROR'="" S SROR=$P(^SRS(SROR,0),"^") I SROR'="" S SRDIV=$P(^SC(SROR,0),"^",4)
  1.  I $P($G(^SRF(CASE,"NON")),"^")="Y" S SROR=$P(^SRF(CASE,"NON"),"^",2) I SROR'="" S SRDIV=$P(^SC(SROR,0),"^",4)
  1.  I SRDIV="" S SRDIV=$P($G(^SRF(CASE,8)),"^")
  1.  S:SRDIV'="" SRDIV=$O(^SRO(133,"B",SRDIV,0))
  1.  S:SRDIV="" SRDIV=$O(^SRO(133,0))
  1.  Q SRDIV
  1. WARD(SRW,SRINST,DGPMOS) ;a boolean divisional call for active ward location
  1.  ; SRW - IEN in File 42
  1.  ; SRINST - user division
  1.  ; DGPMOS - date to check for active ward
  1.  ; returns 0 - non-divisional match; 1 - divisional match
  1.  N SRLOC,D0,X
  1.  S D0=SRW D WIN^DGPMDDCF I X=1 Q 0
  1.  I '$O(^SRO(133,1))!(SRINST="")!(SRINST["ALL") Q 1
  1.  S SRLOC=$P($G(^DIC(42,SRW,44)),"^") I SRLOC="" Q 1
  1.  S SRDIV=$P($G(^SC(SRLOC,0)),"^",4) I SRDIV="" Q 1
  1.  Q SRDIV=SRINST
  1. HL(SRLOC,SRINST) ; define division of this hospital location
  1.  ; SRLOC - File 44 IEN
  1.  ; SRINST - user division
  1.  ; returns 0 - non-divisional match; 1 - divisional match
  1.  N SRDIV I SRINST="" Q 1
  1.  S SRDIV=0
  1.  I $G(SRLOC)'="" S SRDIV=$P($G(^SC(SRLOC,0)),"^",4) I SRDIV="" Q 1
  1.  Q SRDIV=SRINST